pdormqr()

subroutine pdormqr	(	character	side,
		character	trans,
		integer	m,
		integer	n,
		integer	k,
		double precision, dimension( * )	a,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		double precision, dimension( * )	tau,
		double precision, dimension( * )	c,
		integer	ic,
		integer	jc,
		integer, dimension( * )	descc,
		double precision, dimension( * )	work,
		integer	lwork,
		integer	info
	)

Definition at line 1 of file pdormqr.f.

*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 25, 2001
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE, TRANS
      INTEGER            IA, IC, INFO, JA, JC, K, LWORK, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCC( * )
      DOUBLE PRECISION   A( * ), C( * ), TAU( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PDORMQR overwrites the general real M-by-N distributed matrix
*  sub( C ) = C(IC:IC+M-1,JC:JC+N-1) with
*
*                      SIDE = 'L'            SIDE = 'R'
*  TRANS = 'N':      Q * sub( C )          sub( C ) * Q
*  TRANS = 'T':      Q**T * sub( C )       sub( C ) * Q**T
*
*  where Q is a real orthogonal distributed matrix defined as the
*  product of k elementary reflectors
*
*        Q = H(1) H(2) . . . H(k)
*
*  as returned by PDGEQRF. Q is of order M if SIDE = 'L' and of order N
*  if SIDE = 'R'.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  SIDE    (global input) CHARACTER
*          = 'L': apply Q or Q**T from the Left;
*          = 'R': apply Q or Q**T from the Right.
*
*  TRANS   (global input) CHARACTER
*          = 'N':  No transpose, apply Q;
*          = 'T':  Transpose, apply Q**T.
*
*  M       (global input) INTEGER
*          The number of rows to be operated on i.e the number of rows
*          of the distributed submatrix sub( C ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on i.e the number of
*          columns of the distributed submatrix sub( C ). N >= 0.
*
*  K       (global input) INTEGER
*          The number of elementary reflectors whose product defines the
*          matrix Q.  If SIDE = 'L', M >= K >= 0, if SIDE = 'R',
*          N >= K >= 0.
*
*  A       (local input) DOUBLE PRECISION pointer into the local memory
*          to an array of dimension (LLD_A,LOCc(JA+K-1)). On entry, the
*          j-th column must contain the vector which defines the elemen-
*          tary reflector H(j), JA <= j <= JA+K-1, as returned by
*          PDGEQRF in the K columns of its distributed matrix
*          argument A(IA:*,JA:JA+K-1). A(IA:*,JA:JA+K-1) is modified by
*          the routine but restored on exit.
*          If SIDE = 'L', LLD_A >= MAX( 1, LOCr(IA+M-1) );
*          if SIDE = 'R', LLD_A >= MAX( 1, LOCr(IA+N-1) ).
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  TAU     (local input) DOUBLE PRECISION array, dimension LOCc(JA+K-1).
*          This array contains the scalar factors TAU(j) of the
*          elementary reflectors H(j) as returned by PDGEQRF.
*          TAU is tied to the distributed matrix A.
*
*  C       (local input/local output) DOUBLE PRECISION pointer into the
*          local memory to an array of dimension (LLD_C,LOCc(JC+N-1)).
*          On entry, the local pieces of the distributed matrix sub(C).
*          On exit, sub( C ) is overwritten by Q*sub( C ) or Q'*sub( C )
*          or sub( C )*Q' or sub( C )*Q.
*
*  IC      (global input) INTEGER
*          The row index in the global array C indicating the first
*          row of sub( C ).
*
*  JC      (global input) INTEGER
*          The column index in the global array C indicating the
*          first column of sub( C ).
*
*  DESCC   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix C.
*
*  WORK    (local workspace/local output) DOUBLE PRECISION array,
*                                                     dimension (LWORK)
*          On exit, WORK(1) returns the minimal and optimal LWORK.
*
*  LWORK   (local or global input) INTEGER
*          The dimension of the array WORK.
*          LWORK is local input and must be at least
*          If SIDE = 'L',
*            LWORK >= MAX( (NB_A*(NB_A-1))/2, (NqC0 + MpC0)*NB_A ) +
*                     NB_A * NB_A
*          else if SIDE = 'R',
*            LWORK >= MAX( (NB_A*(NB_A-1))/2, ( NqC0 + MAX( NpA0 +
*                     NUMROC( NUMROC( N+ICOFFC, NB_A, 0, 0, NPCOL ),
*                             NB_A, 0, 0, LCMQ ), MpC0 ) )*NB_A ) +
*                     NB_A * NB_A
*          end if
*
*          where LCMQ = LCM / NPCOL with LCM = ICLM( NPROW, NPCOL ),
*
*          IROFFA = MOD( IA-1, MB_A ), ICOFFA = MOD( JA-1, NB_A ),
*          IAROW = INDXG2P( IA, MB_A, MYROW, RSRC_A, NPROW ),
*          NpA0 = NUMROC( N+IROFFA, MB_A, MYROW, IAROW, NPROW ),
*
*          IROFFC = MOD( IC-1, MB_C ), ICOFFC = MOD( JC-1, NB_C ),
*          ICROW = INDXG2P( IC, MB_C, MYROW, RSRC_C, NPROW ),
*          ICCOL = INDXG2P( JC, NB_C, MYCOL, CSRC_C, NPCOL ),
*          MpC0 = NUMROC( M+IROFFC, MB_C, MYROW, ICROW, NPROW ),
*          NqC0 = NUMROC( N+ICOFFC, NB_C, MYCOL, ICCOL, NPCOL ),
*
*          ILCM, INDXG2P and NUMROC are ScaLAPACK tool functions;
*          MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*          the subroutine BLACS_GRIDINFO.
*
*          If LWORK = -1, then LWORK is global input and a workspace
*          query is assumed; the routine only calculates the minimum
*          and optimal size for all work arrays. Each of these
*          values is returned in the first entry of the corresponding
*          work array, and no error message is issued by PXERBLA.
*
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  Alignment requirements
*  ======================
*
*  The distributed submatrices A(IA:*, JA:*) and C(IC:IC+M-1,JC:JC+N-1)
*  must verify some alignment properties, namely the following
*  expressions should be true:
*
*  If SIDE = 'L',
*    ( MB_A.EQ.MB_C .AND. IROFFA.EQ.IROFFC .AND. IAROW.EQ.ICROW )
*  If SIDE = 'R',
*    ( MB_A.EQ.NB_C .AND. IROFFA.EQ.ICOFFC )
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LEFT, LQUERY, NOTRAN
      CHARACTER          COLBTOP, ROWBTOP
      INTEGER            IAROW, ICC, ICCOL, ICOFFC, ICROW, ICTXT, IINFO,
     $                   IPW, IROFFA, IROFFC, J, J1, J2, J3, JB, JCC,
     $                   LCM, LCMQ, LWMIN, MI, MPC0, MYCOL, MYROW, NI,
     $                   NPA0, NPCOL, NPROW, NQ, NQC0
*     ..
*     .. Local Arrays ..
      INTEGER            IDUM1( 4 ), IDUM2( 4 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, pchk2mat, pdlarfb,
     $                   pdlarft, pdorm2r, pb_topget, pb_topset, pxerbla
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICEIL, ILCM, INDXG2P, NUMROC
      EXTERNAL           iceil, ilcm, indxg2p, lsame, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, ichar, max, min, mod
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(900+ctxt_)
      ELSE
         left = lsame( side, 'L' )
         notran = lsame( trans, 'N' )
*
*        NQ is the order of Q
*
         IF( left ) THEN
            nq = m
            CALL chk1mat( m, 3, k, 5, ia, ja, desca, 9, info )
         ELSE
            nq = n
            CALL chk1mat( n, 4, k, 5, ia, ja, desca, 9, info )
         END IF
         CALL chk1mat( m, 3, n, 4, ic, jc, descc, 14, info )
         IF( info.EQ.0 ) THEN
            iroffa = mod( ia-1, desca( mb_ ) )
            iroffc = mod( ic-1, descc( mb_ ) )
            icoffc = mod( jc-1, descc( nb_ ) )
            iarow = indxg2p( ia, desca( mb_ ), myrow, desca( rsrc_ ),
     $                       nprow )
            icrow = indxg2p( ic, descc( mb_ ), myrow, descc( rsrc_ ),
     $                       nprow )
            iccol = indxg2p( jc, descc( nb_ ), mycol, descc( csrc_ ),
     $                       npcol )
            mpc0 = numroc( m+iroffc, descc( mb_ ), myrow, icrow, nprow )
            nqc0 = numroc( n+icoffc, descc( nb_ ), mycol, iccol, npcol )
*
            IF( left ) THEN
               lwmin = max( ( desca( nb_ ) * ( desca( nb_ ) - 1 ) ) / 2,
     $                      ( mpc0 + nqc0 ) * desca( nb_ ) ) +
     $                 desca( nb_ ) * desca( nb_ )
            ELSE
               npa0 = numroc( n+iroffa, desca( mb_ ), myrow, iarow,
     $                        nprow )
               lcm = ilcm( nprow, npcol )
               lcmq = lcm / npcol
               lwmin =  max( ( desca( nb_ ) * ( desca( nb_ ) - 1 ) )
     $                  / 2, ( nqc0 + max( npa0 + numroc( numroc(
     $                  n+icoffc, desca( nb_ ), 0, 0, npcol ),
     $                  desca( nb_ ), 0, 0, lcmq ), mpc0 ) ) *
     $                  desca( nb_ ) ) + desca( nb_ ) * desca( nb_ )
            END IF
*
            work( 1 ) = dble( lwmin )
            lquery = ( lwork.EQ.-1 )
            IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
               info = -1
            ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) ) THEN
               info = -2
            ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
               info = -5
            ELSE IF( .NOT.left .AND. desca( mb_ ).NE.descc( nb_ ) ) THEN
               info = -(900+nb_)
            ELSE IF( left .AND. iroffa.NE.iroffc ) THEN
               info = -12
            ELSE IF( left .AND. iarow.NE.icrow ) THEN
               info = -12
            ELSE IF( .NOT.left .AND. iroffa.NE.icoffc ) THEN
               info = -13
            ELSE IF( left .AND. desca( mb_ ).NE.descc( mb_ ) ) THEN
               info = -(1400+mb_)
            ELSE IF( ictxt.NE.descc( ctxt_ ) ) THEN
               info = -(1400+ctxt_)
            ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
               info = -16
            END IF
         END IF
*
         IF( left ) THEN
            idum1( 1 ) = ichar( 'L' )
         ELSE
            idum1( 1 ) = ichar( 'R' )
         END IF
         idum2( 1 ) = 1
         IF( notran ) THEN
            idum1( 2 ) = ichar( 'N' )
         ELSE
            idum1( 2 ) = ichar( 'T' )
         END IF
         idum2( 2 ) = 2
         idum1( 3 ) = k
         idum2( 3 ) = 5
         IF( lwork.EQ.-1 ) THEN
            idum1( 4 ) = -1
         ELSE
            idum1( 4 ) = 1
         END IF
         idum2( 4 ) = 16
         IF( left ) THEN
            CALL pchk2mat( m, 3, k, 5, ia, ja, desca, 9, m, 3, n, 4, ic,
     $                     jc, descc, 14, 4, idum1, idum2, info )
         ELSE
            CALL pchk2mat( n, 4, k, 5, ia, ja, desca, 9, m, 3, n, 4, ic,
     $                     jc, descc, 14, 4, idum1, idum2, info )
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PDORMQR', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 )
     $   RETURN
*
      CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      IF( ( left .AND. .NOT.notran ) .OR.
     $    ( .NOT.left .AND. notran ) ) THEN
         j1 = min( iceil( ja, desca( nb_ ) ) * desca( nb_ ), ja+k-1 )
     $                    + 1
         j2 = ja+k-1
         j3 = desca( nb_ )
      ELSE
         j1 = max( ( (ja+k-2) / desca( nb_ ) ) * desca( nb_ ) + 1, ja )
         j2 = min( iceil( ja, desca( nb_ ) ) * desca( nb_ ), ja+k-1 )
     $                    + 1
         j3 = -desca( nb_ )
      END IF
*
      IF( left ) THEN
         ni  = n
         jcc = jc
         IF( notran ) THEN
            CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', 'D-ring' )
         ELSE
            CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', 'I-ring' )
         END IF
         CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', ' ' )
      ELSE
         mi  = m
         icc = ic
      END IF
*
*     Use unblocked code for the first block if necessary
*
      IF( ( left .AND. .NOT.notran ) .OR. ( .NOT.left .AND. notran ) )
     $   CALL pdorm2r( side, trans, m, n, j1-ja, a, ia, ja, desca, tau,
     $                 c, ic, jc, descc, work, lwork, iinfo )
*
      ipw = desca( nb_ ) * desca( nb_ ) + 1
      DO 10 j = j1, j2, j3
         jb = min( desca( nb_ ), k-j+ja )
*
*        Form the triangular factor of the block reflector
*        H = H(j) H(j+1) . . . H(j+jb-1)
*
         CALL pdlarft( 'Forward', 'Columnwise', nq-j+ja, jb, a,
     $                 ia+j-ja, j, desca, tau, work, work( ipw ) )
         IF( left ) THEN
*
*           H or H' is applied to C(ic+j-ja:ic+m-1,jc:jc+n-1)
*
            mi  = m - j + ja
            icc = ic + j - ja
         ELSE
*
*           H or H' is applied to C(ic:ic+m-1,jc+j-ja:jc+n-1)
*
            ni  = n - j + ja
            jcc = jc + j - ja
         END IF
*
*        Apply H or H'
*
         CALL pdlarfb( side, trans, 'Forward', 'Columnwise', mi, ni,
     $                jb, a, ia+j-ja, j, desca, work, c, icc, jcc,
     $                descc, work( ipw ) )
   10 CONTINUE
*
*     Use unblocked code for the last block if necessary
*
      IF( ( left .AND. notran ) .OR. ( .NOT.left .AND. .NOT.notran ) )
     $   CALL pdorm2r( side, trans, m, n, j2-ja, a, ia, ja, desca, tau,
     $                 c, ic, jc, descc, work, lwork, iinfo )
*
      CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      work( 1 ) = dble( lwmin )
*
      RETURN
*
*     End of PDORMQR
*

Here is the call graph for this function:

Here is the caller graph for this function: