zpstrf()

subroutine zpstrf	(	character	uplo,
		integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		integer, dimension( n )	piv,
		integer	rank,
		double precision	tol,
		double precision, dimension( 2*n )	work,
		integer	info )

ZPSTRF computes the Cholesky factorization with complete pivoting of a complex Hermitian positive semidefinite matrix.

Download ZPSTRF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZPSTRF computes the Cholesky factorization with complete
!> pivoting of a complex Hermitian positive semidefinite matrix A.
!>
!> The factorization has the form
!>    P**T * A * P = U**H * U ,  if UPLO = 'U',
!>    P**T * A * P = L  * L**H,  if UPLO = 'L',
!> where U is an upper triangular matrix and L is lower triangular, and
!> P is stored as vector PIV.
!>
!> This algorithm does not attempt to check that A is positive
!> semidefinite. This version of the algorithm calls level 3 BLAS.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the upper or lower triangular part of the !> symmetric matrix A is stored. !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in,out]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> On entry, the symmetric matrix A. If UPLO = 'U', the leading !> n by n upper triangular part of A contains the upper !> triangular part of the matrix A, and the strictly lower !> triangular part of A is not referenced. If UPLO = 'L', the !> leading n by n lower triangular part of A contains the lower !> triangular part of the matrix A, and the strictly upper !> triangular part of A is not referenced. !> !> On exit, if INFO = 0, the factor U or L from the Cholesky !> factorization as above. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	PIV	!> PIV is INTEGER array, dimension (N) !> PIV is such that the nonzero entries are P( PIV(K), K ) = 1. !>
[out]	RANK	!> RANK is INTEGER !> The rank of A given by the number of steps the algorithm !> completed. !>
[in]	TOL	!> TOL is DOUBLE PRECISION !> User defined tolerance. If TOL < 0, then N*U*MAX( A(K,K) ) !> will be used. The algorithm terminates at the (K-1)st step !> if the pivot <= TOL. !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (2*N) !> Work space. !>
[out]	INFO	!> INFO is INTEGER !> < 0: If INFO = -K, the K-th argument had an illegal value, !> = 0: algorithm completed successfully, and !> > 0: the matrix A is either rank deficient with computed rank !> as returned in RANK, or is not positive semidefinite. See !> Section 7 of LAPACK Working Note #161 for further !> information. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 139 of file zpstrf.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      DOUBLE PRECISION   TOL
      INTEGER            INFO, LDA, N, RANK
      CHARACTER          UPLO
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * )
      DOUBLE PRECISION   WORK( 2*N )
      INTEGER            PIV( N )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
      COMPLEX*16         CONE
      parameter( cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      COMPLEX*16         ZTEMP
      DOUBLE PRECISION   AJJ, DSTOP, DTEMP
      INTEGER            I, ITEMP, J, JB, K, NB, PVT
      LOGICAL            UPPER
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH
      INTEGER            ILAENV
      LOGICAL            LSAME, DISNAN
      EXTERNAL           dlamch, ilaenv, lsame, disnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           zdscal, zgemv, zherk, zlacgv, zpstf2,
     $                   zswap,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dconjg, max, min, sqrt, maxloc
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZPSTRF', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Get block size
*
      nb = ilaenv( 1, 'ZPOTRF', uplo, n, -1, -1, -1 )
      IF( nb.LE.1 .OR. nb.GE.n ) THEN
*
*        Use unblocked code
*
         CALL zpstf2( uplo, n, a( 1, 1 ), lda, piv, rank, tol, work,
     $                info )
         GO TO 230
*
      ELSE
*
*     Initialize PIV
*
         DO 100 i = 1, n
            piv( i ) = i
  100    CONTINUE
*
*     Compute stopping value
*
         DO 110 i = 1, n
            work( i ) = dble( a( i, i ) )
  110    CONTINUE
         pvt = maxloc( work( 1:n ), 1 )
         ajj = dble( a( pvt, pvt ) )
         IF( ajj.LE.zero.OR.disnan( ajj ) ) THEN
            rank = 0
            info = 1
            GO TO 230
         END IF
*
*     Compute stopping value if not supplied
*
         IF( tol.LT.zero ) THEN
            dstop = n * dlamch( 'Epsilon' ) * ajj
         ELSE
            dstop = tol
         END IF
*
*
         IF( upper ) THEN
*
*           Compute the Cholesky factorization P**T * A * P = U**H * U
*
            DO 160 k = 1, n, nb
*
*              Account for last block not being NB wide
*
               jb = min( nb, n-k+1 )
*
*              Set relevant part of first half of WORK to zero,
*              holds dot products
*
               DO 120 i = k, n
                  work( i ) = 0
  120          CONTINUE
*
               DO 150 j = k, k + jb - 1
*
*              Find pivot, test for exit, else swap rows and columns
*              Update dot products, compute possible pivots which are
*              stored in the second half of WORK
*
                  DO 130 i = j, n
*
                     IF( j.GT.k ) THEN
                        work( i ) = work( i ) +
     $                              dble( dconjg( a( j-1, i ) )*
     $                                    a( j-1, i ) )
                     END IF
                     work( n+i ) = dble( a( i, i ) ) - work( i )
*
  130             CONTINUE
*
                  IF( j.GT.1 ) THEN
                     itemp = maxloc( work( (n+j):(2*n) ), 1 )
                     pvt = itemp + j - 1
                     ajj = work( n+pvt )
                     IF( ajj.LE.dstop.OR.disnan( ajj ) ) THEN
                        a( j, j ) = ajj
                        GO TO 220
                     END IF
                  END IF
*
                  IF( j.NE.pvt ) THEN
*
*                    Pivot OK, so can now swap pivot rows and columns
*
                     a( pvt, pvt ) = a( j, j )
                     CALL zswap( j-1, a( 1, j ), 1, a( 1, pvt ), 1 )
                     IF( pvt.LT.n )
     $                  CALL zswap( n-pvt, a( j, pvt+1 ), lda,
     $                              a( pvt, pvt+1 ), lda )
                     DO 140 i = j + 1, pvt - 1
                        ztemp = dconjg( a( j, i ) )
                        a( j, i ) = dconjg( a( i, pvt ) )
                        a( i, pvt ) = ztemp
  140                CONTINUE
                     a( j, pvt ) = dconjg( a( j, pvt ) )
*
*                    Swap dot products and PIV
*
                     dtemp = work( j )
                     work( j ) = work( pvt )
                     work( pvt ) = dtemp
                     itemp = piv( pvt )
                     piv( pvt ) = piv( j )
                     piv( j ) = itemp
                  END IF
*
                  ajj = sqrt( ajj )
                  a( j, j ) = ajj
*
*                 Compute elements J+1:N of row J.
*
                  IF( j.LT.n ) THEN
                     CALL zlacgv( j-1, a( 1, j ), 1 )
                     CALL zgemv( 'Trans', j-k, n-j, -cone, a( k,
     $                           j+1 ),
     $                           lda, a( k, j ), 1, cone, a( j, j+1 ),
     $                           lda )
                     CALL zlacgv( j-1, a( 1, j ), 1 )
                     CALL zdscal( n-j, one / ajj, a( j, j+1 ), lda )
                  END IF
*
  150          CONTINUE
*
*              Update trailing matrix, J already incremented
*
               IF( k+jb.LE.n ) THEN
                  CALL zherk( 'Upper', 'Conj Trans', n-j+1, jb, -one,
     $                        a( k, j ), lda, one, a( j, j ), lda )
               END IF
*
  160       CONTINUE
*
         ELSE
*
*        Compute the Cholesky factorization P**T * A * P = L * L**H
*
            DO 210 k = 1, n, nb
*
*              Account for last block not being NB wide
*
               jb = min( nb, n-k+1 )
*
*              Set relevant part of first half of WORK to zero,
*              holds dot products
*
               DO 170 i = k, n
                  work( i ) = 0
  170          CONTINUE
*
               DO 200 j = k, k + jb - 1
*
*              Find pivot, test for exit, else swap rows and columns
*              Update dot products, compute possible pivots which are
*              stored in the second half of WORK
*
                  DO 180 i = j, n
*
                     IF( j.GT.k ) THEN
                        work( i ) = work( i ) +
     $                              dble( dconjg( a( i, j-1 ) )*
     $                                    a( i, j-1 ) )
                     END IF
                     work( n+i ) = dble( a( i, i ) ) - work( i )
*
  180             CONTINUE
*
                  IF( j.GT.1 ) THEN
                     itemp = maxloc( work( (n+j):(2*n) ), 1 )
                     pvt = itemp + j - 1
                     ajj = work( n+pvt )
                     IF( ajj.LE.dstop.OR.disnan( ajj ) ) THEN
                        a( j, j ) = ajj
                        GO TO 220
                     END IF
                  END IF
*
                  IF( j.NE.pvt ) THEN
*
*                    Pivot OK, so can now swap pivot rows and columns
*
                     a( pvt, pvt ) = a( j, j )
                     CALL zswap( j-1, a( j, 1 ), lda, a( pvt, 1 ),
     $                           lda )
                     IF( pvt.LT.n )
     $                  CALL zswap( n-pvt, a( pvt+1, j ), 1,
     $                              a( pvt+1, pvt ), 1 )
                     DO 190 i = j + 1, pvt - 1
                        ztemp = dconjg( a( i, j ) )
                        a( i, j ) = dconjg( a( pvt, i ) )
                        a( pvt, i ) = ztemp
  190                CONTINUE
                     a( pvt, j ) = dconjg( a( pvt, j ) )
*
*
*                    Swap dot products and PIV
*
                     dtemp = work( j )
                     work( j ) = work( pvt )
                     work( pvt ) = dtemp
                     itemp = piv( pvt )
                     piv( pvt ) = piv( j )
                     piv( j ) = itemp
                  END IF
*
                  ajj = sqrt( ajj )
                  a( j, j ) = ajj
*
*                 Compute elements J+1:N of column J.
*
                  IF( j.LT.n ) THEN
                     CALL zlacgv( j-1, a( j, 1 ), lda )
                     CALL zgemv( 'No Trans', n-j, j-k, -cone,
     $                           a( j+1, k ), lda, a( j, k ), lda, cone,
     $                           a( j+1, j ), 1 )
                     CALL zlacgv( j-1, a( j, 1 ), lda )
                     CALL zdscal( n-j, one / ajj, a( j+1, j ), 1 )
                  END IF
*
  200          CONTINUE
*
*              Update trailing matrix, J already incremented
*
               IF( k+jb.LE.n ) THEN
                  CALL zherk( 'Lower', 'No Trans', n-j+1, jb, -one,
     $                        a( j, k ), lda, one, a( j, j ), lda )
               END IF
*
  210       CONTINUE
*
         END IF
      END IF
*
*     Ran to completion, A has full rank
*
      rank = n
*
      GO TO 230
  220 CONTINUE
*
*     Rank is the number of steps completed.  Set INFO = 1 to signal
*     that the factorization cannot be used to solve a system.
*
      rank = j - 1
      info = 1
*
  230 CONTINUE
      RETURN
*
*     End of ZPSTRF
*

Here is the call graph for this function:

Here is the caller graph for this function: