pslacon()

subroutine pslacon	(	integer	n,
		real, dimension( * )	v,
		integer	iv,
		integer	jv,
		integer, dimension( * )	descv,
		real, dimension( * )	x,
		integer	ix,
		integer	jx,
		integer, dimension( * )	descx,
		integer, dimension( * )	isgn,
		real	est,
		integer	kase
	)

Definition at line 1 of file pslacon.f.

*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            IV, IX, JV, JX, KASE, N
      REAL               EST
*     ..
*     .. Array Arguments ..
      INTEGER            DESCV( * ), DESCX( * ), ISGN( * )
      REAL               V( * ), X( * )
*     ..
*
*  Purpose
*  =======
*
*  PSLACON estimates the 1-norm of a square, real distributed matrix A.
*  Reverse communication is used for evaluating matrix-vector products.
*  X and V are aligned with the distributed matrix A, this information
*  is implicitly contained within IV, IX, DESCV, and DESCX.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  N       (global input) INTEGER
*          The length of the distributed vectors V and X.  N >= 0.
*
*  V       (local workspace) REAL pointer into the local
*          memory to an array of dimension LOCr(N+MOD(IV-1,MB_V)). On
*          the final return, V = A*W, where EST = norm(V)/norm(W)
*          (W is not returned).
*
*  IV      (global input) INTEGER
*          The row index in the global array V indicating the first
*          row of sub( V ).
*
*  JV      (global input) INTEGER
*          The column index in the global array V indicating the
*          first column of sub( V ).
*
*  DESCV   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix V.
*
*  X       (local input/local output) REAL pointer into the
*          local memory to an array of dimension
*          LOCr(N+MOD(IX-1,MB_X)). On an intermediate return, X
*          should be overwritten by
*                A * X,   if KASE=1,
*                A' * X,  if KASE=2,
*          PSLACON must be re-called with all the other parameters
*          unchanged.
*
*  IX      (global input) INTEGER
*          The row index in the global array X indicating the first
*          row of sub( X ).
*
*  JX      (global input) INTEGER
*          The column index in the global array X indicating the
*          first column of sub( X ).
*
*  DESCX   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix X.
*
*  ISGN    (local workspace) INTEGER array, dimension
*          LOCr(N+MOD(IX-1,MB_X)). ISGN is aligned with X and V.
*
*
*  EST     (global output) REAL
*          An estimate (a lower bound) for norm(A).
*
*  KASE    (local input/local output) INTEGER
*          On the initial call to PSLACON, KASE should be 0.
*          On an intermediate return, KASE will be 1 or 2, indicating
*          whether X should be overwritten by A * X  or A' * X.
*          On the final return from PSLACON, KASE will again be 0.
*
*  Further Details
*  ===============
*
*  The serial version SLACON has been contributed by Nick Higham,
*  University of Manchester. It was originally named SONEST, dated
*  March 16, 1988.
*
*  Reference: N.J. Higham, "FORTRAN codes for estimating the one-norm of
*  a real or complex matrix, with applications to condition estimation",
*  ACM Trans. Math. Soft., vol. 14, no. 4, pp. 381-396, December 1988.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      INTEGER            ITMAX
      parameter( itmax = 5 )
      REAL               ZERO, ONE, TWO
      parameter( zero = 0.0e+0, one = 1.0e+0, two = 2.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, ICTXT, IFLAG, IIVX, IMAXROW, IOFFVX, IROFF,
     $                   ITER, IVXCOL, IVXROW, J, JLAST, JJVX, JUMP,
     $                   K, MYCOL, MYROW, NP, NPCOL, NPROW
      REAL               ALTSGN, ESTOLD, JLMAX, XMAX
*     ..
*     .. Local Arrays ..
      REAL               WORK( 2 )
      REAL               ESTWORK( 1 )
      REAL               TEMP( 1 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, igsum2d, infog2l, psamax,
     $                   psasum, pselget, sgebr2d,
     $                   sgebs2d, scopy
*     ..
*     .. External Functions ..
      INTEGER            INDXG2L, INDXG2P, INDXL2G, NUMROC
      EXTERNAL           indxg2l, indxg2p, indxl2g, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, mod, nint, real, sign
*     ..
*     .. Save statement ..
      SAVE
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters.
*
      estwork( 1 ) = est
      ictxt = descx( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      CALL infog2l( ix, jx, descx, nprow, npcol, myrow, mycol,
     $              iivx, jjvx, ivxrow, ivxcol )
      IF( mycol.NE.ivxcol )
     $   RETURN
      iroff = mod( ix-1, descx( mb_ ) )
      np = numroc( n+iroff, descx( mb_ ), myrow, ivxrow, nprow )
      IF( myrow.EQ.ivxrow )
     $   np = np - iroff
      ioffvx = iivx + (jjvx-1)*descx( lld_ )
*
      IF( kase.EQ.0 ) THEN
         DO 10 i = ioffvx, ioffvx+np-1
            x( i ) = one / real( n )
   10    CONTINUE
         kase = 1
         jump = 1
         RETURN
      END IF
*
      GO TO ( 20, 40, 70, 110, 140 )jump
*
*     ................ ENTRY   (JUMP = 1)
*     FIRST ITERATION.  X HAS BEEN OVERWRITTEN BY A*X
*
   20 CONTINUE
      IF( n.EQ.1 ) THEN
         IF( myrow.EQ.ivxrow ) THEN
            v( ioffvx ) = x( ioffvx )
            estwork( 1 ) = abs( v( ioffvx ) )
            CALL sgebs2d( ictxt, 'Columnwise', ' ', 1, 1, estwork, 1 )
         ELSE
            CALL sgebr2d( ictxt, 'Columnwise', ' ', 1, 1, estwork, 1,
     $                    ivxrow, mycol )
         END IF
*        ... QUIT
         GO TO 150
      END IF
      CALL psasum( n, estwork( 1 ), x, ix, jx, descx, 1 )
      IF( descx( m_ ).EQ.1 .AND. n.EQ.1 ) THEN
         IF( myrow.EQ.ivxrow ) THEN
            CALL sgebs2d( ictxt, 'Columnwise', ' ', 1, 1, estwork, 1 )
         ELSE
            CALL sgebr2d( ictxt, 'Columnwise', ' ', 1, 1, estwork, 1,
     $                    ivxrow, mycol )
         END IF
      END IF
*
      DO 30 i = ioffvx, ioffvx+np-1
         x( i ) = sign( one, x( i ) )
         isgn( i ) = nint( x( i ) )
   30 CONTINUE
      kase = 2
      jump = 2
      RETURN
*
*     ................ ENTRY   (JUMP = 2)
*     FIRST ITERATION.  X HAS BEEN OVERWRITTEN BY TRANSPOSE(A)*X
*
   40 CONTINUE
      CALL psamax( n, xmax, j, x, ix, jx, descx, 1 )
      IF( descx( m_ ).EQ.1 .AND. n.EQ.1 ) THEN
         IF( myrow.EQ.ivxrow ) THEN
            work( 1 ) = xmax
            work( 2 ) = real( j )
            CALL sgebs2d( ictxt, 'Columnwise', ' ', 2, 1, work, 2 )
         ELSE
            CALL sgebr2d( ictxt, 'Columnwise', ' ', 2, 1, work, 2,
     $                    ivxrow, mycol )
            xmax = work( 1 )
            j = nint( work( 2 ) )
         END IF
      END IF
      iter = 2
*
*     MAIN LOOP - ITERATIONS 2, 3,...,ITMAX
*
   50 CONTINUE
      DO 60 i = ioffvx, ioffvx+np-1
         x( i ) = zero
   60 CONTINUE
      imaxrow = indxg2p( j, descx( mb_ ), myrow, descx( rsrc_ ), nprow )
      IF( myrow.EQ.imaxrow ) THEN
         i = indxg2l( j, descx( mb_ ), myrow, descx( rsrc_ ), nprow )
         x( i ) = one
      END IF
      kase = 1
      jump = 3
      RETURN
*
*     ................ ENTRY   (JUMP = 3)
*     X HAS BEEN OVERWRITTEN BY A*X
*
   70 CONTINUE
      CALL scopy( np, x( ioffvx ), 1, v( ioffvx ), 1 )
      estold = estwork( 1 )
      CALL psasum( n, estwork( 1 ), v, iv, jv, descv, 1 )
      IF( descv( m_ ).EQ.1 .AND. n.EQ.1 ) THEN
         IF( myrow.EQ.ivxrow ) THEN
            CALL sgebs2d( ictxt, 'Columnwise', ' ', 1, 1, estwork, 1 )
         ELSE
            CALL sgebr2d( ictxt, 'Columnwise', ' ', 1, 1, estwork, 1,
     $                    ivxrow, mycol )
         END IF
      END IF
      iflag = 0
      DO 80 i = ioffvx, ioffvx+np-1
         IF( nint( sign( one, x( i ) ) ).NE.isgn( i ) ) THEN
            iflag = 1
            GO TO 90
         END IF
   80 CONTINUE
*
   90 CONTINUE
      CALL igsum2d( ictxt, 'C', ' ', 1, 1, iflag, 1, -1, mycol )
*
*     REPEATED SIGN VECTOR DETECTED, HENCE ALGORITHM HAS CONVERGED.
*     ALONG WITH IT, TEST FOR CYCLING.
*
      IF( iflag.EQ.0 .OR. estwork( 1 ).LE.estold )
     $   GO TO 120
*
      DO 100 i = ioffvx, ioffvx+np-1
         x( i ) = sign( one, x( i ) )
         isgn( i ) = nint( x( i ) )
  100 CONTINUE
      kase = 2
      jump = 4
      RETURN
*
*     ................ ENTRY   (JUMP = 4)
*     X HAS BEEN OVERWRITTEN BY TRANSPOSE(A)*X
*
  110 CONTINUE
      jlast = j
      CALL psamax( n, xmax, j, x, ix, jx, descx, 1 )
      IF( descx( m_ ).EQ.1 .AND. n.EQ.1 ) THEN
         IF( myrow.EQ.ivxrow ) THEN
            work( 1 ) = xmax
            work( 2 ) = real( j )
            CALL sgebs2d( ictxt, 'Columnwise', ' ', 2, 1, work, 2 )
        ELSE
            CALL sgebr2d( ictxt, 'Columnwise', ' ', 2, 1, work, 2,
     $                    ivxrow, mycol )
            xmax = work( 1 )
            j = nint( work( 2 ) )
         END IF
      END IF
      CALL pselget( 'Columnwise', ' ', jlmax, x, jlast, jx, descx )
      IF( ( jlmax.NE.abs( xmax ) ).AND.( iter.LT.itmax ) ) THEN
         iter = iter + 1
         GO TO 50
      END IF
*
*     ITERATION COMPLETE.  FINAL STAGE.
*
  120 CONTINUE
      DO 130 i = ioffvx, ioffvx+np-1
         k = indxl2g( i-ioffvx+iivx, descx( mb_ ), myrow,
     $                descx( rsrc_ ), nprow )-ix+1
         IF( mod( k, 2 ).EQ.0 ) THEN
            altsgn = -one
         ELSE
            altsgn = one
         END IF
         x( i ) = altsgn*( one+real( k-1 ) / real( n-1 ) )
  130 CONTINUE
      kase = 1
      jump = 5
      RETURN
*
*     ................ ENTRY   (JUMP = 5)
*     X HAS BEEN OVERWRITTEN BY A*X
*
  140 CONTINUE
      CALL psasum( n, temp( 1 ), x, ix, jx, descx, 1 )
      IF( descx( m_ ).EQ.1 .AND. n.EQ.1 ) THEN
         IF( myrow.EQ.ivxrow ) THEN
            CALL sgebs2d( ictxt, 'Columnwise', ' ', 1, 1, temp, 1 )
         ELSE
            CALL sgebr2d( ictxt, 'Columnwise', ' ', 1, 1, temp, 1,
     $                    ivxrow, mycol )
         END IF
      END IF
      temp( 1 ) = two*( temp( 1 ) / real( 3*n ) )
      IF( temp( 1 ).GT.estwork( 1 ) ) THEN
         CALL scopy( np, x( ioffvx ), 1, v( ioffvx ), 1 )
         estwork( 1 ) = temp( 1 )
      END IF
*
  150 CONTINUE
      kase = 0
*
      est = estwork( 1 )
      RETURN
*
*     End of PSLACON
*

Here is the call graph for this function:

Here is the caller graph for this function: