pctzrzf.f

Go to the documentation of this file.

      SUBROUTINE pctzrzf( M, N, A, IA, JA, DESCA, TAU, WORK, LWORK,
     $                    INFO )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 25, 2001
*
*     .. Scalar Arguments ..
      INTEGER            IA, INFO, JA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      COMPLEX            A( * ), TAU( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PCTZRZF reduces the M-by-N ( M<=N ) complex upper trapezoidal matrix
*  sub( A ) = A(IA:IA+M-1,JA:JA+N-1) to upper triangular form by means
*  of unitary transformations.
*
*  The upper trapezoidal matrix sub( A ) is factored as
*
*     sub( A ) = ( R  0 ) * Z,
*
*  where Z is an N-by-N unitary matrix and R is an M-by-M upper
*  triangular matrix.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  M       (global input) INTEGER
*          The number of rows to be operated on, i.e. the number of rows
*          of the distributed submatrix sub( A ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on, i.e. the number of
*          columns of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) COMPLEX pointer into the
*          local memory to an array of dimension (LLD_A, LOCc(JA+N-1)).
*          On entry, the local pieces of the M-by-N distributed matrix
*          sub( A ) which is to be factored. On exit, the leading M-by-M
*          upper triangular part of sub( A ) contains the upper trian-
*          gular matrix R, and elements M+1 to N of the first M rows of
*          sub( A ), with the array TAU, represent the unitary matrix Z
*          as a product of M elementary reflectors.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  TAU     (local output) COMPLEX, array, dimension LOCr(IA+M-1)
*          This array contains the scalar factors of the elementary
*          reflectors. TAU is tied to the distributed matrix A.
*
*  WORK    (local workspace/local output) COMPLEX array,
*                                                    dimension (LWORK)
*          On exit, WORK(1) returns the minimal and optimal LWORK.
*
*  LWORK   (local or global input) INTEGER
*          The dimension of the array WORK.
*          LWORK is local input and must be at least
*          LWORK >= MB_A * ( Mp0 + Nq0 + MB_A ), where
*
*          IROFF = MOD( IA-1, MB_A ), ICOFF = MOD( JA-1, NB_A ),
*          IAROW = INDXG2P( IA, MB_A, MYROW, RSRC_A, NPROW ),
*          IACOL = INDXG2P( JA, NB_A, MYCOL, CSRC_A, NPCOL ),
*          Mp0   = NUMROC( M+IROFF, MB_A, MYROW, IAROW, NPROW ),
*          Nq0   = NUMROC( N+ICOFF, NB_A, MYCOL, IACOL, NPCOL ),
*
*          and NUMROC, INDXG2P are ScaLAPACK tool functions;
*          MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*          the subroutine BLACS_GRIDINFO.
*
*          If LWORK = -1, then LWORK is global input and a workspace
*          query is assumed; the routine only calculates the minimum
*          and optimal size for all work arrays. Each of these
*          values is returned in the first entry of the corresponding
*          work array, and no error message is issued by PXERBLA.
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  Further Details
*  ===============
*
*  The  factorization is obtained by Householder's method.  The kth
*  transformation matrix, Z( k ), whose conjugate transpose is used to
*  introduce zeros into the (m - k + 1)th row of sub( A ), is given in
*  the form
*
*     Z( k ) = ( I     0   ),
*              ( 0  T( k ) )
*
*  where
*
*     T( k ) = I - tau*u( k )*u( k )',   u( k ) = (   1    ),
*                                                 (   0    )
*                                                 ( z( k ) )
*
*  tau is a scalar and z( k ) is an ( n - m ) element vector.
*  tau and z( k ) are chosen to annihilate the elements of the kth row
*  of sub( A ).
*
*  The scalar tau is returned in the kth element of TAU and the vector
*  u( k ) in the kth row of sub( A ), such that the elements of z( k )
*  are in  a( k, m + 1 ), ..., a( k, n ). The elements of R are returned
*  in the upper triangular part of sub( A ).
*
*  Z is given by
*
*     Z =  Z( 1 ) * Z( 2 ) * ... * Z( m ).
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      COMPLEX            ZERO
      parameter( zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY
      CHARACTER          COLBTOP, ROWBTOP
      INTEGER            I, IACOL, IAROW, IB, ICTXT, IIA, IL, IN, IPW,
     $                   iroffa, j, jm1, l, lwmin, mp0, mycol, myrow,
     $                   npcol, nprow, nq0
*     ..
*     .. Local Arrays ..
      INTEGER            IDUM1( 1 ), IDUM2( 1 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, infog1l, pchk1mat,
     $                   pclatrz, pclarzb, pclarzt, pb_topget,
     $                   pb_topset, pxerbla
*     ..
*     .. External Functions ..
      INTEGER            ICEIL, INDXG2P, NUMROC
      EXTERNAL           iceil, indxg2p, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, min, mod, real
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(600+ctxt_)
      ELSE
         CALL chk1mat( m, 1, n, 2, ia, ja, desca, 6, info )
         IF( info.EQ.0 ) THEN
            iroffa = mod( ia-1, desca( mb_ ) )
            iarow = indxg2p( ia, desca( mb_ ), myrow, desca( rsrc_ ),
     $                       nprow )
            iacol = indxg2p( ja, desca( nb_ ), mycol, desca( csrc_ ),
     $                       npcol )
            mp0 = numroc( m+iroffa, desca( mb_ ), myrow, iarow, nprow )
            nq0 = numroc( n+mod( ja-1, desca( nb_ ) ), desca( nb_ ),
     $                    mycol, iacol, npcol )
            lwmin = desca( mb_ ) * ( mp0 + nq0 + desca( mb_ ) )
*
            work( 1 ) = cmplx( real( lwmin ) )
            lquery = ( lwork.EQ.-1 )
            IF( n.LT.m ) THEN
               info = -2
            ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
               info = -9
            END IF
         END IF
         IF( lquery ) THEN
            idum1( 1 ) = -1
         ELSE
            idum1( 1 ) = 1
         END IF
         idum2( 1 ) = 9
         CALL pchk1mat( m, 1, n, 2, ia, ja, desca, 6, 1, idum1, idum2,
     $                  info )
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PCTZRZF', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 )
     $   RETURN
*
      IF( m.EQ.n ) THEN
*
         CALL infog1l( ia, desca( mb_ ), nprow, myrow, desca( rsrc_ ),
     $                 iia, iarow )
         IF( myrow.EQ.iarow )
     $      mp0 = mp0 - iroffa
         DO 10 i = iia, iia+mp0-1
            tau( i ) = zero
   10    CONTINUE
*
      ELSE
*
         l = n-m
         jm1 = ja + min( m+1, n ) - 1
         ipw = desca( mb_ ) * desca( mb_ ) + 1
         in = min( iceil( ia, desca( mb_ ) ) * desca( mb_ ), ia+m-1 )
         il = max( ( (ia+m-2) / desca( mb_ ) ) * desca( mb_ ) + 1, ia )
         CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
         CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
         CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', ' ' )
         CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', 'D-ring' )
*
*        Use blocked code initially
*
         DO 20 i = il, in+1, -desca( mb_ )
            ib = min( ia+m-i, desca( mb_ ) )
            j = ja + i - ia
*
*           Compute the complete orthogonal factorization of the current
*           block A(i:i+ib-1,j:ja+n-1)
*
            CALL pclatrz( ib, ja+n-j, l, a, i, j, desca, tau, work )
*
            IF( i.GT.ia ) THEN
*
*              Form the triangular factor of the block reflector
*              H = H(i+ib-1) . . . H(i+1) H(i)
*
               CALL pclarzt( 'Backward', 'Rowwise', l, ib, a, i, jm1,
     $                       desca, tau, work, work( ipw ) )
*
*              Apply H to A(ia:i-1,j:ja+n-1) from the right
*
               CALL pclarzb( 'Right', 'No transpose', 'Backward',
     $                       'Rowwise', i-ia, ja+n-j, ib, l, a, i, jm1,
     $                       desca, work, a, ia, j, desca, work( ipw ) )
            END IF
*
   20    CONTINUE
*
*        Use unblocked code to factor the last or only block
*
         CALL pclatrz( in-ia+1, n, n-m, a, ia, ja, desca, tau, work )
*
         CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
         CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      END IF
*
      work( 1 ) = cmplx( real( lwmin ) )
*
      RETURN
*
*     End of PCTZRZF
*
      END