LAPACK  3.10.1
LAPACK: Linear Algebra PACKage
zpstrf.f
Go to the documentation of this file.
1 *> \brief \b ZPSTRF computes the Cholesky factorization with complete pivoting of a complex Hermitian positive semidefinite matrix.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download ZPSTRF + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zpstrf.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zpstrf.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zpstrf.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE ZPSTRF( UPLO, N, A, LDA, PIV, RANK, TOL, WORK, INFO )
22 *
23 * .. Scalar Arguments ..
24 * DOUBLE PRECISION TOL
25 * INTEGER INFO, LDA, N, RANK
26 * CHARACTER UPLO
27 * ..
28 * .. Array Arguments ..
29 * COMPLEX*16 A( LDA, * )
30 * DOUBLE PRECISION WORK( 2*N )
31 * INTEGER PIV( N )
32 * ..
33 *
34 *
35 *> \par Purpose:
36 * =============
37 *>
38 *> \verbatim
39 *>
40 *> ZPSTRF computes the Cholesky factorization with complete
41 *> pivoting of a complex Hermitian positive semidefinite matrix A.
42 *>
43 *> The factorization has the form
44 *> P**T * A * P = U**H * U , if UPLO = 'U',
45 *> P**T * A * P = L * L**H, if UPLO = 'L',
46 *> where U is an upper triangular matrix and L is lower triangular, and
47 *> P is stored as vector PIV.
48 *>
49 *> This algorithm does not attempt to check that A is positive
50 *> semidefinite. This version of the algorithm calls level 3 BLAS.
51 *> \endverbatim
52 *
53 * Arguments:
54 * ==========
55 *
56 *> \param[in] UPLO
57 *> \verbatim
58 *> UPLO is CHARACTER*1
59 *> Specifies whether the upper or lower triangular part of the
60 *> symmetric matrix A is stored.
61 *> = 'U': Upper triangular
62 *> = 'L': Lower triangular
63 *> \endverbatim
64 *>
65 *> \param[in] N
66 *> \verbatim
67 *> N is INTEGER
68 *> The order of the matrix A. N >= 0.
69 *> \endverbatim
70 *>
71 *> \param[in,out] A
72 *> \verbatim
73 *> A is COMPLEX*16 array, dimension (LDA,N)
74 *> On entry, the symmetric matrix A. If UPLO = 'U', the leading
75 *> n by n upper triangular part of A contains the upper
76 *> triangular part of the matrix A, and the strictly lower
77 *> triangular part of A is not referenced. If UPLO = 'L', the
78 *> leading n by n lower triangular part of A contains the lower
79 *> triangular part of the matrix A, and the strictly upper
80 *> triangular part of A is not referenced.
81 *>
82 *> On exit, if INFO = 0, the factor U or L from the Cholesky
83 *> factorization as above.
84 *> \endverbatim
85 *>
86 *> \param[in] LDA
87 *> \verbatim
88 *> LDA is INTEGER
89 *> The leading dimension of the array A. LDA >= max(1,N).
90 *> \endverbatim
91 *>
92 *> \param[out] PIV
93 *> \verbatim
94 *> PIV is INTEGER array, dimension (N)
95 *> PIV is such that the nonzero entries are P( PIV(K), K ) = 1.
96 *> \endverbatim
97 *>
98 *> \param[out] RANK
99 *> \verbatim
100 *> RANK is INTEGER
101 *> The rank of A given by the number of steps the algorithm
102 *> completed.
103 *> \endverbatim
104 *>
105 *> \param[in] TOL
106 *> \verbatim
107 *> TOL is DOUBLE PRECISION
108 *> User defined tolerance. If TOL < 0, then N*U*MAX( A(K,K) )
109 *> will be used. The algorithm terminates at the (K-1)st step
110 *> if the pivot <= TOL.
111 *> \endverbatim
112 *>
113 *> \param[out] WORK
114 *> \verbatim
115 *> WORK is DOUBLE PRECISION array, dimension (2*N)
116 *> Work space.
117 *> \endverbatim
118 *>
119 *> \param[out] INFO
120 *> \verbatim
121 *> INFO is INTEGER
122 *> < 0: If INFO = -K, the K-th argument had an illegal value,
123 *> = 0: algorithm completed successfully, and
124 *> > 0: the matrix A is either rank deficient with computed rank
125 *> as returned in RANK, or is not positive semidefinite. See
126 *> Section 7 of LAPACK Working Note #161 for further
127 *> information.
128 *> \endverbatim
129 *
130 * Authors:
131 * ========
132 *
133 *> \author Univ. of Tennessee
134 *> \author Univ. of California Berkeley
135 *> \author Univ. of Colorado Denver
136 *> \author NAG Ltd.
137 *
138 *> \ingroup complex16OTHERcomputational
139 *
140 * =====================================================================
141  SUBROUTINE zpstrf( UPLO, N, A, LDA, PIV, RANK, TOL, WORK, INFO )
142 *
143 * -- LAPACK computational routine --
144 * -- LAPACK is a software package provided by Univ. of Tennessee, --
145 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
146 *
147 * .. Scalar Arguments ..
148  DOUBLE PRECISION TOL
149  INTEGER INFO, LDA, N, RANK
150  CHARACTER UPLO
151 * ..
152 * .. Array Arguments ..
153  COMPLEX*16 A( LDA, * )
154  DOUBLE PRECISION WORK( 2*N )
155  INTEGER PIV( N )
156 * ..
157 *
158 * =====================================================================
159 *
160 * .. Parameters ..
161  DOUBLE PRECISION ONE, ZERO
162  parameter( one = 1.0d+0, zero = 0.0d+0 )
163  COMPLEX*16 CONE
164  parameter( cone = ( 1.0d+0, 0.0d+0 ) )
165 * ..
166 * .. Local Scalars ..
167  COMPLEX*16 ZTEMP
168  DOUBLE PRECISION AJJ, DSTOP, DTEMP
169  INTEGER I, ITEMP, J, JB, K, NB, PVT
170  LOGICAL UPPER
171 * ..
172 * .. External Functions ..
173  DOUBLE PRECISION DLAMCH
174  INTEGER ILAENV
175  LOGICAL LSAME, DISNAN
176  EXTERNAL dlamch, ilaenv, lsame, disnan
177 * ..
178 * .. External Subroutines ..
179  EXTERNAL zdscal, zgemv, zherk, zlacgv, zpstf2, zswap,
180  $ xerbla
181 * ..
182 * .. Intrinsic Functions ..
183  INTRINSIC dble, dconjg, max, min, sqrt, maxloc
184 * ..
185 * .. Executable Statements ..
186 *
187 * Test the input parameters.
188 *
189  info = 0
190  upper = lsame( uplo, 'U' )
191  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
192  info = -1
193  ELSE IF( n.LT.0 ) THEN
194  info = -2
195  ELSE IF( lda.LT.max( 1, n ) ) THEN
196  info = -4
197  END IF
198  IF( info.NE.0 ) THEN
199  CALL xerbla( 'ZPSTRF', -info )
200  RETURN
201  END IF
202 *
203 * Quick return if possible
204 *
205  IF( n.EQ.0 )
206  $ RETURN
207 *
208 * Get block size
209 *
210  nb = ilaenv( 1, 'ZPOTRF', uplo, n, -1, -1, -1 )
211  IF( nb.LE.1 .OR. nb.GE.n ) THEN
212 *
213 * Use unblocked code
214 *
215  CALL zpstf2( uplo, n, a( 1, 1 ), lda, piv, rank, tol, work,
216  $ info )
217  GO TO 230
218 *
219  ELSE
220 *
221 * Initialize PIV
222 *
223  DO 100 i = 1, n
224  piv( i ) = i
225  100 CONTINUE
226 *
227 * Compute stopping value
228 *
229  DO 110 i = 1, n
230  work( i ) = dble( a( i, i ) )
231  110 CONTINUE
232  pvt = maxloc( work( 1:n ), 1 )
233  ajj = dble( a( pvt, pvt ) )
234  IF( ajj.LE.zero.OR.disnan( ajj ) ) THEN
235  rank = 0
236  info = 1
237  GO TO 230
238  END IF
239 *
240 * Compute stopping value if not supplied
241 *
242  IF( tol.LT.zero ) THEN
243  dstop = n * dlamch( 'Epsilon' ) * ajj
244  ELSE
245  dstop = tol
246  END IF
247 *
248 *
249  IF( upper ) THEN
250 *
251 * Compute the Cholesky factorization P**T * A * P = U**H * U
252 *
253  DO 160 k = 1, n, nb
254 *
255 * Account for last block not being NB wide
256 *
257  jb = min( nb, n-k+1 )
258 *
259 * Set relevant part of first half of WORK to zero,
260 * holds dot products
261 *
262  DO 120 i = k, n
263  work( i ) = 0
264  120 CONTINUE
265 *
266  DO 150 j = k, k + jb - 1
267 *
268 * Find pivot, test for exit, else swap rows and columns
269 * Update dot products, compute possible pivots which are
270 * stored in the second half of WORK
271 *
272  DO 130 i = j, n
273 *
274  IF( j.GT.k ) THEN
275  work( i ) = work( i ) +
276  $ dble( dconjg( a( j-1, i ) )*
277  $ a( j-1, i ) )
278  END IF
279  work( n+i ) = dble( a( i, i ) ) - work( i )
280 *
281  130 CONTINUE
282 *
283  IF( j.GT.1 ) THEN
284  itemp = maxloc( work( (n+j):(2*n) ), 1 )
285  pvt = itemp + j - 1
286  ajj = work( n+pvt )
287  IF( ajj.LE.dstop.OR.disnan( ajj ) ) THEN
288  a( j, j ) = ajj
289  GO TO 220
290  END IF
291  END IF
292 *
293  IF( j.NE.pvt ) THEN
294 *
295 * Pivot OK, so can now swap pivot rows and columns
296 *
297  a( pvt, pvt ) = a( j, j )
298  CALL zswap( j-1, a( 1, j ), 1, a( 1, pvt ), 1 )
299  IF( pvt.LT.n )
300  $ CALL zswap( n-pvt, a( j, pvt+1 ), lda,
301  $ a( pvt, pvt+1 ), lda )
302  DO 140 i = j + 1, pvt - 1
303  ztemp = dconjg( a( j, i ) )
304  a( j, i ) = dconjg( a( i, pvt ) )
305  a( i, pvt ) = ztemp
306  140 CONTINUE
307  a( j, pvt ) = dconjg( a( j, pvt ) )
308 *
309 * Swap dot products and PIV
310 *
311  dtemp = work( j )
312  work( j ) = work( pvt )
313  work( pvt ) = dtemp
314  itemp = piv( pvt )
315  piv( pvt ) = piv( j )
316  piv( j ) = itemp
317  END IF
318 *
319  ajj = sqrt( ajj )
320  a( j, j ) = ajj
321 *
322 * Compute elements J+1:N of row J.
323 *
324  IF( j.LT.n ) THEN
325  CALL zlacgv( j-1, a( 1, j ), 1 )
326  CALL zgemv( 'Trans', j-k, n-j, -cone, a( k, j+1 ),
327  $ lda, a( k, j ), 1, cone, a( j, j+1 ),
328  $ lda )
329  CALL zlacgv( j-1, a( 1, j ), 1 )
330  CALL zdscal( n-j, one / ajj, a( j, j+1 ), lda )
331  END IF
332 *
333  150 CONTINUE
334 *
335 * Update trailing matrix, J already incremented
336 *
337  IF( k+jb.LE.n ) THEN
338  CALL zherk( 'Upper', 'Conj Trans', n-j+1, jb, -one,
339  $ a( k, j ), lda, one, a( j, j ), lda )
340  END IF
341 *
342  160 CONTINUE
343 *
344  ELSE
345 *
346 * Compute the Cholesky factorization P**T * A * P = L * L**H
347 *
348  DO 210 k = 1, n, nb
349 *
350 * Account for last block not being NB wide
351 *
352  jb = min( nb, n-k+1 )
353 *
354 * Set relevant part of first half of WORK to zero,
355 * holds dot products
356 *
357  DO 170 i = k, n
358  work( i ) = 0
359  170 CONTINUE
360 *
361  DO 200 j = k, k + jb - 1
362 *
363 * Find pivot, test for exit, else swap rows and columns
364 * Update dot products, compute possible pivots which are
365 * stored in the second half of WORK
366 *
367  DO 180 i = j, n
368 *
369  IF( j.GT.k ) THEN
370  work( i ) = work( i ) +
371  $ dble( dconjg( a( i, j-1 ) )*
372  $ a( i, j-1 ) )
373  END IF
374  work( n+i ) = dble( a( i, i ) ) - work( i )
375 *
376  180 CONTINUE
377 *
378  IF( j.GT.1 ) THEN
379  itemp = maxloc( work( (n+j):(2*n) ), 1 )
380  pvt = itemp + j - 1
381  ajj = work( n+pvt )
382  IF( ajj.LE.dstop.OR.disnan( ajj ) ) THEN
383  a( j, j ) = ajj
384  GO TO 220
385  END IF
386  END IF
387 *
388  IF( j.NE.pvt ) THEN
389 *
390 * Pivot OK, so can now swap pivot rows and columns
391 *
392  a( pvt, pvt ) = a( j, j )
393  CALL zswap( j-1, a( j, 1 ), lda, a( pvt, 1 ), lda )
394  IF( pvt.LT.n )
395  $ CALL zswap( n-pvt, a( pvt+1, j ), 1,
396  $ a( pvt+1, pvt ), 1 )
397  DO 190 i = j + 1, pvt - 1
398  ztemp = dconjg( a( i, j ) )
399  a( i, j ) = dconjg( a( pvt, i ) )
400  a( pvt, i ) = ztemp
401  190 CONTINUE
402  a( pvt, j ) = dconjg( a( pvt, j ) )
403 *
404 *
405 * Swap dot products and PIV
406 *
407  dtemp = work( j )
408  work( j ) = work( pvt )
409  work( pvt ) = dtemp
410  itemp = piv( pvt )
411  piv( pvt ) = piv( j )
412  piv( j ) = itemp
413  END IF
414 *
415  ajj = sqrt( ajj )
416  a( j, j ) = ajj
417 *
418 * Compute elements J+1:N of column J.
419 *
420  IF( j.LT.n ) THEN
421  CALL zlacgv( j-1, a( j, 1 ), lda )
422  CALL zgemv( 'No Trans', n-j, j-k, -cone,
423  $ a( j+1, k ), lda, a( j, k ), lda, cone,
424  $ a( j+1, j ), 1 )
425  CALL zlacgv( j-1, a( j, 1 ), lda )
426  CALL zdscal( n-j, one / ajj, a( j+1, j ), 1 )
427  END IF
428 *
429  200 CONTINUE
430 *
431 * Update trailing matrix, J already incremented
432 *
433  IF( k+jb.LE.n ) THEN
434  CALL zherk( 'Lower', 'No Trans', n-j+1, jb, -one,
435  $ a( j, k ), lda, one, a( j, j ), lda )
436  END IF
437 *
438  210 CONTINUE
439 *
440  END IF
441  END IF
442 *
443 * Ran to completion, A has full rank
444 *
445  rank = n
446 *
447  GO TO 230
448  220 CONTINUE
449 *
450 * Rank is the number of steps completed. Set INFO = 1 to signal
451 * that the factorization cannot be used to solve a system.
452 *
453  rank = j - 1
454  info = 1
455 *
456  230 CONTINUE
457  RETURN
458 *
459 * End of ZPSTRF
460 *
461  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine zswap(N, ZX, INCX, ZY, INCY)
ZSWAP
Definition: zswap.f:81
subroutine zdscal(N, DA, ZX, INCX)
ZDSCAL
Definition: zdscal.f:78
subroutine zgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
ZGEMV
Definition: zgemv.f:158
subroutine zherk(UPLO, TRANS, N, K, ALPHA, A, LDA, BETA, C, LDC)
ZHERK
Definition: zherk.f:173
subroutine zlacgv(N, X, INCX)
ZLACGV conjugates a complex vector.
Definition: zlacgv.f:74
subroutine zpstf2(UPLO, N, A, LDA, PIV, RANK, TOL, WORK, INFO)
ZPSTF2 computes the Cholesky factorization with complete pivoting of a complex Hermitian positive sem...
Definition: zpstf2.f:142
subroutine zpstrf(UPLO, N, A, LDA, PIV, RANK, TOL, WORK, INFO)
ZPSTRF computes the Cholesky factorization with complete pivoting of a complex Hermitian positive sem...
Definition: zpstrf.f:142