zchkpt()

subroutine zchkpt	(	logical, dimension( * )	dotype,
		integer	nn,
		integer, dimension( * )	nval,
		integer	nns,
		integer, dimension( * )	nsval,
		double precision	thresh,
		logical	tsterr,
		complex*16, dimension( * )	a,
		double precision, dimension( * )	d,
		complex*16, dimension( * )	e,
		complex*16, dimension( * )	b,
		complex*16, dimension( * )	x,
		complex*16, dimension( * )	xact,
		complex*16, dimension( * )	work,
		double precision, dimension( * )	rwork,
		integer	nout )

ZCHKPT

Purpose:

!>
!> ZCHKPT tests ZPTTRF, -TRS, -RFS, and -CON
!> 

Parameters

[in]	DOTYPE	!> DOTYPE is LOGICAL array, dimension (NTYPES) !> The matrix types to be used for testing. Matrices of type j !> (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) = !> .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used. !>
[in]	NN	!> NN is INTEGER !> The number of values of N contained in the vector NVAL. !>
[in]	NVAL	!> NVAL is INTEGER array, dimension (NN) !> The values of the matrix dimension N. !>
[in]	NNS	!> NNS is INTEGER !> The number of values of NRHS contained in the vector NSVAL. !>
[in]	NSVAL	!> NSVAL is INTEGER array, dimension (NNS) !> The values of the number of right hand sides NRHS. !>
[in]	THRESH	!> THRESH is DOUBLE PRECISION !> The threshold value for the test ratios. A result is !> included in the output file if RESULT >= THRESH. To have !> every test ratio printed, use THRESH = 0. !>
[in]	TSTERR	!> TSTERR is LOGICAL !> Flag that indicates whether error exits are to be tested. !>
[out]	A	!> A is COMPLEX*16 array, dimension (NMAX*2) !>
[out]	D	!> D is DOUBLE PRECISION array, dimension (NMAX*2) !>
[out]	E	!> E is COMPLEX*16 array, dimension (NMAX*2) !>
[out]	B	!> B is COMPLEX*16 array, dimension (NMAX*NSMAX) !> where NSMAX is the largest entry in NSVAL. !>
[out]	X	!> X is COMPLEX*16 array, dimension (NMAX*NSMAX) !>
[out]	XACT	!> XACT is COMPLEX*16 array, dimension (NMAX*NSMAX) !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension !> (NMAX*max(3,NSMAX)) !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension !> (max(NMAX,2*NSMAX)) !>
[in]	NOUT	!> NOUT is INTEGER !> The unit number for output. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 145 of file zchkpt.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NN, NNS, NOUT
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            NSVAL( * ), NVAL( * )
      DOUBLE PRECISION   D( * ), RWORK( * )
      COMPLEX*16         A( * ), B( * ), E( * ), WORK( * ), X( * ),
     $                   XACT( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
      INTEGER            NTYPES
      parameter( ntypes = 12 )
      INTEGER            NTESTS
      parameter( ntests = 7 )
*     ..
*     .. Local Scalars ..
      LOGICAL            ZEROT
      CHARACTER          DIST, TYPE, UPLO
      CHARACTER*3        PATH
      INTEGER            I, IA, IMAT, IN, INFO, IRHS, IUPLO, IX, IZERO,
     $                   J, K, KL, KU, LDA, MODE, N, NERRS, NFAIL,
     $                   NIMAT, NRHS, NRUN
      DOUBLE PRECISION   AINVNM, ANORM, COND, DMAX, RCOND, RCONDC
*     ..
*     .. Local Arrays ..
      CHARACTER          UPLOS( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      DOUBLE PRECISION   RESULT( NTESTS )
      COMPLEX*16         Z( 3 )
*     ..
*     .. External Functions ..
      INTEGER            IDAMAX
      DOUBLE PRECISION   DGET06, DZASUM, ZLANHT
      EXTERNAL           idamax, dget06, dzasum, zlanht
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, dcopy, dlarnv, dscal,
     $                   zcopy, zdscal, zerrgt, zget04, zlacpy, zlaptm,
     $                   zlarnv, zlatb4, zlatms, zptcon, zptrfs, zptt01,
     $                   zptt02, zptt05, zpttrf, zpttrs
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, max
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 0, 0, 0, 1 / , uplos / 'U', 'L' /
*     ..
*     .. Executable Statements ..
*
      path( 1: 1 ) = 'Zomplex precision'
      path( 2: 3 ) = 'PT'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL zerrgt( path, nout )
      infot = 0
*
      DO 120 in = 1, nn
*
*        Do for each value of N in NVAL.
*
         n = nval( in )
         lda = max( 1, n )
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         DO 110 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( n.GT.0 .AND. .NOT.dotype( imat ) )
     $         GO TO 110
*
*           Set up parameters with ZLATB4.
*
            CALL zlatb4( path, imat, n, n, TYPE, KL, KU, ANORM, MODE,
     $                   COND, DIST )
*
            zerot = imat.GE.8 .AND. imat.LE.10
            IF( imat.LE.6 ) THEN
*
*              Type 1-6:  generate a Hermitian tridiagonal matrix of
*              known condition number in lower triangular band storage.
*
               srnamt = 'ZLATMS'
               CALL zlatms( n, n, dist, iseed, TYPE, RWORK, MODE, COND,
     $                      ANORM, KL, KU, 'B', A, 2, WORK, INFO )
*
*              Check the error code from ZLATMS.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'ZLATMS', info, 0, ' ', n, n, kl,
     $                         ku, -1, imat, nfail, nerrs, nout )
                  GO TO 110
               END IF
               izero = 0
*
*              Copy the matrix to D and E.
*
               ia = 1
               DO 20 i = 1, n - 1
                  d( i ) = dble( a( ia ) )
                  e( i ) = a( ia+1 )
                  ia = ia + 2
   20          CONTINUE
               IF( n.GT.0 )
     $            d( n ) = dble( a( ia ) )
            ELSE
*
*              Type 7-12:  generate a diagonally dominant matrix with
*              unknown condition number in the vectors D and E.
*
               IF( .NOT.zerot .OR. .NOT.dotype( 7 ) ) THEN
*
*                 Let E be complex, D real, with values from [-1,1].
*
                  CALL dlarnv( 2, iseed, n, d )
                  CALL zlarnv( 2, iseed, n-1, e )
*
*                 Make the tridiagonal matrix diagonally dominant.
*
                  IF( n.EQ.1 ) THEN
                     d( 1 ) = abs( d( 1 ) )
                  ELSE
                     d( 1 ) = abs( d( 1 ) ) + abs( e( 1 ) )
                     d( n ) = abs( d( n ) ) + abs( e( n-1 ) )
                     DO 30 i = 2, n - 1
                        d( i ) = abs( d( i ) ) + abs( e( i ) ) +
     $                           abs( e( i-1 ) )
   30                CONTINUE
                  END IF
*
*                 Scale D and E so the maximum element is ANORM.
*
                  ix = idamax( n, d, 1 )
                  dmax = d( ix )
                  CALL dscal( n, anorm / dmax, d, 1 )
                  CALL zdscal( n-1, anorm / dmax, e, 1 )
*
               ELSE IF( izero.GT.0 ) THEN
*
*                 Reuse the last matrix by copying back the zeroed out
*                 elements.
*
                  IF( izero.EQ.1 ) THEN
                     d( 1 ) = dble( z( 2 ) )
                     IF( n.GT.1 )
     $                  e( 1 ) = z( 3 )
                  ELSE IF( izero.EQ.n ) THEN
                     e( n-1 ) = z( 1 )
                     d( n ) = dble( z( 2 ) )
                  ELSE
                     e( izero-1 ) = z( 1 )
                     d( izero ) = dble( z( 2 ) )
                     e( izero ) = z( 3 )
                  END IF
               END IF
*
*              For types 8-10, set one row and column of the matrix to
*              zero.
*
               izero = 0
               IF( imat.EQ.8 ) THEN
                  izero = 1
                  z( 2 ) = d( 1 )
                  d( 1 ) = zero
                  IF( n.GT.1 ) THEN
                     z( 3 ) = e( 1 )
                     e( 1 ) = zero
                  END IF
               ELSE IF( imat.EQ.9 ) THEN
                  izero = n
                  IF( n.GT.1 ) THEN
                     z( 1 ) = e( n-1 )
                     e( n-1 ) = zero
                  END IF
                  z( 2 ) = d( n )
                  d( n ) = zero
               ELSE IF( imat.EQ.10 ) THEN
                  izero = ( n+1 ) / 2
                  IF( izero.GT.1 ) THEN
                     z( 1 ) = e( izero-1 )
                     z( 3 ) = e( izero )
                     e( izero-1 ) = zero
                     e( izero ) = zero
                  END IF
                  z( 2 ) = d( izero )
                  d( izero ) = zero
               END IF
            END IF
*
            CALL dcopy( n, d, 1, d( n+1 ), 1 )
            IF( n.GT.1 )
     $         CALL zcopy( n-1, e, 1, e( n+1 ), 1 )
*
*+    TEST 1
*           Factor A as L*D*L' and compute the ratio
*              norm(L*D*L' - A) / (n * norm(A) * EPS )
*
            CALL zpttrf( n, d( n+1 ), e( n+1 ), info )
*
*           Check error code from ZPTTRF.
*
            IF( info.NE.izero ) THEN
               CALL alaerh( path, 'ZPTTRF', info, izero, ' ', n, n, -1,
     $                      -1, -1, imat, nfail, nerrs, nout )
               GO TO 110
            END IF
*
            IF( info.GT.0 ) THEN
               rcondc = zero
               GO TO 100
            END IF
*
            CALL zptt01( n, d, e, d( n+1 ), e( n+1 ), work,
     $                   result( 1 ) )
*
*           Print the test ratio if greater than or equal to THRESH.
*
            IF( result( 1 ).GE.thresh ) THEN
               IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $            CALL alahd( nout, path )
               WRITE( nout, fmt = 9999 )n, imat, 1, result( 1 )
               nfail = nfail + 1
            END IF
            nrun = nrun + 1
*
*           Compute RCONDC = 1 / (norm(A) * norm(inv(A))
*
*           Compute norm(A).
*
            anorm = zlanht( '1', n, d, e )
*
*           Use ZPTTRS to solve for one column at a time of inv(A),
*           computing the maximum column sum as we go.
*
            ainvnm = zero
            DO 50 i = 1, n
               DO 40 j = 1, n
                  x( j ) = zero
   40          CONTINUE
               x( i ) = one
               CALL zpttrs( 'Lower', n, 1, d( n+1 ), e( n+1 ), x, lda,
     $                      info )
               ainvnm = max( ainvnm, dzasum( n, x, 1 ) )
   50       CONTINUE
            rcondc = one / max( one, anorm*ainvnm )
*
            DO 90 irhs = 1, nns
               nrhs = nsval( irhs )
*
*           Generate NRHS random solution vectors.
*
               ix = 1
               DO 60 j = 1, nrhs
                  CALL zlarnv( 2, iseed, n, xact( ix ) )
                  ix = ix + lda
   60          CONTINUE
*
               DO 80 iuplo = 1, 2
*
*              Do first for UPLO = 'U', then for UPLO = 'L'.
*
                  uplo = uplos( iuplo )
*
*              Set the right hand side.
*
                  CALL zlaptm( uplo, n, nrhs, one, d, e, xact, lda,
     $                         zero, b, lda )
*
*+    TEST 2
*              Solve A*x = b and compute the residual.
*
                  CALL zlacpy( 'Full', n, nrhs, b, lda, x, lda )
                  CALL zpttrs( uplo, n, nrhs, d( n+1 ), e( n+1 ), x,
     $                         lda, info )
*
*              Check error code from ZPTTRS.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'ZPTTRS', info, 0, uplo, n, n,
     $                            -1, -1, nrhs, imat, nfail, nerrs,
     $                            nout )
*
                  CALL zlacpy( 'Full', n, nrhs, b, lda, work, lda )
                  CALL zptt02( uplo, n, nrhs, d, e, x, lda, work, lda,
     $                         result( 2 ) )
*
*+    TEST 3
*              Check solution from generated exact solution.
*
                  CALL zget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                         result( 3 ) )
*
*+    TESTS 4, 5, and 6
*              Use iterative refinement to improve the solution.
*
                  srnamt = 'ZPTRFS'
                  CALL zptrfs( uplo, n, nrhs, d, e, d( n+1 ), e( n+1 ),
     $                         b, lda, x, lda, rwork, rwork( nrhs+1 ),
     $                         work, rwork( 2*nrhs+1 ), info )
*
*              Check error code from ZPTRFS.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'ZPTRFS', info, 0, uplo, n, n,
     $                            -1, -1, nrhs, imat, nfail, nerrs,
     $                            nout )
*
                  CALL zget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                         result( 4 ) )
                  CALL zptt05( n, nrhs, d, e, b, lda, x, lda, xact, lda,
     $                         rwork, rwork( nrhs+1 ), result( 5 ) )
*
*              Print information about the tests that did not pass the
*              threshold.
*
                  DO 70 k = 2, 6
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9998 )uplo, n, nrhs, imat,
     $                     k, result( k )
                        nfail = nfail + 1
                     END IF
   70             CONTINUE
                  nrun = nrun + 5
*
   80          CONTINUE
   90       CONTINUE
*
*+    TEST 7
*           Estimate the reciprocal of the condition number of the
*           matrix.
*
  100       CONTINUE
            srnamt = 'ZPTCON'
            CALL zptcon( n, d( n+1 ), e( n+1 ), anorm, rcond, rwork,
     $                   info )
*
*           Check error code from ZPTCON.
*
            IF( info.NE.0 )
     $         CALL alaerh( path, 'ZPTCON', info, 0, ' ', n, n, -1, -1,
     $                      -1, imat, nfail, nerrs, nout )
*
            result( 7 ) = dget06( rcond, rcondc )
*
*           Print the test ratio if greater than or equal to THRESH.
*
            IF( result( 7 ).GE.thresh ) THEN
               IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $            CALL alahd( nout, path )
               WRITE( nout, fmt = 9999 )n, imat, 7, result( 7 )
               nfail = nfail + 1
            END IF
            nrun = nrun + 1
  110    CONTINUE
  120 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' N =', i5, ', type ', i2, ', test ', i2, ', ratio = ',
     $      g12.5 )
 9998 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', NRHS =', i3,
     $        ', type ', i2, ', test ', i2, ', ratio = ', g12.5 )
      RETURN
*
*     End of ZCHKPT
*

Here is the call graph for this function:

Here is the caller graph for this function: