psgerfs.f

Go to the documentation of this file.

      SUBROUTINE psgerfs( TRANS, N, NRHS, A, IA, JA, DESCA, AF, IAF,
     $                    JAF, DESCAF, IPIV, B, IB, JB, DESCB, X, IX,
     $                    JX, DESCX, FERR, BERR, WORK, LWORK, IWORK,
     $                    LIWORK, INFO )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     November 15, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            IA, IAF, IB, IX, INFO, JA, JAF, JB, JX,
     $                   LIWORK, LWORK, N, NRHS
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCAF( * ), DESCB( * ),
     $                   DESCX( * ),IPIV( * ), IWORK( * )
      REAL               A( * ), AF( * ), B( * ), BERR( * ), FERR( * ),
     $                   work( * ), x( * )
*     ..
*
*  Purpose
*  =======
*
*  PSGERFS improves the computed solution to a system of linear
*  equations and provides error bounds and backward error estimates for
*  the solutions.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  In the following comments, sub( A ), sub( X ) and sub( B ) denote
*  respectively A(IA:IA+N-1,JA:JA+N-1), X(IX:IX+N-1,JX:JX+NRHS-1) and
*  B(IB:IB+N-1,JB:JB+NRHS-1).
*
*  Arguments
*  =========
*
*  TRANS   (global input) CHARACTER*1
*          Specifies the form of the system of equations.
*          = 'N': sub( A ) * sub( X ) = sub( B )          (No transpose)
*          = 'T': sub( A )**T * sub( X ) = sub( B )          (Transpose)
*          = 'C': sub( A )**T * sub( X ) = sub( B )
*                                      (Conjugate transpose = Transpose)
*
*
*  N       (global input) INTEGER
*          The order of the matrix sub( A ). N >= 0.
*
*  NRHS    (global input) INTEGER
*          The number of right hand sides, i.e., the number of columns
*          of the matrices sub( B ) and sub( X ).  NRHS >= 0.
*
*  A       (local input) REAL pointer into the local
*          memory to an array of local dimension (LLD_A,LOCc(JA+N-1)).
*          This array contains the local pieces of the distributed
*          matrix sub( A ).
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  AF      (local input) REAL pointer into the local
*          memory to an array of local dimension (LLD_AF,LOCc(JA+N-1)).
*          This array contains the local pieces of the distributed
*          factors of the matrix sub( A ) = P * L * U as computed by
*          PSGETRF.
*
*  IAF     (global input) INTEGER
*          The row index in the global array AF indicating the first
*          row of sub( AF ).
*
*  JAF     (global input) INTEGER
*          The column index in the global array AF indicating the
*          first column of sub( AF ).
*
*  DESCAF  (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix AF.
*
*  IPIV    (local input) INTEGER array of dimension LOCr(M_AF)+MB_AF.
*          This array contains the pivoting information as computed
*          by PSGETRF. IPIV(i) -> The global row local row i
*          was swapped with. This array is tied to the distributed
*          matrix A.
*
*  B       (local input) REAL pointer into the local
*          memory to an array of local dimension
*          (LLD_B,LOCc(JB+NRHS-1)). This array contains the local
*          pieces of the distributed matrix of right hand sides
*          sub( B ).
*
*  IB      (global input) INTEGER
*          The row index in the global array B indicating the first
*          row of sub( B ).
*
*  JB      (global input) INTEGER
*          The column index in the global array B indicating the
*          first column of sub( B ).
*
*  DESCB   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix B.
*
*  X       (local input and output) REAL pointer into the
*          local memory to an array of local dimension
*          (LLD_X,LOCc(JX+NRHS-1)). On entry, this array contains
*          the local pieces of the distributed matrix solution
*          sub( X ). On exit, the improved solution vectors.
*
*  IX      (global input) INTEGER
*          The row index in the global array X indicating the first
*          row of sub( X ).
*
*  JX      (global input) INTEGER
*          The column index in the global array X indicating the
*          first column of sub( X ).
*
*  DESCX   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix X.
*
*  FERR    (local output) REAL array of local dimension
*          LOCc(JB+NRHS-1).
*          The estimated forward error bound for each solution vector
*          of sub( X ).  If XTRUE is the true solution corresponding
*          to sub( X ), FERR is an estimated upper bound for the
*          magnitude of the largest element in (sub( X ) - XTRUE)
*          divided by the magnitude of the largest element in sub( X ).
*          The estimate is as reliable as the estimate for RCOND, and
*          is almost always a slight overestimate of the true error.
*          This array is tied to the distributed matrix X.
*
*  BERR    (local output) REAL array of local dimension
*          LOCc(JB+NRHS-1). The componentwise relative backward
*          error of each solution vector (i.e., the smallest re-
*          lative change in any entry of sub( A ) or sub( B )
*          that makes sub( X ) an exact solution).
*          This array is tied to the distributed matrix X.
*
*  WORK    (local workspace/local output) REAL array,
*                                                   dimension (LWORK)
*          On exit, WORK(1) returns the minimal and optimal LWORK.
*
*  LWORK   (local or global input) INTEGER
*          The dimension of the array WORK.
*          LWORK is local input and must be at least
*          LWORK >= 3*LOCr( N + MOD(IA-1,MB_A) )
*
*          If LWORK = -1, then LWORK is global input and a workspace
*          query is assumed; the routine only calculates the minimum
*          and optimal size for all work arrays. Each of these
*          values is returned in the first entry of the corresponding
*          work array, and no error message is issued by PXERBLA.
*
*  IWORK   (local workspace/local output) INTEGER array,
*                                                  dimension (LIWORK)
*          On exit, IWORK(1) returns the minimal and optimal LIWORK.
*
*  LIWORK  (local or global input) INTEGER
*          The dimension of the array IWORK.
*          LIWORK is local input and must be at least
*          LIWORK >= LOCr( N + MOD(IB-1,MB_B) ).
*
*          If LIWORK = -1, then LIWORK is global input and a workspace
*          query is assumed; the routine only calculates the minimum
*          and optimal size for all work arrays. Each of these
*          values is returned in the first entry of the corresponding
*          work array, and no error message is issued by PXERBLA.
*
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  Internal Parameters
*  ===================
*
*  ITMAX is the maximum number of steps of iterative refinement.
*
*  Notes
*  =====
*
*  This routine temporarily returns when N <= 1.
*
*  The distributed submatrices op( A ) and op( AF ) (respectively
*  sub( X ) and sub( B ) ) should be distributed the same way on the
*  same processes. These conditions ensure that sub( A ) and sub( AF )
*  (resp. sub( X ) and sub( B ) ) are "perfectly" aligned.
*
*  Moreover, this routine requires the distributed submatrices sub( A ),
*  sub( AF ), sub( X ), and sub( B ) to be aligned on a block boundary,
*  i.e., if f(x,y) = MOD( x-1, y ):
*  f( IA, DESCA( MB_ ) ) = f( JA, DESCA( NB_ ) ) = 0,
*  f( IAF, DESCAF( MB_ ) ) = f( JAF, DESCAF( NB_ ) ) = 0,
*  f( IB, DESCB( MB_ ) ) = f( JB, DESCB( NB_ ) ) = 0, and
*  f( IX, DESCX( MB_ ) ) = f( JX, DESCX( NB_ ) ) = 0.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      PARAMETER          ( BLOCK_CYCLIC_2D = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      INTEGER            ITMAX
      PARAMETER          ( ITMAX = 5 )
      real               zero, one
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      REAL               TWO, THREE
      parameter( two = 2.0e+0, three = 3.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, NOTRAN
      CHARACTER          TRANST
      INTEGER            COUNT, IACOL, IAFCOL, IAFROW, IAROW, IXBCOL,
     $                   ixbrow, ixcol, ixrow, icoffa, icoffaf, icoffb,
     $                   icoffx, ictxt, icurcol, idum, ii, iixb, iiw,
     $                   ioffxb, ipb, ipr, ipv, iroffa, iroffaf, iroffb,
     $                   iroffx, iw, j, jbrhs, jj, jjfbe, jjxb, jn, jw,
     $                   k, kase, ldxb, liwmin, lwmin, mycol, myrhs,
     $                   myrow, np, np0, npcol, npmod, nprow, nz
      REAL               EPS, EST, LSTRES, S, SAFE1, SAFE2, SAFMIN
*     ..
*     .. Local Arrays ..
      INTEGER            DESCW( DLEN_ ), IDUM1( 5 ), IDUM2( 5 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICEIL, INDXG2P, NUMROC
      REAL               PSLAMCH
      EXTERNAL           iceil, indxg2p, lsame, numroc, pslamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, descset, infog2l,
     $                   pchk2mat, psagemv, psaxpy, pscopy,
     $                   psgemv, psgetrs, pslacon, pxerbla,
     $                   sgamx2d, sgebr2d, sgebs2d
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, ichar, max, min, mod, real
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters.
*
      notran = lsame( trans, 'N' )
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(700+ctxt_)
      ELSE
         CALL chk1mat( n, 2, n, 2, ia, ja, desca, 7, info )
         CALL chk1mat( n, 2, n, 2, iaf, jaf, descaf, 11, info )
         CALL chk1mat( n, 2, nrhs, 3, ib, jb, descb, 16, info )
         CALL chk1mat( n, 2, nrhs, 3, ix, jx, descx, 20, info )
         IF( info.EQ.0 ) THEN
            iroffa = mod( ia-1, desca( mb_ ) )
            icoffa = mod( ja-1, desca( nb_ ) )
            iroffaf = mod( iaf-1, descaf( mb_ ) )
            icoffaf = mod( jaf-1, descaf( nb_ ) )
            iroffb = mod( ib-1, descb( mb_ ) )
            icoffb = mod( jb-1, descb( nb_ ) )
            iroffx = mod( ix-1, descx( mb_ ) )
            icoffx = mod( jx-1, descx( nb_ ) )
            iarow = indxg2p( ia, desca( mb_ ), myrow, desca( rsrc_ ),
     $                       nprow )
            iafcol = indxg2p( jaf, descaf( nb_ ), mycol,
     $                        descaf( csrc_ ), npcol )
            iafrow = indxg2p( iaf, descaf( mb_ ), myrow,
     $                        descaf( rsrc_ ), nprow )
            iacol = indxg2p( ja, desca( nb_ ), mycol, desca( csrc_ ),
     $                       npcol )
            CALL infog2l( ib, jb, descb, nprow, npcol, myrow, mycol,
     $                    iixb, jjxb, ixbrow, ixbcol )
            ixrow = indxg2p( ix, descx( mb_ ), myrow, descx( rsrc_ ),
     $                       nprow )
            ixcol = indxg2p( jx, descx( nb_ ), mycol, descx( csrc_ ),
     $                       npcol )
            npmod = numroc( n+iroffa, desca( mb_ ), myrow, iarow,
     $                      nprow )
            lwmin = 3 * npmod
            liwmin = npmod
            work( 1 ) = real( lwmin )
            iwork( 1 ) = liwmin
            lquery = ( lwork.EQ.-1 .OR. liwork.EQ.-1 )
*
            IF( ( .NOT.notran ) .AND. ( .NOT.lsame( trans, 'T' ) ) .AND.
     $          ( .NOT.lsame( trans, 'C' ) ) ) THEN
               info = -1
            ELSE IF( n.LT.0 ) THEN
               info = -2
            ELSE IF( nrhs.LT.0 ) THEN
               info = -3
            ELSE IF( iroffa.NE.0 ) THEN
               info = -5
            ELSE IF( icoffa.NE.0 ) THEN
               info = -6
            ELSE IF( desca( mb_ ).NE.desca( nb_ ) ) THEN
               info = -( 700 + nb_ )
            ELSE IF( desca( mb_ ).NE.descaf( mb_ ) ) THEN
               info = -( 1100 + mb_ )
            ELSE IF( iroffaf.NE.0 .OR. iarow.NE.iafrow ) THEN
               info = -9
            ELSE IF( desca( nb_ ).NE.descaf( nb_ ) ) THEN
               info = -( 1100 + nb_ )
            ELSE IF( icoffaf.NE.0 .OR. iacol.NE.iafcol ) THEN
               info = -10
            ELSE IF( ictxt.NE.descaf( ctxt_ ) ) THEN
               info = -( 1100 + ctxt_ )
            ELSE IF( iroffa.NE.iroffb .OR. iarow.NE.ixbrow ) THEN
               info = -14
            ELSE IF( desca( mb_ ).NE.descb( mb_ ) ) THEN
               info = -( 1600 + mb_ )
            ELSE IF( ictxt.NE.descb( ctxt_ ) ) THEN
               info = -( 1600 + ctxt_ )
            ELSE IF( descb( mb_ ).NE.descx( mb_ ) ) THEN
               info = -( 2000 + mb_ )
            ELSE IF( iroffx.NE.0 .OR. ixbrow.NE.ixrow ) THEN
               info = -18
            ELSE IF( descb( nb_ ).NE.descx( nb_ ) ) THEN
               info = -( 2000 + nb_ )
            ELSE IF( icoffb.NE.icoffx .OR. ixbcol.NE.ixcol ) THEN
               info = -19
            ELSE IF( ictxt.NE.descx( ctxt_ ) ) THEN
               info = -( 2000 + ctxt_ )
            ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
               info = -24
            ELSE IF( liwork.LT.liwmin .AND. .NOT.lquery ) THEN
               info = -26
            END IF
         END IF
*
         IF( notran ) THEN
            idum1( 1 ) = ichar( 'N' )
         ELSE IF( lsame( trans, 'T' ) ) THEN
            idum1( 1 ) = ichar( 'T' )
         ELSE
            idum1( 1 ) = ichar( 'C' )
         END IF
         idum2( 1 ) = 1
         idum1( 2 ) = n
         idum2( 2 ) = 2
         idum1( 3 ) = nrhs
         idum2( 3 ) = 3
         IF( lwork.EQ.-1 ) THEN
            idum1( 4 ) = -1
         ELSE
            idum1( 4 ) = 1
         END IF
         idum2( 4 ) = 24
         IF( liwork.EQ.-1 ) THEN
            idum1( 5 ) = -1
         ELSE
            idum1( 5 ) = 1
         END IF
         idum2( 5 ) = 26
         CALL pchk2mat( n, 2, n, 2, ia, ja, desca, 7, n, 2, n, 2, iaf,
     $                  jaf, descaf, 11, 5, idum1, idum2, info )
         CALL pchk2mat( n, 2, nrhs, 3, ib, jb, descb, 16, n, 2, nrhs, 3,
     $                  ix, jx, descx, 20, 5, idum1, idum2, info )
      END IF
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PSGERFS', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
      jjfbe = jjxb
      myrhs = numroc( jb+nrhs-1, descb( nb_ ), mycol, descb( csrc_ ),
     $                npcol )
*
*     Quick return if possible
*
      IF( n.LE.1 .OR. nrhs.EQ.0 ) THEN
         DO 10 jj = jjfbe, myrhs
            ferr( jj ) = zero
            berr( jj ) = zero
   10    CONTINUE
         RETURN
      END IF
*
      IF( notran ) THEN
         transt = 'T'
      ELSE
         transt = 'N'
      END IF
*
      np0 = numroc( n+iroffb, descb( mb_ ), myrow, ixbrow, nprow )
      CALL descset( descw, n+iroffb, 1, desca( mb_ ), 1, ixbrow, ixbcol,
     $              ictxt, max( 1, np0 ) )
      ipb = 1
      ipr = ipb + np0
      ipv = ipr + np0
      IF( myrow.EQ.ixbrow ) THEN
         iiw = 1 + iroffb
         np = np0 - iroffb
      ELSE
         iiw = 1
         np = np0
      END IF
      iw = 1 + iroffb
      jw = 1
      ldxb = descb( lld_ )
      ioffxb = ( jjxb-1 )*ldxb
*
*     NZ = 1 + maximum number of nonzero entries in each row of sub( A )
*
      nz = n + 1
      eps = pslamch( ictxt, 'Epsilon' )
      safmin = pslamch( ictxt, 'Safe minimum' )
      safe1 = nz*safmin
      safe2 = safe1 / eps
      jn = min( iceil( jb, descb( nb_ ) ) * descb( nb_ ), jb+nrhs-1 )
*
*     Handle first block separately
*
      jbrhs = jn - jb + 1
      DO 100 k = 0, jbrhs-1
*
         count = 1
         lstres = three
   20    CONTINUE
*
*        Loop until stopping criterion is satisfied.
*
*        Compute residual R = sub(B) - op(sub(A)) * sub(X),
*        where op(sub(A)) = sub(A), or sub(A)' (A**T or A**H),
*        depending on TRANS.
*
         CALL pscopy( n, b, ib, jb+k, descb, 1, work( ipr ), iw, jw,
     $                descw, 1 )
         CALL psgemv( trans, n, n, -one, a, ia, ja, desca, x, ix,
     $                jx+k, descx, 1, one, work( ipr ), iw, jw,
     $                descw, 1 )
*
*        Compute componentwise relative backward error from formula
*
*        max(i) ( abs(R(i)) / ( abs(op(A))*abs(X) + abs(B) )(i) )
*
*        where abs(Z) is the componentwise absolute value of the
*        matrix or vector Z.  If the i-th component of the
*        denominator is less than SAFE2, then SAFE1 is added to the
*        i-th components of the numerator and denominator before
*        dividing.
*
         IF( mycol.EQ.ixbcol ) THEN
            IF( np.GT.0 ) THEN
               DO 30 ii = iixb, iixb + np - 1
                  work( iiw+ii-iixb ) = abs( b( ii+ioffxb ) )
   30          CONTINUE
            END IF
         END IF
*
         CALL psagemv( trans, n, n, one, a, ia, ja, desca, x, ix, jx+k,
     $                 descx, 1, one, work( ipb ), iw, jw, descw, 1 )
*
         s = zero
         IF( mycol.EQ.ixbcol ) THEN
            IF( np.GT.0 ) THEN
               DO 40 ii = iiw-1, iiw+np-2
                  IF( work( ipb+ii ).GT.safe2 ) THEN
                     s = max( s, abs( work( ipr+ii ) ) /
     $                           work( ipb+ii ) )
                  ELSE
                     s = max( s, ( abs( work( ipr+ii ) )+safe1 ) /
     $                           ( work( ipb+ii )+safe1 ) )
                  END IF
   40          CONTINUE
            END IF
         END IF
*
         CALL sgamx2d( ictxt, 'All', ' ', 1, 1, s, 1, idum, idum, 1,
     $                 -1, mycol )
         IF( mycol.EQ.ixbcol )
     $      berr( jjfbe ) = s
*
*        Test stopping criterion. Continue iterating if
*          1) The residual BERR(J+K) is larger than machine epsilon,
*             and
*          2) BERR(J+K) decreased by at least a factor of 2 during the
*             last iteration, and
*          3) At most ITMAX iterations tried.
*
         IF( s.GT.eps .AND. two*s.LE.lstres .AND. count.LE.itmax ) THEN
*
*           Update solution and try again.
*
            CALL psgetrs( trans, n, 1, af, iaf, jaf, descaf, ipiv,
     $                    work( ipr ), iw, jw, descw, info )
            CALL psaxpy( n, one, work( ipr ), iw, jw, descw, 1, x, ix,
     $                   jx+k, descx, 1 )
            lstres = s
            count = count + 1
            GO TO 20
         END IF
*
*        Bound error from formula
*
*        norm(sub(X) - XTRUE) / norm(sub(X)) .le. FERR =
*        norm( abs(inv(op(sub(A))))*
*            ( abs(R) + NZ*EPS*(
*           abs(op(sub(A)))*abs(sub(X))+abs(sub(B)))))/norm(sub(X))
*
*        where
*          norm(Z) is the magnitude of the largest component of Z
*          inv(op(sub(A))) is the inverse of op(sub(A))
*          abs(Z) is the componentwise absolute value of the matrix
*                 or vector Z
*          NZ is the maximum number of nonzeros in any row of sub(A),
*             plus 1
*          EPS is machine epsilon
*
*        The i-th component of
*            abs(R)+NZ*EPS*(abs(op(sub(A)))*abs(sub(X))+abs(sub(B)))
*        is incremented by SAFE1 if the i-th component of
*        abs(op(sub(A)))*abs(sub(X)) + abs(sub(B)) is less than
*        SAFE2.
*
*        Use PSLACON to estimate the infinity-norm of the matrix
*        inv(op(sub(A))) * diag(W), where
*        W = abs(R)+NZ*EPS*(abs(op(sub(A)))*abs(sub(X))+abs(sub(B))).
*
         IF( mycol.EQ.ixbcol ) THEN
            IF( np.GT.0 ) THEN
               DO 50 ii = iiw-1, iiw+np-2
                  IF( work( ipb+ii ).GT.safe2 ) THEN
                     work( ipb+ii ) = abs( work( ipr+ii ) ) +
     $                                nz*eps*work( ipb+ii )
                  ELSE
                     work( ipb+ii ) = abs( work( ipr+ii ) ) +
     $                                nz*eps*work( ipb+ii ) + safe1
                  END IF
   50          CONTINUE
            END IF
         END IF
*
         kase = 0
   60    CONTINUE
         IF( mycol.EQ.ixbcol ) THEN
            CALL sgebs2d( ictxt, 'Rowwise', ' ', np, 1, work( ipr ),
     $                    descw( lld_ ) )
         ELSE
            CALL sgebr2d( ictxt, 'Rowwise', ' ', np, 1, work( ipr ),
     $                    descw( lld_ ), myrow, ixbcol )
         END IF
         descw( csrc_ ) = mycol
         CALL pslacon( n, work( ipv ), iw, jw, descw, work( ipr ),
     $                 iw, jw, descw, iwork, est, kase )
         descw( csrc_ ) = ixbcol
*
         IF( kase.NE.0 ) THEN
            IF( kase.EQ.1 ) THEN
*
*              Multiply by diag(W)*inv(op(sub(A))').
*
               CALL psgetrs( transt, n, 1, af, iaf, jaf, descaf,
     $                       ipiv, work( ipr ), iw, jw, descw, info )
*
               IF( mycol.EQ.ixbcol ) THEN
                  IF( np.GT.0 ) THEN
                     DO 70 ii = iiw-1, iiw+np-2
                        work( ipr+ii ) = work( ipb+ii )*work( ipr+ii )
   70                CONTINUE
                  END IF
               END IF
            ELSE
*
*              Multiply by inv(op(sub(A)))*diag(W).
*
               IF( mycol.EQ.ixbcol ) THEN
                  IF( np.GT.0 ) THEN
                     DO 80 ii = iiw-1, iiw+np-2
                        work( ipr+ii ) = work( ipb+ii )*work( ipr+ii )
   80                CONTINUE
                  END IF
               END IF
*
               CALL psgetrs( trans, n, 1, af, iaf, jaf, descaf, ipiv,
     $                       work( ipr ), iw, jw, descw, info )
            END IF
            GO TO 60
         END IF
*
*        Normalize error.
*
         lstres = zero
         IF( mycol.EQ.ixbcol ) THEN
            IF( np.GT.0 ) THEN
               DO 90 ii = iixb, iixb+np-1
                  lstres = max( lstres, abs( x( ioffxb+ii ) ) )
   90          CONTINUE
            END IF
            CALL sgamx2d( ictxt, 'Column', ' ', 1, 1, lstres, 1, idum,
     $                    idum, 1, -1, mycol )
            IF( lstres.NE.zero )
     $         ferr( jjfbe ) = est / lstres
*
            jjxb = jjxb + 1
            jjfbe = jjfbe + 1
            ioffxb = ioffxb + ldxb
*
         END IF
*
  100 CONTINUE
*
      icurcol = mod( ixbcol+1, npcol )
*
*     Do for each right hand side
*
      DO 200 j = jn+1, jb+nrhs-1, descb( nb_ )
         jbrhs = min( jb+nrhs-j, descb( nb_ ) )
         descw( csrc_ ) = icurcol
*
         DO 190 k = 0, jbrhs-1
*
            count = 1
            lstres = three
  110       CONTINUE
*
*           Loop until stopping criterion is satisfied.
*
*           Compute residual R = sub(B) - op(sub(A)) * sub(X),
*           where op(sub(A)) = sub(A), or sub(A)' (A**T or A**H),
*           depending on TRANS.
*
            CALL pscopy( n, b, ib, j+k, descb, 1, work( ipr ), iw, jw,
     $                   descw, 1 )
            CALL psgemv( trans, n, n, -one, a, ia, ja, desca, x,
     $                   ix, j+k, descx, 1, one, work( ipr ), iw, jw,
     $                   descw, 1 )
*
*           Compute componentwise relative backward error from formula
*
*           max(i) (abs(R(i))/(abs(op(sub(A)))*abs(sub(X)) +
*                              abs(sub(B)))(i))
*
*           where abs(Z) is the componentwise absolute value of the
*           matrix or vector Z.  If the i-th component of the
*           denominator is less than SAFE2, then SAFE1 is added to the
*           i-th components of the numerator and denominator before
*           dividing.
*
            IF( mycol.EQ.icurcol ) THEN
               IF( np.GT.0 ) THEN
                  DO 120 ii = iixb, iixb+np-1
                     work( iiw+ii-iixb ) = abs( b( ii+ioffxb ) )
  120             CONTINUE
               END IF
            END IF
*
            CALL psagemv( trans, n, n, one, a, ia, ja, desca, x, ix,
     $                    j+k, descx, 1, one, work( ipb ), iw, jw,
     $                    descw, 1 )
*
            s = zero
            IF( mycol.EQ.icurcol ) THEN
               IF( np.GT.0 )THEN
                  DO 130 ii = iiw-1, iiw+np-2
                     IF( work( ipb+ii ).GT.safe2 ) THEN
                        s = max( s, abs( work( ipr+ii ) ) /
     $                              work( ipb+ii ) )
                     ELSE
                        s = max( s, ( abs( work( ipr+ii ) )+safe1 ) /
     $                              ( work( ipb+ii )+safe1 ) )
                     END IF
  130             CONTINUE
               END IF
            END IF
*
            CALL sgamx2d( ictxt, 'All', ' ', 1, 1, s, 1, idum, idum, 1,
     $                    -1, mycol )
            IF( mycol.EQ.icurcol )
     $         berr( jjfbe ) = s
*
*           Test stopping criterion. Continue iterating if
*             1) The residual BERR(J+K) is larger than machine epsilon,
*                and
*             2) BERR(J+K) decreased by at least a factor of 2 during
*                the last iteration, and
*             3) At most ITMAX iterations tried.
*
            IF( s.GT.eps .AND. two*s.LE.lstres .AND.
     $          count.LE.itmax ) THEN
*
*              Update solution and try again.
*
               CALL psgetrs( trans, n, 1, af, iaf, jaf, descaf, ipiv,
     $                       work( ipr ), iw, jw, descw, info )
               CALL psaxpy( n, one, work( ipr ), iw, jw, descw, 1, x,
     $                      ix, j+k, descx, 1 )
               lstres = s
               count = count + 1
               GO TO 110
            END IF
*
*           Bound error from formula
*
*           norm(sub(X) - XTRUE) / norm(sub(X)) .le. FERR =
*           norm( abs(inv(op(sub(A))))*
*               ( abs(R) + NZ*EPS*(
*              abs(op(sub(A)))*abs(sub(X))+abs(sub(B)))))/norm(sub(X))
*
*           where
*             norm(Z) is the magnitude of the largest component of Z
*             inv(op(sub(A))) is the inverse of op(sub(A))
*             abs(Z) is the componentwise absolute value of the matrix
*                or vector Z
*             NZ is the maximum number of nonzeros in any row of sub(A),
*                plus 1
*             EPS is machine epsilon
*
*           The i-th component of
*               abs(R)+NZ*EPS*(abs(op(sub(A)))*abs(sub(X))+abs(sub(B)))
*           is incremented by SAFE1 if the i-th component of
*           abs(op(sub(A)))*abs(sub(X)) + abs(sub(B)) is less than
*           SAFE2.
*
*           Use PSLACON to estimate the infinity-norm of the matrix
*           inv(op(sub(A))) * diag(W), where
*           W = abs(R)+NZ*EPS*(abs(op(sub(A)))*abs(sub(X))+abs(sub(B))).
*
            IF( mycol.EQ.icurcol ) THEN
               IF( np.GT.0 ) THEN
                  DO 140 ii = iiw-1, iiw+np-2
                     IF( work( ipb+ii ).GT.safe2 ) THEN
                        work( ipb+ii ) = abs( work( ipr+ii ) ) +
     $                                   nz*eps*work( ipb+ii )
                     ELSE
                        work( ipb+ii ) = abs( work( ipr+ii ) ) +
     $                                   nz*eps*work( ipb+ii ) + safe1
                     END IF
  140             CONTINUE
               END IF
            END IF
*
            kase = 0
  150       CONTINUE
            IF( mycol.EQ.icurcol ) THEN
               CALL sgebs2d( ictxt, 'Rowwise', ' ', np, 1, work( ipr ),
     $                       descw( lld_ ) )
            ELSE
               CALL sgebr2d( ictxt, 'Rowwise', ' ', np, 1, work( ipr ),
     $                       descw( lld_ ), myrow, icurcol )
            END IF
            descw( csrc_ ) = mycol
            CALL pslacon( n, work( ipv ), iw, jw, descw, work( ipr ),
     $                    iw, jw, descw, iwork, est, kase )
            descw( csrc_ ) = icurcol
*
            IF( kase.NE.0 ) THEN
               IF( kase.EQ.1 ) THEN
*
*                 Multiply by diag(W)*inv(op(sub(A))').
*
                  CALL psgetrs( transt, n, 1, af, iaf, jaf, descaf,
     $                          ipiv, work( ipr ), iw, jw, descw, info )
*
                  IF( mycol.EQ.icurcol ) THEN
                     IF( np.GT.0 ) THEN
                        DO 160 ii = iiw-1, iiw+np-2
                           work( ipr+ii ) = work( ipb+ii )*
     $                                      work( ipr+ii )
  160                   CONTINUE
                     END IF
                  END IF
               ELSE
*
*                 Multiply by inv(op(sub(A)))*diag(W).
*
                  IF( mycol.EQ.icurcol ) THEN
                     IF( np.GT.0 ) THEN
                        DO 170 ii = iiw-1, iiw+np-2
                           work( ipr+ii ) = work( ipb+ii )*
     $                                      work( ipr+ii )
  170                   CONTINUE
                     END IF
                  END IF
*
                  CALL psgetrs( trans, n, 1, af, iaf, jaf, descaf,
     $                          ipiv, work( ipr ), iw, jw, descw,
     $                          info )
               END IF
               GO TO 150
            END IF
*
*           Normalize error.
*
            lstres = zero
            IF( mycol.EQ.icurcol ) THEN
               IF( np.GT.0 ) THEN
                  DO 180 ii = iixb, iixb+np-1
                     lstres = max( lstres, abs( x( ioffxb+ii ) ) )
  180             CONTINUE
               END IF
               CALL sgamx2d( ictxt, 'Column', ' ', 1, 1, lstres,
     $                       1, idum, idum, 1, -1, mycol )
               IF( lstres.NE.zero )
     $            ferr( jjfbe ) = est / lstres
*
               jjxb = jjxb + 1
               jjfbe = jjfbe + 1
               ioffxb = ioffxb + ldxb
*
            END IF
*
  190    CONTINUE
*
         icurcol = mod( icurcol+1, npcol )
*
  200 CONTINUE
*
      work( 1 ) = real( lwmin )
      iwork( 1 ) = liwmin
*
      RETURN
*
*     End of PSGERFS
*
      END