pssyntrd()

subroutine pssyntrd	(	character	uplo,
		integer	n,
		real, dimension( * )	a,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		real, dimension( * )	d,
		real, dimension( * )	e,
		real, dimension( * )	tau,
		real, dimension( * )	work,
		integer	lwork,
		integer	info
	)

Definition at line 1 of file pssyntrd.f.

*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 25, 2001
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            IA, INFO, JA, LWORK, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      REAL               A( * ), D( * ), E( * ), TAU( * ), WORK( * )
*     ..
*  Bugs
*  ====
*
*
*  Support for UPLO='U' is limited to calling the old, slow, PSSYTRD
*  code.
*
*
*  Purpose
*  =======
*
*  PSSYNTRD is a prototype version of PSSYTRD which uses tailored
*  codes (either the serial, SSYTRD, or the parallel code, PSSYTTRD)
*  when the workspace provided by the user is adequate.
*
*
*  PSSYNTRD reduces a real symmetric matrix sub( A ) to symmetric
*  tridiagonal form T by an orthogonal similarity transformation:
*  Q' * sub( A ) * Q = T, where sub( A ) = A(IA:IA+N-1,JA:JA+N-1).
*
*  Features
*  ========
*
*  PSSYNTRD is faster than PSSYTRD on almost all matrices,
*  particularly small ones (i.e. N < 500 * sqrt(P) ), provided that
*  enough workspace is available to use the tailored codes.
*
*  The tailored codes provide performance that is essentially
*  independent of the input data layout.
*
*  The tailored codes place no restrictions on IA, JA, MB or NB.
*  At present, IA, JA, MB and NB are restricted to those values allowed
*  by PSSYTRD to keep the interface simple.  These restrictions are
*  documented below.  (Search for "restrictions".)
*
*  Notes
*  =====
*
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*
*  Arguments
*  =========
*
*  UPLO    (global input) CHARACTER
*          Specifies whether the upper or lower triangular part of the
*          symmetric matrix sub( A ) is stored:
*          = 'U':  Upper triangular
*          = 'L':  Lower triangular
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) REAL pointer into the
*          local memory to an array of dimension (LLD_A,LOCc(JA+N-1)).
*          On entry, this array contains the local pieces of the
*          symmetric distributed matrix sub( A ).  If UPLO = 'U', the
*          leading N-by-N upper triangular part of sub( A ) contains
*          the upper triangular part of the matrix, and its strictly
*          lower triangular part is not referenced. If UPLO = 'L', the
*          leading N-by-N lower triangular part of sub( A ) contains the
*          lower triangular part of the matrix, and its strictly upper
*          triangular part is not referenced. On exit, if UPLO = 'U',
*          the diagonal and first superdiagonal of sub( A ) are over-
*          written by the corresponding elements of the tridiagonal
*          matrix T, and the elements above the first superdiagonal,
*          with the array TAU, represent the orthogonal matrix Q as a
*          product of elementary reflectors; if UPLO = 'L', the diagonal
*          and first subdiagonal of sub( A ) are overwritten by the
*          corresponding elements of the tridiagonal matrix T, and the
*          elements below the first subdiagonal, with the array TAU,
*          represent the orthogonal matrix Q as a product of elementary
*          reflectors. See Further Details.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  D       (local output) REAL array, dimension LOCc(JA+N-1)
*          The diagonal elements of the tridiagonal matrix T:
*          D(i) = A(i,i). D is tied to the distributed matrix A.
*
*  E       (local output) REAL array, dimension LOCc(JA+N-1)
*          if UPLO = 'U', LOCc(JA+N-2) otherwise. The off-diagonal
*          elements of the tridiagonal matrix T: E(i) = A(i,i+1) if
*          UPLO = 'U', E(i) = A(i+1,i) if UPLO = 'L'. E is tied to the
*          distributed matrix A.
*
*  TAU     (local output) REAL, array, dimension
*          LOCc(JA+N-1). This array contains the scalar factors TAU of
*          the elementary reflectors. TAU is tied to the distributed
*          matrix A.
*
*  WORK    (local workspace/local output) REAL array,
*                                                  dimension (LWORK)
*          On exit, WORK( 1 ) returns the optimal LWORK.
*
*  LWORK   (local or global input) INTEGER
*          The dimension of the array WORK.
*          LWORK is local input and must be at least
*          LWORK >= MAX( NB * ( NP +1 ), 3 * NB )
*
*          For optimal performance, greater workspace is needed, i.e.
*            LWORK >= 2*( ANB+1 )*( 4*NPS+2 ) + ( NPS + 4 ) * NPS
*            ICTXT = DESCA( CTXT_ )
*            ANB = PJLAENV( ICTXT, 3, 'PSSYTTRD', 'L', 0, 0, 0, 0 )
*            SQNPC = INT( SQRT( REAL( NPROW * NPCOL ) ) )
*            NPS = MAX( NUMROC( N, 1, 0, 0, SQNPC ), 2*ANB )
*
*            NUMROC is a ScaLAPACK tool functions;
*            PJLAENV is a ScaLAPACK envionmental inquiry function
*            MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*            the subroutine BLACS_GRIDINFO.
*
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  Further Details
*  ===============
*
*  If UPLO = 'U', the matrix Q is represented as a product of elementary
*  reflectors
*
*     Q = H(n-1) . . . H(2) H(1).
*
*  Each H(i) has the form
*
*     H(i) = I - tau * v * v'
*
*  where tau is a real scalar, and v is a real vector with
*  v(i+1:n) = 0 and v(i) = 1; v(1:i-1) is stored on exit in
*  A(ia:ia+i-2,ja+i), and tau in TAU(ja+i-1).
*
*  If UPLO = 'L', the matrix Q is represented as a product of elementary
*  reflectors
*
*     Q = H(1) H(2) . . . H(n-1).
*
*  Each H(i) has the form
*
*     H(i) = I - tau * v * v'
*
*  where tau is a real scalar, and v is a real vector with
*  v(1:i) = 0 and v(i+1) = 1; v(i+2:n) is stored on exit in
*  A(ia+i+1:ia+n-1,ja+i-1), and tau in TAU(ja+i-1).
*
*  The contents of sub( A ) on exit are illustrated by the following
*  examples with n = 5:
*
*  if UPLO = 'U':                       if UPLO = 'L':
*
*    (  d   e   v2  v3  v4 )              (  d                  )
*    (      d   e   v3  v4 )              (  e   d              )
*    (          d   e   v4 )              (  v1  e   d          )
*    (              d   e  )              (  v1  v2  e   d      )
*    (                  d  )              (  v1  v2  v3  e   d  )
*
*  where d and e denote diagonal and off-diagonal elements of T, and vi
*  denotes an element of the vector defining H(i).
*
*  Alignment requirements
*  ======================
*
*  The distributed submatrix sub( A ) must verify some alignment proper-
*  ties, namely the following expression should be true:
*  ( MB_A.EQ.NB_A .AND. IROFFA.EQ.ICOFFA .AND. IROFFA.EQ.0 ) with
*  IROFFA = MOD( IA-1, MB_A ) and ICOFFA = MOD( JA-1, NB_A ).
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, DLEN_, DTYPE_, CTXT_, M_, N_,
     $                   MB_, NB_, RSRC_, CSRC_, LLD_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                   ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                   rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               ONE
      parameter( one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, UPPER
      CHARACTER          COLCTOP, ROWCTOP
      INTEGER            ANB, CTXTB, I, IACOL, IAROW, ICOFFA, ICTXT,
     $                   IINFO, INDB, INDD, INDE, INDTAU, INDW, IPW,
     $                   IROFFA, J, JB, JX, K, KK, LLWORK, LWMIN, MINSZ,
     $                   MYCOL, MYCOLB, MYROW, MYROWB, NB, NP, NPCOL,
     $                   NPCOLB, NPROW, NPROWB, NPS, NQ, ONEPMIN, SQNPC,
     $                   TTLWMIN
*     ..
*     .. Local Arrays ..
      INTEGER            DESCB( DLEN_ ), DESCW( DLEN_ ), IDUM1( 2 ),
     $                   IDUM2( 2 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_get, blacs_gridexit, blacs_gridinfo,
     $                   blacs_gridinit, chk1mat, descset, igamn2d,
     $                   pchk1mat, pselset, pslamr1d, pslatrd, pssyr2k,
     $                   pssytd2, pssyttrd, pstrmr2d, pb_topget,
     $                   pb_topset, pxerbla, ssytrd
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            INDXG2L, INDXG2P, NUMROC, PJLAENV
      EXTERNAL           lsame, indxg2l, indxg2p, numroc, pjlaenv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          ichar, int, max, min, mod, real, sqrt
*     ..
*     .. Executable Statements ..
*
*       This is just to keep ftnchek and toolpack/1 happy
      IF( block_cyclic_2d*csrc_*ctxt_*dlen_*dtype_*lld_*mb_*m_*nb_*n_*
     $    rsrc_.LT.0 )RETURN
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -( 600+ctxt_ )
      ELSE
         CALL chk1mat( n, 2, n, 2, ia, ja, desca, 6, info )
         upper = lsame( uplo, 'U' )
         IF( info.EQ.0 ) THEN
            nb = desca( nb_ )
            iroffa = mod( ia-1, desca( mb_ ) )
            icoffa = mod( ja-1, desca( nb_ ) )
            iarow = indxg2p( ia, nb, myrow, desca( rsrc_ ), nprow )
            iacol = indxg2p( ja, nb, mycol, desca( csrc_ ), npcol )
            np = numroc( n, nb, myrow, iarow, nprow )
            nq = max( 1, numroc( n+ja-1, nb, mycol, desca( csrc_ ),
     $           npcol ) )
            lwmin = max( ( np+1 )*nb, 3*nb )
            anb = pjlaenv( ictxt, 3, 'PSSYTTRD', 'L', 0, 0, 0, 0 )
            minsz = pjlaenv( ictxt, 5, 'PSSYTTRD', 'L', 0, 0, 0, 0 )
            sqnpc = int( sqrt( real( nprow*npcol ) ) )
            nps = max( numroc( n, 1, 0, 0, sqnpc ), 2*anb )
            ttlwmin = 2*( anb+1 )*( 4*nps+2 ) + ( nps+4 )*nps
*
            work( 1 ) = real( ttlwmin )
            lquery = ( lwork.EQ.-1 )
            IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
               info = -1
*
*            The following two restrictions are not necessary provided
*            that either of the tailored codes are used.
*
            ELSE IF( iroffa.NE.icoffa .OR. icoffa.NE.0 ) THEN
               info = -5
            ELSE IF( desca( mb_ ).NE.desca( nb_ ) ) THEN
               info = -( 600+nb_ )
            ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
               info = -11
            END IF
         END IF
         IF( upper ) THEN
            idum1( 1 ) = ichar( 'U' )
         ELSE
            idum1( 1 ) = ichar( 'L' )
         END IF
         idum2( 1 ) = 1
         IF( lwork.EQ.-1 ) THEN
            idum1( 2 ) = -1
         ELSE
            idum1( 2 ) = 1
         END IF
         idum2( 2 ) = 11
         CALL pchk1mat( n, 2, n, 2, ia, ja, desca, 6, 2, idum1, idum2,
     $                  info )
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PSSYNTRD', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*
      onepmin = n*n + 3*n + 1
      llwork = lwork
      CALL igamn2d( ictxt, 'A', ' ', 1, 1, llwork, 1, 1, -1, -1, -1,
     $              -1 )
*
*
*
*     Use the serial, LAPACK, code:  STRD on small matrices if we
*     we have enough space.
*
      nprowb = 0
      IF( ( n.LT.minsz .OR. sqnpc.EQ.1 ) .AND. llwork.GE.onepmin .AND.
     $    .NOT.upper ) THEN
         nprowb = 1
         nps = n
      ELSE
         IF( llwork.GE.ttlwmin .AND. .NOT.upper ) THEN
            nprowb = sqnpc
         END IF
      END IF
*
      IF( nprowb.GE.1 ) THEN
         npcolb = nprowb
         sqnpc = nprowb
         indb = 1
         indd = indb + nps*nps
         inde = indd + nps
         indtau = inde + nps
         indw = indtau + nps
         llwork = llwork - indw + 1
*
         CALL blacs_get( ictxt, 10, ctxtb )
         CALL blacs_gridinit( ctxtb, 'Row major', sqnpc, sqnpc )
         CALL blacs_gridinfo( ctxtb, nprowb, npcolb, myrowb, mycolb )
         CALL descset( descb, n, n, 1, 1, 0, 0, ctxtb, nps )
*
         CALL pstrmr2d( uplo, 'N', n, n, a, ia, ja, desca, work( indb ),
     $                  1, 1, descb, ictxt )
*
*
*        Only those processors in context CTXTB are needed for a while
*
         IF( nprowb.GT.0 ) THEN
*
            IF( nprowb.EQ.1 ) THEN
               CALL ssytrd( uplo, n, work( indb ), nps, work( indd ),
     $                      work( inde ), work( indtau ), work( indw ),
     $                      llwork, info )
            ELSE
*
               CALL pssyttrd( 'L', n, work( indb ), 1, 1, descb,
     $                        work( indd ), work( inde ),
     $                        work( indtau ), work( indw ), llwork,
     $                        info )
*
            END IF
         END IF
*
*           All processors participate in moving the data back to the
*           way that PSSYNTRD expects it.
*
         CALL pslamr1d( n-1, work( inde ), 1, 1, descb, e, 1, ja,
     $                  desca )
*
         CALL pslamr1d( n, work( indd ), 1, 1, descb, d, 1, ja, desca )
*
         CALL pslamr1d( n, work( indtau ), 1, 1, descb, tau, 1, ja,
     $                  desca )
*
         CALL pstrmr2d( uplo, 'N', n, n, work( indb ), 1, 1, descb, a,
     $                  ia, ja, desca, ictxt )
*
         IF( myrowb.GE.0 )
     $      CALL blacs_gridexit( ctxtb )
*
      ELSE
*
         CALL pb_topget( ictxt, 'Combine', 'Columnwise', colctop )
         CALL pb_topget( ictxt, 'Combine', 'Rowwise', rowctop )
         CALL pb_topset( ictxt, 'Combine', 'Columnwise', '1-tree' )
         CALL pb_topset( ictxt, 'Combine', 'Rowwise', '1-tree' )
*
         ipw = np*nb + 1
*
         IF( upper ) THEN
*
*        Reduce the upper triangle of sub( A ).
*
            kk = mod( ja+n-1, nb )
            IF( kk.EQ.0 )
     $         kk = nb
            CALL descset( descw, n, nb, nb, nb, iarow,
     $                    indxg2p( ja+n-kk, nb, mycol, desca( csrc_ ),
     $                    npcol ), ictxt, max( 1, np ) )
*
            DO 10 k = n - kk + 1, nb + 1, -nb
               jb = min( n-k+1, nb )
               i = ia + k - 1
               j = ja + k - 1
*
*           Reduce columns I:I+NB-1 to tridiagonal form and form
*           the matrix W which is needed to update the unreduced part of
*           the matrix
*
               CALL pslatrd( uplo, k+jb-1, jb, a, ia, ja, desca, d, e,
     $                       tau, work, 1, 1, descw, work( ipw ) )
*
*           Update the unreduced submatrix A(IA:I-1,JA:J-1), using an
*           update of the form:
*           A(IA:I-1,JA:J-1) := A(IA:I-1,JA:J-1) - V*W' - W*V'
*
               CALL pssyr2k( uplo, 'No transpose', k-1, jb, -one, a, ia,
     $                       j, desca, work, 1, 1, descw, one, a, ia,
     $                       ja, desca )
*
*           Copy last superdiagonal element back into sub( A )
*
               jx = min( indxg2l( j, nb, 0, iacol, npcol ), nq )
               CALL pselset( a, i-1, j, desca, e( jx ) )
*
               descw( csrc_ ) = mod( descw( csrc_ )+npcol-1, npcol )
*
   10       CONTINUE
*
*        Use unblocked code to reduce the last or only block
*
            CALL pssytd2( uplo, min( n, nb ), a, ia, ja, desca, d, e,
     $                    tau, work, lwork, iinfo )
*
         ELSE
*
*        Reduce the lower triangle of sub( A )
*
            kk = mod( ja+n-1, nb )
            IF( kk.EQ.0 )
     $         kk = nb
            CALL descset( descw, n, nb, nb, nb, iarow, iacol, ictxt,
     $                    max( 1, np ) )
*
            DO 20 k = 1, n - nb, nb
               i = ia + k - 1
               j = ja + k - 1
*
*           Reduce columns I:I+NB-1 to tridiagonal form and form
*           the matrix W which is needed to update the unreduced part
*           of the matrix
*
               CALL pslatrd( uplo, n-k+1, nb, a, i, j, desca, d, e, tau,
     $                       work, k, 1, descw, work( ipw ) )
*
*           Update the unreduced submatrix A(I+NB:IA+N-1,I+NB:IA+N-1),
*           using an update of the form: A(I+NB:IA+N-1,I+NB:IA+N-1) :=
*           A(I+NB:IA+N-1,I+NB:IA+N-1) - V*W' - W*V'
*
               CALL pssyr2k( uplo, 'No transpose', n-k-nb+1, nb, -one,
     $                       a, i+nb, j, desca, work, k+nb, 1, descw,
     $                       one, a, i+nb, j+nb, desca )
*
*           Copy last subdiagonal element back into sub( A )
*
               jx = min( indxg2l( j+nb-1, nb, 0, iacol, npcol ), nq )
               CALL pselset( a, i+nb, j+nb-1, desca, e( jx ) )
*
               descw( csrc_ ) = mod( descw( csrc_ )+1, npcol )
*
   20       CONTINUE
*
*        Use unblocked code to reduce the last or only block
*
            CALL pssytd2( uplo, kk, a, ia+k-1, ja+k-1, desca, d, e, tau,
     $                    work, lwork, iinfo )
         END IF
*
         CALL pb_topset( ictxt, 'Combine', 'Columnwise', colctop )
         CALL pb_topset( ictxt, 'Combine', 'Rowwise', rowctop )
*
      END IF
*
      work( 1 ) = real( ttlwmin )
*
      RETURN
*
*     End of PSSYNTRD
*

Here is the call graph for this function:

Here is the caller graph for this function: