LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
dpotrf2.f
Go to the documentation of this file.
1 *> \brief \b DPOTRF2
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 * Definition:
9 * ===========
10 *
11 * RECURSIVE SUBROUTINE DPOTRF2( UPLO, N, A, LDA, INFO )
12 *
13 * .. Scalar Arguments ..
14 * CHARACTER UPLO
15 * INTEGER INFO, LDA, N
16 * ..
17 * .. Array Arguments ..
18 * REAL A( LDA, * )
19 * ..
20 *
21 *
22 *> \par Purpose:
23 * =============
24 *>
25 *> \verbatim
26 *>
27 *> DPOTRF2 computes the Cholesky factorization of a real symmetric
28 *> positive definite matrix A using the recursive algorithm.
29 *>
30 *> The factorization has the form
31 *> A = U**T * U, if UPLO = 'U', or
32 *> A = L * L**T, if UPLO = 'L',
33 *> where U is an upper triangular matrix and L is lower triangular.
34 *>
35 *> This is the recursive version of the algorithm. It divides
36 *> the matrix into four submatrices:
37 *>
38 *> [ A11 | A12 ] where A11 is n1 by n1 and A22 is n2 by n2
39 *> A = [ -----|----- ] with n1 = n/2
40 *> [ A21 | A22 ] n2 = n-n1
41 *>
42 *> The subroutine calls itself to factor A11. Update and scale A21
43 *> or A12, update A22 then calls itself to factor A22.
44 *>
45 *> \endverbatim
46 *
47 * Arguments:
48 * ==========
49 *
50 *> \param[in] UPLO
51 *> \verbatim
52 *> UPLO is CHARACTER*1
53 *> = 'U': Upper triangle of A is stored;
54 *> = 'L': Lower triangle of A is stored.
55 *> \endverbatim
56 *>
57 *> \param[in] N
58 *> \verbatim
59 *> N is INTEGER
60 *> The order of the matrix A. N >= 0.
61 *> \endverbatim
62 *>
63 *> \param[in,out] A
64 *> \verbatim
65 *> A is DOUBLE PRECISION array, dimension (LDA,N)
66 *> On entry, the symmetric matrix A. If UPLO = 'U', the leading
67 *> N-by-N upper triangular part of A contains the upper
68 *> triangular part of the matrix A, and the strictly lower
69 *> triangular part of A is not referenced. If UPLO = 'L', the
70 *> leading N-by-N lower triangular part of A contains the lower
71 *> triangular part of the matrix A, and the strictly upper
72 *> triangular part of A is not referenced.
73 *>
74 *> On exit, if INFO = 0, the factor U or L from the Cholesky
75 *> factorization A = U**T*U or A = L*L**T.
76 *> \endverbatim
77 *>
78 *> \param[in] LDA
79 *> \verbatim
80 *> LDA is INTEGER
81 *> The leading dimension of the array A. LDA >= max(1,N).
82 *> \endverbatim
83 *>
84 *> \param[out] INFO
85 *> \verbatim
86 *> INFO is INTEGER
87 *> = 0: successful exit
88 *> < 0: if INFO = -i, the i-th argument had an illegal value
89 *> > 0: if INFO = i, the leading minor of order i is not
90 *> positive definite, and the factorization could not be
91 *> completed.
92 *> \endverbatim
93 *
94 * Authors:
95 * ========
96 *
97 *> \author Univ. of Tennessee
98 *> \author Univ. of California Berkeley
99 *> \author Univ. of Colorado Denver
100 *> \author NAG Ltd.
101 *
102 *> \ingroup doublePOcomputational
103 *
104 * =====================================================================
105  RECURSIVE SUBROUTINE dpotrf2( UPLO, N, A, LDA, INFO )
106 *
107 * -- LAPACK computational routine --
108 * -- LAPACK is a software package provided by Univ. of Tennessee, --
109 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
110 *
111 * .. Scalar Arguments ..
112  CHARACTER uplo
113  INTEGER info, lda, n
114 * ..
115 * .. Array Arguments ..
116  DOUBLE PRECISION a( lda, * )
117 * ..
118 *
119 * =====================================================================
120 *
121 * .. Parameters ..
122  DOUBLE PRECISION one, zero
123  parameter( one = 1.0d+0, zero = 0.0d+0 )
124 * ..
125 * .. Local Scalars ..
126  LOGICAL upper
127  INTEGER n1, n2, iinfo
128 * ..
129 * .. External Functions ..
130  LOGICAL lsame, disnan
131  EXTERNAL lsame, disnan
132 * ..
133 * .. External Subroutines ..
134  EXTERNAL dsyrk, dtrsm, xerbla
135 * ..
136 * .. Intrinsic Functions ..
137  INTRINSIC max, sqrt
138 * ..
139 * .. Executable Statements ..
140 *
141 * Test the input parameters
142 *
143  info = 0
144  upper = lsame( uplo, 'U' )
145  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
146  info = -1
147  ELSE IF( n.LT.0 ) THEN
148  info = -2
149  ELSE IF( lda.LT.max( 1, n ) ) THEN
150  info = -4
151  END IF
152  IF( info.NE.0 ) THEN
153  CALL xerbla( 'DPOTRF2', -info )
154  RETURN
155  END IF
156 *
157 * Quick return if possible
158 *
159  IF( n.EQ.0 )
160  $ RETURN
161 *
162 * N=1 case
163 *
164  IF( n.EQ.1 ) THEN
165 *
166 * Test for non-positive-definiteness
167 *
168  IF( a( 1, 1 ).LE.zero.OR.disnan( a( 1, 1 ) ) ) THEN
169  info = 1
170  RETURN
171  END IF
172 *
173 * Factor
174 *
175  a( 1, 1 ) = sqrt( a( 1, 1 ) )
176 *
177 * Use recursive code
178 *
179  ELSE
180  n1 = n/2
181  n2 = n-n1
182 *
183 * Factor A11
184 *
185  CALL dpotrf2( uplo, n1, a( 1, 1 ), lda, iinfo )
186  IF ( iinfo.NE.0 ) THEN
187  info = iinfo
188  RETURN
189  END IF
190 *
191 * Compute the Cholesky factorization A = U**T*U
192 *
193  IF( upper ) THEN
194 *
195 * Update and scale A12
196 *
197  CALL dtrsm( 'L', 'U', 'T', 'N', n1, n2, one,
198  $ a( 1, 1 ), lda, a( 1, n1+1 ), lda )
199 *
200 * Update and factor A22
201 *
202  CALL dsyrk( uplo, 'T', n2, n1, -one, a( 1, n1+1 ), lda,
203  $ one, a( n1+1, n1+1 ), lda )
204  CALL dpotrf2( uplo, n2, a( n1+1, n1+1 ), lda, iinfo )
205  IF ( iinfo.NE.0 ) THEN
206  info = iinfo + n1
207  RETURN
208  END IF
209 *
210 * Compute the Cholesky factorization A = L*L**T
211 *
212  ELSE
213 *
214 * Update and scale A21
215 *
216  CALL dtrsm( 'R', 'L', 'T', 'N', n2, n1, one,
217  $ a( 1, 1 ), lda, a( n1+1, 1 ), lda )
218 *
219 * Update and factor A22
220 *
221  CALL dsyrk( uplo, 'N', n2, n1, -one, a( n1+1, 1 ), lda,
222  $ one, a( n1+1, n1+1 ), lda )
223  CALL dpotrf2( uplo, n2, a( n1+1, n1+1 ), lda, iinfo )
224  IF ( iinfo.NE.0 ) THEN
225  info = iinfo + n1
226  RETURN
227  END IF
228  END IF
229  END IF
230  RETURN
231 *
232 * End of DPOTRF2
233 *
234  END
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:59
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine dtrsm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
DTRSM
Definition: dtrsm.f:181
subroutine dsyrk(UPLO, TRANS, N, K, ALPHA, A, LDA, BETA, C, LDC)
DSYRK
Definition: dsyrk.f:169
recursive subroutine dpotrf2(UPLO, N, A, LDA, INFO)
DPOTRF2
Definition: dpotrf2.f:106