LAPACK 3.11.0 LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
cungr2.f
Go to the documentation of this file.
1*> \brief \b CUNGR2 generates all or part of the unitary matrix Q from an RQ factorization determined by cgerqf (unblocked algorithm).
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download CUNGR2 + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cungr2.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cungr2.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cungr2.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE CUNGR2( M, N, K, A, LDA, TAU, WORK, INFO )
22*
23* .. Scalar Arguments ..
24* INTEGER INFO, K, LDA, M, N
25* ..
26* .. Array Arguments ..
27* COMPLEX A( LDA, * ), TAU( * ), WORK( * )
28* ..
29*
30*
31*> \par Purpose:
32* =============
33*>
34*> \verbatim
35*>
36*> CUNGR2 generates an m by n complex matrix Q with orthonormal rows,
37*> which is defined as the last m rows of a product of k elementary
38*> reflectors of order n
39*>
40*> Q = H(1)**H H(2)**H . . . H(k)**H
41*>
42*> as returned by CGERQF.
43*> \endverbatim
44*
45* Arguments:
46* ==========
47*
48*> \param[in] M
49*> \verbatim
50*> M is INTEGER
51*> The number of rows of the matrix Q. M >= 0.
52*> \endverbatim
53*>
54*> \param[in] N
55*> \verbatim
56*> N is INTEGER
57*> The number of columns of the matrix Q. N >= M.
58*> \endverbatim
59*>
60*> \param[in] K
61*> \verbatim
62*> K is INTEGER
63*> The number of elementary reflectors whose product defines the
64*> matrix Q. M >= K >= 0.
65*> \endverbatim
66*>
67*> \param[in,out] A
68*> \verbatim
69*> A is COMPLEX array, dimension (LDA,N)
70*> On entry, the (m-k+i)-th row must contain the vector which
71*> defines the elementary reflector H(i), for i = 1,2,...,k, as
72*> returned by CGERQF in the last k rows of its array argument
73*> A.
74*> On exit, the m-by-n matrix Q.
75*> \endverbatim
76*>
77*> \param[in] LDA
78*> \verbatim
79*> LDA is INTEGER
80*> The first dimension of the array A. LDA >= max(1,M).
81*> \endverbatim
82*>
83*> \param[in] TAU
84*> \verbatim
85*> TAU is COMPLEX array, dimension (K)
86*> TAU(i) must contain the scalar factor of the elementary
87*> reflector H(i), as returned by CGERQF.
88*> \endverbatim
89*>
90*> \param[out] WORK
91*> \verbatim
92*> WORK is COMPLEX array, dimension (M)
93*> \endverbatim
94*>
95*> \param[out] INFO
96*> \verbatim
97*> INFO is INTEGER
98*> = 0: successful exit
99*> < 0: if INFO = -i, the i-th argument has an illegal value
100*> \endverbatim
101*
102* Authors:
103* ========
104*
105*> \author Univ. of Tennessee
106*> \author Univ. of California Berkeley
107*> \author Univ. of Colorado Denver
108*> \author NAG Ltd.
109*
110*> \ingroup complexOTHERcomputational
111*
112* =====================================================================
113 SUBROUTINE cungr2( M, N, K, A, LDA, TAU, WORK, INFO )
114*
115* -- LAPACK computational routine --
116* -- LAPACK is a software package provided by Univ. of Tennessee, --
117* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
118*
119* .. Scalar Arguments ..
120 INTEGER INFO, K, LDA, M, N
121* ..
122* .. Array Arguments ..
123 COMPLEX A( LDA, * ), TAU( * ), WORK( * )
124* ..
125*
126* =====================================================================
127*
128* .. Parameters ..
129 COMPLEX ONE, ZERO
130 parameter( one = ( 1.0e+0, 0.0e+0 ),
131 \$ zero = ( 0.0e+0, 0.0e+0 ) )
132* ..
133* .. Local Scalars ..
134 INTEGER I, II, J, L
135* ..
136* .. External Subroutines ..
137 EXTERNAL clacgv, clarf, cscal, xerbla
138* ..
139* .. Intrinsic Functions ..
140 INTRINSIC conjg, max
141* ..
142* .. Executable Statements ..
143*
144* Test the input arguments
145*
146 info = 0
147 IF( m.LT.0 ) THEN
148 info = -1
149 ELSE IF( n.LT.m ) THEN
150 info = -2
151 ELSE IF( k.LT.0 .OR. k.GT.m ) THEN
152 info = -3
153 ELSE IF( lda.LT.max( 1, m ) ) THEN
154 info = -5
155 END IF
156 IF( info.NE.0 ) THEN
157 CALL xerbla( 'CUNGR2', -info )
158 RETURN
159 END IF
160*
161* Quick return if possible
162*
163 IF( m.LE.0 )
164 \$ RETURN
165*
166 IF( k.LT.m ) THEN
167*
168* Initialise rows 1:m-k to rows of the unit matrix
169*
170 DO 20 j = 1, n
171 DO 10 l = 1, m - k
172 a( l, j ) = zero
173 10 CONTINUE
174 IF( j.GT.n-m .AND. j.LE.n-k )
175 \$ a( m-n+j, j ) = one
176 20 CONTINUE
177 END IF
178*
179 DO 40 i = 1, k
180 ii = m - k + i
181*
182* Apply H(i)**H to A(1:m-k+i,1:n-k+i) from the right
183*
184 CALL clacgv( n-m+ii-1, a( ii, 1 ), lda )
185 a( ii, n-m+ii ) = one
186 CALL clarf( 'Right', ii-1, n-m+ii, a( ii, 1 ), lda,
187 \$ conjg( tau( i ) ), a, lda, work )
188 CALL cscal( n-m+ii-1, -tau( i ), a( ii, 1 ), lda )
189 CALL clacgv( n-m+ii-1, a( ii, 1 ), lda )
190 a( ii, n-m+ii ) = one - conjg( tau( i ) )
191*
192* Set A(m-k+i,n-k+i+1:n) to zero
193*
194 DO 30 l = n - m + ii + 1, n
195 a( ii, l ) = zero
196 30 CONTINUE
197 40 CONTINUE
198 RETURN
199*
200* End of CUNGR2
201*
202 END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine cscal(N, CA, CX, INCX)
CSCAL
Definition: cscal.f:78
subroutine clacgv(N, X, INCX)
CLACGV conjugates a complex vector.
Definition: clacgv.f:74
subroutine clarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
CLARF applies an elementary reflector to a general rectangular matrix.
Definition: clarf.f:128
subroutine cungr2(M, N, K, A, LDA, TAU, WORK, INFO)
CUNGR2 generates all or part of the unitary matrix Q from an RQ factorization determined by cgerqf (u...
Definition: cungr2.f:114