ScaLAPACK 2.1  2.1 ScaLAPACK: Scalable Linear Algebra PACKage
pzunmqr.f
Go to the documentation of this file.
1  SUBROUTINE pzunmqr( SIDE, TRANS, M, N, K, A, IA, JA, DESCA, TAU,
2  \$ C, IC, JC, DESCC, WORK, LWORK, INFO )
3 *
4 * -- ScaLAPACK routine (version 1.7) --
5 * University of Tennessee, Knoxville, Oak Ridge National Laboratory,
6 * and University of California, Berkeley.
7 * May 25, 2001
8 *
9 * .. Scalar Arguments ..
10  CHARACTER SIDE, TRANS
11  INTEGER IA, IC, INFO, JA, JC, K, LWORK, M, N
12 * ..
13 * .. Array Arguments ..
14  INTEGER DESCA( * ), DESCC( * )
15  COMPLEX*16 A( * ), C( * ), TAU( * ), WORK( * )
16 * ..
17 *
18 * Purpose
19 * =======
20 *
21 * PZUNMQR overwrites the general complex M-by-N distributed matrix
22 * sub( C ) = C(IC:IC+M-1,JC:JC+N-1) with
23 *
24 * SIDE = 'L' SIDE = 'R'
25 * TRANS = 'N': Q * sub( C ) sub( C ) * Q
26 * TRANS = 'C': Q**H * sub( C ) sub( C ) * Q**H
27 *
28 * where Q is a complex unitary distributed matrix defined as the
29 * product of k elementary reflectors
30 *
31 * Q = H(1) H(2) . . . H(k)
32 *
33 * as returned by PZGEQRF. Q is of order M if SIDE = 'L' and of order N
34 * if SIDE = 'R'.
35 *
36 * Notes
37 * =====
38 *
39 * Each global data object is described by an associated description
40 * vector. This vector stores the information required to establish
41 * the mapping between an object element and its corresponding process
42 * and memory location.
43 *
44 * Let A be a generic term for any 2D block cyclicly distributed array.
45 * Such a global array has an associated description vector DESCA.
46 * In the following comments, the character _ should be read as
47 * "of the global array".
48 *
49 * NOTATION STORED IN EXPLANATION
50 * --------------- -------------- --------------------------------------
51 * DTYPE_A(global) DESCA( DTYPE_ )The descriptor type. In this case,
52 * DTYPE_A = 1.
53 * CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
54 * the BLACS process grid A is distribu-
55 * ted over. The context itself is glo-
56 * bal, but the handle (the integer
57 * value) may vary.
58 * M_A (global) DESCA( M_ ) The number of rows in the global
59 * array A.
60 * N_A (global) DESCA( N_ ) The number of columns in the global
61 * array A.
62 * MB_A (global) DESCA( MB_ ) The blocking factor used to distribute
63 * the rows of the array.
64 * NB_A (global) DESCA( NB_ ) The blocking factor used to distribute
65 * the columns of the array.
66 * RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
67 * row of the array A is distributed.
68 * CSRC_A (global) DESCA( CSRC_ ) The process column over which the
69 * first column of the array A is
70 * distributed.
71 * LLD_A (local) DESCA( LLD_ ) The leading dimension of the local
72 * array. LLD_A >= MAX(1,LOCr(M_A)).
73 *
74 * Let K be the number of rows or columns of a distributed matrix,
75 * and assume that its process grid has dimension p x q.
76 * LOCr( K ) denotes the number of elements of K that a process
77 * would receive if K were distributed over the p processes of its
78 * process column.
79 * Similarly, LOCc( K ) denotes the number of elements of K that a
80 * process would receive if K were distributed over the q processes of
81 * its process row.
82 * The values of LOCr() and LOCc() may be determined via a call to the
83 * ScaLAPACK tool function, NUMROC:
84 * LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
85 * LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
86 * An upper bound for these quantities may be computed by:
87 * LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
88 * LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
89 *
90 * Arguments
91 * =========
92 *
93 * SIDE (global input) CHARACTER
94 * = 'L': apply Q or Q**H from the Left;
95 * = 'R': apply Q or Q**H from the Right.
96 *
97 * TRANS (global input) CHARACTER
98 * = 'N': No transpose, apply Q;
99 * = 'C': Conjugate transpose, apply Q**H.
100 *
101 * M (global input) INTEGER
102 * The number of rows to be operated on i.e the number of rows
103 * of the distributed submatrix sub( C ). M >= 0.
104 *
105 * N (global input) INTEGER
106 * The number of columns to be operated on i.e the number of
107 * columns of the distributed submatrix sub( C ). N >= 0.
108 *
109 * K (global input) INTEGER
110 * The number of elementary reflectors whose product defines the
111 * matrix Q. If SIDE = 'L', M >= K >= 0, if SIDE = 'R',
112 * N >= K >= 0.
113 *
114 * A (local input) COMPLEX*16 pointer into the local memory
115 * to an array of dimension (LLD_A,LOCc(JA+K-1)). On entry, the
116 * j-th column must contain the vector which defines the elemen-
117 * tary reflector H(j), JA <= j <= JA+K-1, as returned by
118 * PZGEQRF in the K columns of its distributed matrix
119 * argument A(IA:*,JA:JA+K-1). A(IA:*,JA:JA+K-1) is modified by
120 * the routine but restored on exit.
121 * If SIDE = 'L', LLD_A >= MAX( 1, LOCr(IA+M-1) );
122 * if SIDE = 'R', LLD_A >= MAX( 1, LOCr(IA+N-1) ).
123 *
124 * IA (global input) INTEGER
125 * The row index in the global array A indicating the first
126 * row of sub( A ).
127 *
128 * JA (global input) INTEGER
129 * The column index in the global array A indicating the
130 * first column of sub( A ).
131 *
132 * DESCA (global and local input) INTEGER array of dimension DLEN_.
133 * The array descriptor for the distributed matrix A.
134 *
135 * TAU (local input) COMPLEX*16, array, dimension LOCc(JA+K-1).
136 * This array contains the scalar factors TAU(j) of the
137 * elementary reflectors H(j) as returned by PZGEQRF.
138 * TAU is tied to the distributed matrix A.
139 *
140 * C (local input/local output) COMPLEX*16 pointer into the
141 * local memory to an array of dimension (LLD_C,LOCc(JC+N-1)).
142 * On entry, the local pieces of the distributed matrix sub(C).
143 * On exit, sub( C ) is overwritten by Q*sub( C ) or Q'*sub( C )
144 * or sub( C )*Q' or sub( C )*Q.
145 *
146 * IC (global input) INTEGER
147 * The row index in the global array C indicating the first
148 * row of sub( C ).
149 *
150 * JC (global input) INTEGER
151 * The column index in the global array C indicating the
152 * first column of sub( C ).
153 *
154 * DESCC (global and local input) INTEGER array of dimension DLEN_.
155 * The array descriptor for the distributed matrix C.
156 *
157 * WORK (local workspace/local output) COMPLEX*16 array,
158 * dimension (LWORK)
159 * On exit, WORK(1) returns the minimal and optimal LWORK.
160 *
161 * LWORK (local or global input) INTEGER
162 * The dimension of the array WORK.
163 * LWORK is local input and must be at least
164 * If SIDE = 'L',
165 * LWORK >= MAX( (NB_A*(NB_A-1))/2, (NqC0 + MpC0)*NB_A ) +
166 * NB_A * NB_A
167 * else if SIDE = 'R',
168 * LWORK >= MAX( (NB_A*(NB_A-1))/2, ( NqC0 + MAX( NpA0 +
169 * NUMROC( NUMROC( N+ICOFFC, NB_A, 0, 0, NPCOL ),
170 * NB_A, 0, 0, LCMQ ), MpC0 ) )*NB_A ) +
171 * NB_A * NB_A
172 * end if
173 *
174 * where LCMQ = LCM / NPCOL with LCM = ICLM( NPROW, NPCOL ),
175 *
176 * IROFFA = MOD( IA-1, MB_A ), ICOFFA = MOD( JA-1, NB_A ),
177 * IAROW = INDXG2P( IA, MB_A, MYROW, RSRC_A, NPROW ),
178 * NpA0 = NUMROC( N+IROFFA, MB_A, MYROW, IAROW, NPROW ),
179 *
180 * IROFFC = MOD( IC-1, MB_C ), ICOFFC = MOD( JC-1, NB_C ),
181 * ICROW = INDXG2P( IC, MB_C, MYROW, RSRC_C, NPROW ),
182 * ICCOL = INDXG2P( JC, NB_C, MYCOL, CSRC_C, NPCOL ),
183 * MpC0 = NUMROC( M+IROFFC, MB_C, MYROW, ICROW, NPROW ),
184 * NqC0 = NUMROC( N+ICOFFC, NB_C, MYCOL, ICCOL, NPCOL ),
185 *
186 * ILCM, INDXG2P and NUMROC are ScaLAPACK tool functions;
187 * MYROW, MYCOL, NPROW and NPCOL can be determined by calling
188 * the subroutine BLACS_GRIDINFO.
189 *
190 * If LWORK = -1, then LWORK is global input and a workspace
191 * query is assumed; the routine only calculates the minimum
192 * and optimal size for all work arrays. Each of these
193 * values is returned in the first entry of the corresponding
194 * work array, and no error message is issued by PXERBLA.
195 *
196 *
197 * INFO (global output) INTEGER
198 * = 0: successful exit
199 * < 0: If the i-th argument is an array and the j-entry had
200 * an illegal value, then INFO = -(i*100+j), if the i-th
201 * argument is a scalar and had an illegal value, then
202 * INFO = -i.
203 *
204 * Alignment requirements
205 * ======================
206 *
207 * The distributed submatrices A(IA:*, JA:*) and C(IC:IC+M-1,JC:JC+N-1)
208 * must verify some alignment properties, namely the following
209 * expressions should be true:
210 *
211 * If SIDE = 'L',
212 * ( MB_A.EQ.MB_C .AND. IROFFA.EQ.IROFFC .AND. IAROW.EQ.ICROW )
213 * If SIDE = 'R',
214 * ( MB_A.EQ.NB_C .AND. IROFFA.EQ.ICOFFC )
215 *
216 * =====================================================================
217 *
218 * .. Parameters ..
219  INTEGER BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
220  \$ lld_, mb_, m_, nb_, n_, rsrc_
221  parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
222  \$ ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
223  \$ rsrc_ = 7, csrc_ = 8, lld_ = 9 )
224 * ..
225 * .. Local Scalars ..
226  LOGICAL LEFT, LQUERY, NOTRAN
227  CHARACTER COLBTOP, ROWBTOP
228  INTEGER IAROW, ICC, ICCOL, ICOFFC, ICROW, ICTXT, IINFO,
229  \$ ipw, iroffa, iroffc, j, j1, j2, j3, jb, jcc,
230  \$ lcm, lcmq, lwmin, mi, mpc0, mycol, myrow, ni,
231  \$ npa0, npcol, nprow, nq, nqc0
232 * ..
233 * .. Local Arrays ..
234  INTEGER IDUM1( 4 ), IDUM2( 4 )
235 * ..
236 * .. External Subroutines ..
237  EXTERNAL blacs_gridinfo, chk1mat, pchk2mat, pb_topget,
238  \$ pb_topset, pxerbla, pzlarfb, pzlarft,
239  \$ pzunm2r
240 * ..
241 * .. External Functions ..
242  LOGICAL LSAME
243  INTEGER ICEIL, ILCM, INDXG2P, NUMROC
244  EXTERNAL iceil, ilcm, indxg2p, lsame, numroc
245 * ..
246 * .. Intrinsic Functions ..
247  INTRINSIC dble, dcmplx, ichar, max, min, mod
248 * ..
249 * .. Executable Statements ..
250 *
251 * Get grid parameters
252 *
253  ictxt = desca( ctxt_ )
254  CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
255 *
256 * Test the input parameters
257 *
258  info = 0
259  IF( nprow.EQ.-1 ) THEN
260  info = -(900+ctxt_)
261  ELSE
262  left = lsame( side, 'L' )
263  notran = lsame( trans, 'N' )
264 *
265 * NQ is the order of Q
266 *
267  IF( left ) THEN
268  nq = m
269  CALL chk1mat( m, 3, k, 5, ia, ja, desca, 9, info )
270  ELSE
271  nq = n
272  CALL chk1mat( n, 4, k, 5, ia, ja, desca, 9, info )
273  END IF
274  CALL chk1mat( m, 3, n, 4, ic, jc, descc, 14, info )
275  IF( info.EQ.0 ) THEN
276  iroffa = mod( ia-1, desca( mb_ ) )
277  iroffc = mod( ic-1, descc( mb_ ) )
278  icoffc = mod( jc-1, descc( nb_ ) )
279  iarow = indxg2p( ia, desca( mb_ ), myrow, desca( rsrc_ ),
280  \$ nprow )
281  icrow = indxg2p( ic, descc( mb_ ), myrow, descc( rsrc_ ),
282  \$ nprow )
283  iccol = indxg2p( jc, descc( nb_ ), mycol, descc( csrc_ ),
284  \$ npcol )
285  mpc0 = numroc( m+iroffc, descc( mb_ ), myrow, icrow, nprow )
286  nqc0 = numroc( n+icoffc, descc( nb_ ), mycol, iccol, npcol )
287 *
288  IF( left ) THEN
289  lwmin = max( ( desca( nb_ ) * ( desca( nb_ ) - 1 ) ) / 2,
290  \$ ( mpc0 + nqc0 ) * desca( nb_ ) ) +
291  \$ desca( nb_ ) * desca( nb_ )
292  ELSE
293  npa0 = numroc( n+iroffa, desca( mb_ ), myrow, iarow,
294  \$ nprow )
295  lcm = ilcm( nprow, npcol )
296  lcmq = lcm / npcol
297  lwmin = max( ( desca( nb_ ) * ( desca( nb_ ) - 1 ) )
298  \$ / 2, ( nqc0 + max( npa0 + numroc( numroc(
299  \$ n+icoffc, desca( nb_ ), 0, 0, npcol ),
300  \$ desca( nb_ ), 0, 0, lcmq ), mpc0 ) ) *
301  \$ desca( nb_ ) ) + desca( nb_ ) * desca( nb_ )
302  END IF
303 *
304  work( 1 ) = dcmplx( dble( lwmin ) )
305  lquery = ( lwork.EQ.-1 )
306  IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
307  info = -1
308  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
309  info = -2
310  ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
311  info = -5
312  ELSE IF( .NOT.left .AND. desca( mb_ ).NE.descc( nb_ ) ) THEN
313  info = -(900+nb_)
314  ELSE IF( left .AND. iroffa.NE.iroffc ) THEN
315  info = -12
316  ELSE IF( left .AND. iarow.NE.icrow ) THEN
317  info = -12
318  ELSE IF( .NOT.left .AND. iroffa.NE.icoffc ) THEN
319  info = -13
320  ELSE IF( left .AND. desca( mb_ ).NE.descc( mb_ ) ) THEN
321  info = -(1400+mb_)
322  ELSE IF( ictxt.NE.descc( ctxt_ ) ) THEN
323  info = -(1400+ctxt_)
324  ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
325  info = -16
326  END IF
327  END IF
328 *
329  IF( left ) THEN
330  idum1( 1 ) = ichar( 'L' )
331  ELSE
332  idum1( 1 ) = ichar( 'R' )
333  END IF
334  idum2( 1 ) = 1
335  IF( notran ) THEN
336  idum1( 2 ) = ichar( 'N' )
337  ELSE
338  idum1( 2 ) = ichar( 'C' )
339  END IF
340  idum2( 2 ) = 2
341  idum1( 3 ) = k
342  idum2( 3 ) = 5
343  IF( lwork.EQ.-1 ) THEN
344  idum1( 4 ) = -1
345  ELSE
346  idum1( 4 ) = 1
347  END IF
348  idum2( 4 ) = 16
349  IF( left ) THEN
350  CALL pchk2mat( m, 3, k, 5, ia, ja, desca, 9, m, 3, n, 4, ic,
351  \$ jc, descc, 14, 4, idum1, idum2, info )
352  ELSE
353  CALL pchk2mat( n, 4, k, 5, ia, ja, desca, 9, m, 3, n, 4, ic,
354  \$ jc, descc, 14, 4, idum1, idum2, info )
355  END IF
356  END IF
357 *
358  IF( info.NE.0 ) THEN
359  CALL pxerbla( ictxt, 'PZUNMQR', -info )
360  RETURN
361  ELSE IF( lquery ) THEN
362  RETURN
363  END IF
364 *
365 * Quick return if possible
366 *
367  IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 )
368  \$ RETURN
369 *
370  CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
371  CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
372 *
373  IF( ( left .AND. .NOT.notran ) .OR.
374  \$ ( .NOT.left .AND. notran ) ) THEN
375  j1 = min( iceil( ja, desca( nb_ ) ) * desca( nb_ ), ja+k-1 )
376  \$ + 1
377  j2 = ja+k-1
378  j3 = desca( nb_ )
379  ELSE
380  j1 = max( ( (ja+k-2) / desca( nb_ ) ) * desca( nb_ ) + 1, ja )
381  j2 = min( iceil( ja, desca( nb_ ) ) * desca( nb_ ), ja+k-1 )
382  \$ + 1
383  j3 = -desca( nb_ )
384  END IF
385 *
386  IF( left ) THEN
387  ni = n
388  jcc = jc
389  IF( notran ) THEN
390  CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', 'D-ring' )
391  ELSE
392  CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', 'I-ring' )
393  END IF
394  CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', ' ' )
395  ELSE
396  mi = m
397  icc = ic
398  END IF
399 *
400 * Use unblocked code for the first block if necessary
401 *
402  IF( ( left .AND. .NOT.notran ) .OR. ( .NOT.left .AND. notran ) )
403  \$ CALL pzunm2r( side, trans, m, n, j1-ja, a, ia, ja, desca, tau,
404  \$ c, ic, jc, descc, work, lwork, iinfo )
405 *
406  ipw = desca( nb_ ) * desca( nb_ ) + 1
407  DO 10 j = j1, j2, j3
408  jb = min( desca( nb_ ), k-j+ja )
409 *
410 * Form the triangular factor of the block reflector
411 * H = H(j) H(j+1) . . . H(j+jb-1)
412 *
413  CALL pzlarft( 'Forward', 'Columnwise', nq-j+ja, jb, a,
414  \$ ia+j-ja, j, desca, tau, work, work( ipw ) )
415  IF( left ) THEN
416 *
417 * H or H' is applied to C(ic+j-ja:ic+m-1,jc:jc+n-1)
418 *
419  mi = m - j + ja
420  icc = ic + j - ja
421  ELSE
422 *
423 * H or H' is applied to C(ic:ic+m-1,jc+j-ja:jc+n-1)
424 *
425  ni = n - j + ja
426  jcc = jc + j - ja
427  END IF
428 *
429 * Apply H or H'
430 *
431  CALL pzlarfb( side, trans, 'Forward', 'Columnwise', mi, ni,
432  \$ jb, a, ia+j-ja, j, desca, work, c, icc, jcc,
433  \$ descc, work( ipw ) )
434  10 CONTINUE
435 *
436 * Use unblocked code for the last block if necessary
437 *
438  IF( ( left .AND. notran ) .OR. ( .NOT.left .AND. .NOT.notran ) )
439  \$ CALL pzunm2r( side, trans, m, n, j2-ja, a, ia, ja, desca, tau,
440  \$ c, ic, jc, descc, work, lwork, iinfo )
441 *
442  CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
443  CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
444 *
445  work( 1 ) = dcmplx( dble( lwmin ) )
446 *
447  RETURN
448 *
449 * End of PZUNMQR
450 *
451  END
pzlarfb
subroutine pzlarfb(SIDE, TRANS, DIRECT, STOREV, M, N, K, V, IV, JV, DESCV, T, C, IC, JC, DESCC, WORK)
Definition: pzlarfb.f:3
max
#define max(A, B)
Definition: pcgemr.c:180
pzunmqr
subroutine pzunmqr(SIDE, TRANS, M, N, K, A, IA, JA, DESCA, TAU, C, IC, JC, DESCC, WORK, LWORK, INFO)
Definition: pzunmqr.f:3
pchk2mat
subroutine pchk2mat(MA, MAPOS0, NA, NAPOS0, IA, JA, DESCA, DESCAPOS0, MB, MBPOS0, NB, NBPOS0, IB, JB, DESCB, DESCBPOS0, NEXTRA, EX, EXPOS, INFO)
Definition: pchkxmat.f:175
pzunm2r
subroutine pzunm2r(SIDE, TRANS, M, N, K, A, IA, JA, DESCA, TAU, C, IC, JC, DESCC, WORK, LWORK, INFO)
Definition: pzunm2r.f:3
chk1mat
subroutine chk1mat(MA, MAPOS0, NA, NAPOS0, IA, JA, DESCA, DESCAPOS0, INFO)
Definition: chk1mat.f:3
pzlarft
subroutine pzlarft(DIRECT, STOREV, N, K, V, IV, JV, DESCV, TAU, T, WORK)
Definition: pzlarft.f:3
pxerbla
subroutine pxerbla(ICTXT, SRNAME, INFO)
Definition: pxerbla.f:2
min
#define min(A, B)
Definition: pcgemr.c:181