numroc.f

Go to the documentation of this file.

      INTEGER FUNCTION numroc( N, NB, IPROC, ISRCPROC, NPROCS )
*
*  -- ScaLAPACK tools routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER              iproc, isrcproc, n, nb, nprocs
*     ..
*
*  Purpose
*  =======
*
*  NUMROC computes the NUMber of Rows Or Columns of a distributed
*  matrix owned by the process indicated by IPROC.
*
*  Arguments
*  =========
*
*  N         (global input) INTEGER
*            The number of rows/columns in distributed matrix.
*
*  NB        (global input) INTEGER
*            Block size, size of the blocks the distributed matrix is
*            split into.
*
*  IPROC     (local input) INTEGER
*            The coordinate of the process whose local array row or
*            column is to be determined.
*
*  ISRCPROC  (global input) INTEGER
*            The coordinate of the process that possesses the first
*            row or column of the distributed matrix.
*
*  NPROCS    (global input) INTEGER
*            The total number processes over which the matrix is
*            distributed.
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER              extrablks, mydist, nblocks
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC            mod
*     ..
*     .. Executable Statements ..
*
*     Figure PROC's distance from source process
*
      mydist = mod( nprocs+iproc-isrcproc, nprocs )
*
*     Figure the total number of whole NB blocks N is split up into
*
      nblocks = n / nb
*
*     Figure the minimum number of rows/cols a process can have
*
      numroc = (nblocks/nprocs) * nb
*
*     See if there are any extra blocks
*
      extrablks = mod( nblocks, nprocs )
*
*     If I have an extra block
*
      IF( mydist.LT.extrablks ) THEN
          numroc = numroc + nb
*
*         If I have last block, it may be a partial block
*
      ELSE IF( mydist.EQ.extrablks ) THEN
          numroc = numroc + mod( n, nb )
      END IF
*
      RETURN
*
*     End of NUMROC
*
      END