pslatrd.f

Go to the documentation of this file.

      SUBROUTINE pslatrd( UPLO, N, NB, A, IA, JA, DESCA, D, E, TAU, W,
     $                    IW, JW, DESCW, WORK )
*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            IA, IW, JA, JW, N, NB
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCW( * )
      REAL               A( * ), D( * ), E( * ), TAU( * ), W( * ),
     $                   work( * )
*     ..
*
*  Purpose
*  =======
*
*  PSLATRD reduces NB rows and columns of a real symmetric distributed
*  matrix sub( A ) = A(IA:IA+N-1,JA:JA+N-1) to symmetric tridiagonal
*  form by an orthogonal similarity transformation Q' * sub( A ) * Q,
*  and returns the matrices V and W which are needed to apply the
*  transformation to the unreduced part of sub( A ).
*
*  If UPLO = 'U', PSLATRD reduces the last NB rows and columns of a
*  matrix, of which the upper triangle is supplied;
*  if UPLO = 'L', PSLATRD reduces the first NB rows and columns of a
*  matrix, of which the lower triangle is supplied.
*
*  This is an auxiliary routine called by PSSYTRD.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  UPLO    (global input) CHARACTER
*          Specifies whether the upper or lower triangular part of the
*          symmetric matrix sub( A ) is stored:
*          = 'U': Upper triangular
*          = 'L': Lower triangular
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix sub( A ). N >= 0.
*
*  NB      (global input) INTEGER
*          The number of rows and columns to be reduced.
*
*  A       (local input/local output) REAL pointer into the
*          local memory to an array of dimension (LLD_A,LOCc(JA+N-1)).
*          On entry, this array contains the local pieces of the
*          symmetric distributed matrix sub( A ).  If UPLO = 'U', the
*          leading N-by-N upper triangular part of sub( A ) contains
*          the upper triangular part of the matrix, and its strictly
*          lower triangular part is not referenced. If UPLO = 'L', the
*          leading N-by-N lower triangular part of sub( A ) contains the
*          lower triangular part of the matrix, and its strictly upper
*          triangular part is not referenced.
*          On exit, if UPLO = 'U', the last NB columns have been reduced
*          to tridiagonal form, with the diagonal elements overwriting
*          the diagonal elements of sub( A ); the elements above the
*          diagonal with the array TAU, represent the orthogonal matrix
*          Q as a product of elementary reflectors. If UPLO = 'L', the
*          first NB columns have been reduced to tridiagonal form, with
*          the diagonal elements overwriting the diagonal elements of
*          sub( A ); the elements below the diagonal with the array TAU,
*          represent the orthogonal matrix Q as a product of elementary
*          reflectors; See Further Details.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  D       (local output) REAL array, dimension LOCc(JA+N-1)
*          The diagonal elements of the tridiagonal matrix T:
*          D(i) = A(i,i). D is tied to the distributed matrix A.
*
*  E       (local output) REAL array, dimension LOCc(JA+N-1)
*          if UPLO = 'U', LOCc(JA+N-2) otherwise. The off-diagonal
*          elements of the tridiagonal matrix T: E(i) = A(i,i+1) if
*          UPLO = 'U', E(i) = A(i+1,i) if UPLO = 'L'. E is tied to the
*          distributed matrix A.
*
*  TAU     (local output) REAL, array, dimension
*          LOCc(JA+N-1). This array contains the scalar factors TAU of
*          the elementary reflectors. TAU is tied to the distributed
*          matrix A.
*
*  W       (local output) REAL pointer into the local memory
*          to an array of dimension (LLD_W,NB_W), This array contains
*          the local pieces of the N-by-NB_W matrix W required to
*          update the unreduced part of sub( A ).
*
*  IW      (global input) INTEGER
*          The row index in the global array W indicating the first
*          row of sub( W ).
*
*  JW      (global input) INTEGER
*          The column index in the global array W indicating the
*          first column of sub( W ).
*
*  DESCW   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix W.
*
*  WORK    (local workspace) REAL array, dimension (NB_A)
*
*  Further Details
*  ===============
*
*  If UPLO = 'U', the matrix Q is represented as a product of elementary
*  reflectors
*
*     Q = H(n) H(n-1) . . . H(n-nb+1).
*
*  Each H(i) has the form
*
*     H(i) = I - tau * v * v'
*
*  where tau is a real scalar, and v is a real vector with
*  v(i:n) = 0 and v(i-1) = 1; v(1:i-1) is stored on exit in
*  A(ia:ia+i-2,ja+i), and tau in TAU(ja+i-1).
*
*  If UPLO = 'L', the matrix Q is represented as a product of elementary
*  reflectors
*
*     Q = H(1) H(2) . . . H(nb).
*
*  Each H(i) has the form
*
*     H(i) = I - tau * v * v'
*
*  where tau is a real scalar, and v is a real vector with
*  v(1:i) = 0 and v(i+1) = 1; v(i+2:n) is stored on exit in
*  A(ia+i+1:ia+n-1,ja+i-1), and tau in TAU(ja+i-1).
*
*  The elements of the vectors v together form the N-by-NB matrix V
*  which is needed, with W, to apply the transformation to the unreduced
*  part of the matrix, using a symmetric rank-2k update of the form:
*  sub( A ) := sub( A ) - V*W' - W*V'.
*
*  The contents of A on exit are illustrated by the following examples
*  with n = 5 and nb = 2:
*
*  if UPLO = 'U':                       if UPLO = 'L':
*
*    (  a   a   a   v4  v5 )              (  d                  )
*    (      a   a   v4  v5 )              (  1   d              )
*    (          a   1   v5 )              (  v1  1   a          )
*    (              d   1  )              (  v1  v2  a   a      )
*    (                  d  )              (  v1  v2  a   a   a  )
*
*  where d denotes a diagonal element of the reduced matrix, a denotes
*  an element of the original matrix that is unchanged, and vi denotes
*  an element of the vector defining H(i).
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               HALF, ONE, ZERO
      parameter( half = 0.5e+0, one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IACOL, IAROW, ICTXT, II, J, JJ, JP, JWK, K,
     $                   kw, mycol, myrow, npcol, nprow, nq
      REAL               ALPHA
*     ..
*     .. Local Arrays ..
      INTEGER            DESCD( DLEN_ ), DESCE( DLEN_ ), DESCWK( DLEN_ )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, descset, infog2l, psaxpy,
     $                   psdot, pselget, pselset, psgemv,
     $                   pslarfg, psscal, pssymv, sgebr2d,
     $                   sgebs2d
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            NUMROC
      EXTERNAL           lsame, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.0 )
     $   RETURN
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
      nq = max( 1, numroc( ja+n-1, desca( nb_ ), mycol, desca( csrc_ ),
     $          npcol ) )
      CALL descset( descd, 1, ja+n-1, 1, desca( nb_ ), myrow,
     $              desca( csrc_ ), desca( ctxt_ ), 1 )
*
      IF( lsame( uplo, 'U' ) ) THEN
*
         CALL infog2l( n+ia-nb, n+ja-nb, desca, nprow, npcol, myrow,
     $                 mycol, ii, jj, iarow, iacol )
         CALL descset( descwk, 1, descw( nb_ ), 1, descw( nb_ ), iarow,
     $                 iacol, ictxt, 1 )
         CALL descset( desce, 1, ja+n-1, 1, desca( nb_ ), myrow,
     $                 desca( csrc_ ), desca( ctxt_ ), 1 )
*
*        Reduce last NB columns of upper triangle
*
         DO 10 j = ja+n-1, ja+n-nb, -1
            i = ia + j - ja
            k = j - ja + 1
            kw = mod( k-1, desca( mb_ ) ) + 1
*
*           Update A(IA:I,I)
*
            CALL psgemv( 'No transpose', k, n-k, -one, a, ia, j+1,
     $                   desca, w, iw+k-1, jw+kw, descw, descw( m_ ),
     $                   one, a, ia, j, desca, 1 )
            CALL psgemv( 'No transpose', k, n-k, -one, w, iw, jw+kw,
     $                   descw, a, i, j+1, desca, desca( m_ ), one, a,
     $                   ia, j, desca, 1 )
            IF( n-k.GT.0 )
     $         CALL pselset( a, i, j+1, desca, e( jp ) )
*
*           Generate elementary reflector H(i) to annihilate
*           A(IA:I-2,I)
*
            jp = min( jj+kw-1, nq )
            CALL pslarfg( k-1, e( jp ), i-1, j, a, ia, j, desca, 1,
     $                    tau )
            CALL pselset( a, i-1, j, desca, one )
*
*           Compute W(IW:IW+K-2,JW+KW-1)
*
            CALL pssymv( 'Upper', k-1, one, a, ia, ja, desca, a, ia, j,
     $                   desca, 1, zero, w, iw, jw+kw-1, descw, 1 )
*
            jwk = mod( k-1, descwk( nb_ ) ) + 2
            CALL psgemv( 'Transpose', k-1, n-k, one, w, iw, jw+kw,
     $                   descw, a, ia, j, desca, 1, zero, work, 1, jwk,
     $                   descwk, descwk( m_ ) )
            CALL psgemv( 'No transpose', k-1, n-k, -one, a, ia, j+1,
     $                   desca, work, 1, jwk, descwk, descwk( m_ ), one,
     $                   w, iw, jw+kw-1, descw, 1 )
            CALL psgemv( 'Transpose', k-1, n-k, one, a, ia, j+1, desca,
     $                   a, ia, j, desca, 1, zero, work, 1, jwk, descwk,
     $                   descwk( m_ ) )
            CALL psgemv( 'No transpose', k-1, n-k, -one, w, iw, jw+kw,
     $                   descw, work, 1, jwk, descwk, descwk( m_ ), one,
     $                   w, iw, jw+kw-1, descw, 1 )
            CALL psscal( k-1, tau( jp ), w, iw, jw+kw-1, descw, 1 )
*
            CALL psdot( k-1, alpha, w, iw, jw+kw-1, descw, 1, a, ia, j,
     $                  desca, 1 )
            IF( mycol.EQ.iacol )
     $         alpha = -half*tau( jp )*alpha
            CALL psaxpy( k-1, alpha, a, ia, j, desca, 1, w, iw, jw+kw-1,
     $                   descw, 1 )
            IF( mycol.EQ.iacol ) THEN
               CALL pselget( 'E', ' ', d( jp ), a, i, j, desca )
            END IF
*
   10    CONTINUE
*
      ELSE
*
         CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, ii,
     $                 jj, iarow, iacol )
         CALL descset( descwk, 1, descw( nb_ ), 1, descw( nb_ ), iarow,
     $                 iacol, ictxt, 1 )
         CALL descset( desce, 1, ja+n-2, 1, desca( nb_ ), myrow,
     $                 desca( csrc_ ), desca( ctxt_ ), 1 )
*
*        Reduce first NB columns of lower triangle
*
         DO 20 j = ja, ja+nb-1
            i = ia + j - ja
            k = j - ja + 1
*
*           Update A(J:JA+N-1,J)
*
            CALL psgemv( 'No transpose', n-k+1, k-1, -one, a, i, ja,
     $                   desca, w, iw+k-1, jw, descw, descw( m_ ), one,
     $                   a, i, j, desca, 1 )
            CALL psgemv( 'No transpose', n-k+1, k-1, -one, w, iw+k-1,
     $                   jw, descw, a, i, ja, desca, desca( m_ ), one,
     $                   a, i, j, desca, 1 )
            IF( k.GT.1 )
     $         CALL pselset( a, i, j-1, desca, e( jp ) )
*
*
*           Generate elementary reflector H(i) to annihilate
*           A(I+2:IA+N-1,I)
*
            jp = min( jj+k-1, nq )
            CALL pslarfg( n-k, e( jp ), i+1, j, a, i+2, j, desca, 1,
     $                    tau )
            CALL pselset( a, i+1, j, desca, one )
*
*           Compute W(IW+K:IW+N-1,JW+K-1)
*
            CALL pssymv( 'Lower', n-k, one, a, i+1, j+1, desca, a, i+1,
     $                   j, desca, 1, zero, w, iw+k, jw+k-1, descw, 1 )
*
            CALL psgemv( 'Transpose', n-k, k-1, one, w, iw+k, jw, descw,
     $                   a, i+1, j, desca, 1, zero, work, 1, 1, descwk,
     $                   descwk( m_ ) )
            CALL psgemv( 'No transpose', n-k, k-1, -one, a, i+1, ja,
     $                  desca, work, 1, 1, descwk, descwk( m_ ), one, w,
     $                  iw+k, jw+k-1, descw, 1 )
            CALL psgemv( 'Transpose', n-k, k-1, one, a, i+1, ja, desca,
     $                  a, i+1, j, desca, 1, zero, work, 1, 1, descwk,
     $                  descwk( m_ ) )
            CALL psgemv( 'No transpose', n-k, k-1, -one, w, iw+k, jw,
     $                  descw, work, 1, 1, descwk, descwk( m_ ), one, w,
     $                  iw+k, jw+k-1, descw, 1 )
            CALL psscal( n-k, tau( jp ), w, iw+k, jw+k-1, descw, 1 )
            CALL psdot( n-k, alpha, w, iw+k, jw+k-1, descw, 1, a, i+1,
     $                  j, desca, 1 )
            IF( mycol.EQ.iacol )
     $         alpha = -half*tau( jp )*alpha
            CALL psaxpy( n-k, alpha, a, i+1, j, desca, 1, w, iw+k,
     $                   jw+k-1, descw, 1 )
            IF( mycol.EQ.iacol ) THEN
               CALL pselget( 'E', ' ', d( jp ), a, i, j, desca )
            END IF
*
   20    CONTINUE
*
      END IF
*
*     Broadcast columnwise the diagonal elements into D.
*
      IF( mycol.EQ.iacol ) THEN
         IF( myrow.EQ.iarow ) THEN
            CALL sgebs2d( ictxt, 'Columnwise', ' ', 1, nb, d( jj ), 1 )
         ELSE
            CALL sgebr2d( ictxt, 'Columnwise', ' ', 1, nb, d( jj ), 1,
     $                    iarow, mycol )
         END IF
      END IF
*
      RETURN
*
*     End of PSLATRD
*
      END