pcdbtrsv()

subroutine pcdbtrsv	(	character	uplo,
		character	trans,
		integer	n,
		integer	bwl,
		integer	bwu,
		integer	nrhs,
		complex, dimension( * )	a,
		integer	ja,
		integer, dimension( * )	desca,
		complex, dimension( * )	b,
		integer	ib,
		integer, dimension( * )	descb,
		complex, dimension( * )	af,
		integer	laf,
		complex, dimension( * )	work,
		integer	lwork,
		integer	info
	)

Definition at line 1 of file pcdbtrsv.f.

*
*  -- ScaLAPACK routine (version 2.0.2) --
*     Univ. of Tennessee, Univ. of California Berkeley, Univ. of Colorado Denver
*     May 1 2012
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS, UPLO
      INTEGER            BWL, BWU, IB, INFO, JA, LAF, LWORK, N, NRHS
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCB( * )
      COMPLEX            A( * ), AF( * ), B( * ), WORK( * )
*     ..
*
*
*  Purpose
*  =======
*
*  PCDBTRSV solves a banded triangular system of linear equations
*
*                      A(1:N, JA:JA+N-1) * X = B(IB:IB+N-1, 1:NRHS)
*                                 or
*                      A(1:N, JA:JA+N-1)^H * X = B(IB:IB+N-1, 1:NRHS)
*
*  where A(1:N, JA:JA+N-1) is a banded
*  triangular matrix factor produced by the
*  Gaussian elimination code PC@(dom_pre)BTRF
*  and is stored in A(1:N,JA:JA+N-1) and AF.
*  The matrix stored in A(1:N, JA:JA+N-1) is either
*  upper or lower triangular according to UPLO,
*  and the choice of solving A(1:N, JA:JA+N-1) or A(1:N, JA:JA+N-1)^H
*  is dictated by the user by the parameter TRANS.
*
*  Routine PCDBTRF MUST be called first.
*
*  =====================================================================
*
*  Arguments
*  =========
*
*  UPLO    (global input) CHARACTER
*          = 'U':  Upper triangle of A(1:N, JA:JA+N-1) is stored;
*          = 'L':  Lower triangle of A(1:N, JA:JA+N-1) is stored.
*
*  TRANS   (global input) CHARACTER
*          = 'N':  Solve with A(1:N, JA:JA+N-1);
*          = 'C':  Solve with conjugate_transpose( A(1:N, JA:JA+N-1) );
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix A(1:N, JA:JA+N-1). N >= 0.
*
*  BWL     (global input) INTEGER
*          Number of subdiagonals. 0 <= BWL <= N-1
*
*  BWU     (global input) INTEGER
*          Number of superdiagonals. 0 <= BWU <= N-1
*
*  NRHS    (global input) INTEGER
*          The number of right hand sides, i.e., the number of columns
*          of the distributed submatrix B(IB:IB+N-1, 1:NRHS).
*          NRHS >= 0.
*
*  A       (local input/local output) COMPLEX pointer into
*          local memory to an array with first dimension
*          LLD_A >=(bwl+bwu+1) (stored in DESCA).
*          On entry, this array contains the local pieces of the
*          N-by-N unsymmetric banded distributed Cholesky factor L or
*          L^T A(1:N, JA:JA+N-1).
*          This local portion is stored in the packed banded format
*            used in LAPACK. Please see the Notes below and the
*            ScaLAPACK manual for more detail on the format of
*            distributed matrices.
*
*  JA      (global input) INTEGER
*          The index in the global array A that points to the start of
*          the matrix to be operated on (which may be either all of A
*          or a submatrix of A).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN.
*          if 1D type (DTYPE_A=501), DLEN >= 7;
*          if 2D type (DTYPE_A=1), DLEN >= 9 .
*          The array descriptor for the distributed matrix A.
*          Contains information of mapping of A to memory. Please
*          see NOTES below for full description and options.
*
*  B       (local input/local output) COMPLEX pointer into
*          local memory to an array of local lead dimension lld_b>=NB.
*          On entry, this array contains the
*          the local pieces of the right hand sides
*          B(IB:IB+N-1, 1:NRHS).
*          On exit, this contains the local piece of the solutions
*          distributed matrix X.
*
*  IB      (global input) INTEGER
*          The row index in the global array B that points to the first
*          row of the matrix to be operated on (which may be either
*          all of B or a submatrix of B).
*
*  DESCB   (global and local input) INTEGER array of dimension DLEN.
*          if 1D type (DTYPE_B=502), DLEN >=7;
*          if 2D type (DTYPE_B=1), DLEN >= 9.
*          The array descriptor for the distributed matrix B.
*          Contains information of mapping of B to memory. Please
*          see NOTES below for full description and options.
*
*  AF      (local output) COMPLEX array, dimension LAF.
*          Auxiliary Fillin Space.
*          Fillin is created during the factorization routine
*          PCDBTRF and this is stored in AF. If a linear system
*          is to be solved using PCDBTRS after the factorization
*          routine, AF *must not be altered* after the factorization.
*
*  LAF     (local input) INTEGER
*          Size of user-input Auxiliary Fillin space AF. Must be >=
*          NB*(bwl+bwu)+6*max(bwl,bwu)*max(bwl,bwu)
*          If LAF is not large enough, an error code will be returned
*          and the minimum acceptable size will be returned in AF( 1 )
*
*  WORK    (local workspace/local output)
*          COMPLEX temporary workspace. This space may
*          be overwritten in between calls to routines. WORK must be
*          the size given in LWORK.
*          On exit, WORK( 1 ) contains the minimal LWORK.
*
*  LWORK   (local input or global input) INTEGER
*          Size of user-input workspace WORK.
*          If LWORK is too small, the minimal acceptable size will be
*          returned in WORK(1) and an error code is returned. LWORK>=
*          (max(bwl,bwu)*NRHS)
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  =====================================================================
*
*
*  Restrictions
*  ============
*
*  The following are restrictions on the input parameters. Some of these
*    are temporary and will be removed in future releases, while others
*    may reflect fundamental technical limitations.
*
*    Non-cyclic restriction: VERY IMPORTANT!
*      P*NB>= mod(JA-1,NB)+N.
*      The mapping for matrices must be blocked, reflecting the nature
*      of the divide and conquer algorithm as a task-parallel algorithm.
*      This formula in words is: no processor may have more than one
*      chunk of the matrix.
*
*    Blocksize cannot be too small:
*      If the matrix spans more than one processor, the following
*      restriction on NB, the size of each block on each processor,
*      must hold:
*      NB >= 2*MAX(BWL,BWU)
*      The bulk of parallel computation is done on the matrix of size
*      O(NB) on each processor. If this is too small, divide and conquer
*      is a poor choice of algorithm.
*
*    Submatrix reference:
*      JA = IB
*      Alignment restriction that prevents unnecessary communication.
*
*
*  =====================================================================
*
*
*  Notes
*  =====
*
*  If the factorization routine and the solve routine are to be called
*    separately (to solve various sets of righthand sides using the same
*    coefficient matrix), the auxiliary space AF *must not be altered*
*    between calls to the factorization routine and the solve routine.
*
*  The best algorithm for solving banded and tridiagonal linear systems
*    depends on a variety of parameters, especially the bandwidth.
*    Currently, only algorithms designed for the case N/P >> bw are
*    implemented. These go by many names, including Divide and Conquer,
*    Partitioning, domain decomposition-type, etc.
*
*  Algorithm description: Divide and Conquer
*
*    The Divide and Conqer algorithm assumes the matrix is narrowly
*      banded compared with the number of equations. In this situation,
*      it is best to distribute the input matrix A one-dimensionally,
*      with columns atomic and rows divided amongst the processes.
*      The basic algorithm divides the banded matrix up into
*      P pieces with one stored on each processor,
*      and then proceeds in 2 phases for the factorization or 3 for the
*      solution of a linear system.
*      1) Local Phase:
*         The individual pieces are factored independently and in
*         parallel. These factors are applied to the matrix creating
*         fillin, which is stored in a non-inspectable way in auxiliary
*         space AF. Mathematically, this is equivalent to reordering
*         the matrix A as P A P^T and then factoring the principal
*         leading submatrix of size equal to the sum of the sizes of
*         the matrices factored on each processor. The factors of
*         these submatrices overwrite the corresponding parts of A
*         in memory.
*      2) Reduced System Phase:
*         A small (max(bwl,bwu)* (P-1)) system is formed representing
*         interaction of the larger blocks, and is stored (as are its
*         factors) in the space AF. A parallel Block Cyclic Reduction
*         algorithm is used. For a linear system, a parallel front solve
*         followed by an analagous backsolve, both using the structure
*         of the factored matrix, are performed.
*      3) Backsubsitution Phase:
*         For a linear system, a local backsubstitution is performed on
*         each processor in parallel.
*
*
*  Descriptors
*  ===========
*
*  Descriptors now have *types* and differ from ScaLAPACK 1.0.
*
*  Note: banded codes can use either the old two dimensional
*    or new one-dimensional descriptors, though the processor grid in
*    both cases *must be one-dimensional*. We describe both types below.
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*
*  One-dimensional descriptors:
*
*  One-dimensional descriptors are a new addition to ScaLAPACK since
*    version 1.0. They simplify and shorten the descriptor for 1D
*    arrays.
*
*  Since ScaLAPACK supports two-dimensional arrays as the fundamental
*    object, we allow 1D arrays to be distributed either over the
*    first dimension of the array (as if the grid were P-by-1) or the
*    2nd dimension (as if the grid were 1-by-P). This choice is
*    indicated by the descriptor type (501 or 502)
*    as described below.
*
*    IMPORTANT NOTE: the actual BLACS grid represented by the
*    CTXT entry in the descriptor may be *either*  P-by-1 or 1-by-P
*    irrespective of which one-dimensional descriptor type
*    (501 or 502) is input.
*    This routine will interpret the grid properly either way.
*    ScaLAPACK routines *do not support intercontext operations* so that
*    the grid passed to a single ScaLAPACK routine *must be the same*
*    for all array descriptors passed to that routine.
*
*    NOTE: In all cases where 1D descriptors are used, 2D descriptors
*    may also be used, since a one-dimensional array is a special case
*    of a two-dimensional array with one dimension of size unity.
*    The two-dimensional array used in this case *must* be of the
*    proper orientation:
*      If the appropriate one-dimensional descriptor is DTYPEA=501
*      (1 by P type), then the two dimensional descriptor must
*      have a CTXT value that refers to a 1 by P BLACS grid;
*      If the appropriate one-dimensional descriptor is DTYPEA=502
*      (P by 1 type), then the two dimensional descriptor must
*      have a CTXT value that refers to a P by 1 BLACS grid.
*
*
*  Summary of allowed descriptors, types, and BLACS grids:
*  DTYPE           501         502         1         1
*  BLACS grid      1xP or Px1  1xP or Px1  1xP       Px1
*  -----------------------------------------------------
*  A               OK          NO          OK        NO
*  B               NO          OK          NO        OK
*
*  Note that a consequence of this chart is that it is not possible
*    for *both* DTYPE_A and DTYPE_B to be 2D_type(1), as these lead
*    to opposite requirements for the orientation of the BLACS grid,
*    and as noted before, the *same* BLACS context must be used in
*    all descriptors in a single ScaLAPACK subroutine call.
*
*  Let A be a generic term for any 1D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN  EXPLANATION
*  --------------- ---------- ------------------------------------------
*  DTYPE_A(global) DESCA( 1 ) The descriptor type. For 1D grids,
*                                TYPE_A = 501: 1-by-P grid.
*                                TYPE_A = 502: P-by-1 grid.
*  CTXT_A (global) DESCA( 2 ) The BLACS context handle, indicating
*                                the BLACS process grid A is distribu-
*                                ted over. The context itself is glo-
*                                bal, but the handle (the integer
*                                value) may vary.
*  N_A    (global) DESCA( 3 ) The size of the array dimension being
*                                distributed.
*  NB_A   (global) DESCA( 4 ) The blocking factor used to distribute
*                                the distributed dimension of the array.
*  SRC_A  (global) DESCA( 5 ) The process row or column over which the
*                                first row or column of the array
*                                is distributed.
*  LLD_A  (local)  DESCA( 6 ) The leading dimension of the local array
*                                storing the local blocks of the distri-
*                                buted array A. Minimum value of LLD_A
*                                depends on TYPE_A.
*                                TYPE_A = 501: LLD_A >=
*                                   size of undistributed dimension, 1.
*                                TYPE_A = 502: LLD_A >=NB_A, 1.
*  Reserved        DESCA( 7 ) Reserved for future use.
*
*
*
*  =====================================================================
*
*  Code Developer: Andrew J. Cleary, University of Tennessee.
*    Current address: Lawrence Livermore National Labs.
*  This version released: August, 2001.
*
*  =====================================================================
*
*     ..
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0 )
      parameter( zero = 0.0e+0 )
      COMPLEX            CONE, CZERO
      parameter( cone = ( 1.0e+0, 0.0e+0 ) )
      parameter( czero = ( 0.0e+0, 0.0e+0 ) )
      INTEGER            INT_ONE
      parameter( int_one = 1 )
      INTEGER            DESCMULT, BIGNUM
      parameter(descmult = 100, bignum = descmult * descmult)
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      INTEGER            CSRC, FIRST_PROC, ICTXT, ICTXT_NEW, ICTXT_SAVE,
     $                   IDUM1, IDUM2, IDUM3, JA_NEW, LEVEL_DIST, LLDA,
     $                   LLDB, MAX_BW, MBW2, MYCOL, MYROW, MY_NUM_COLS,
     $                   NB, NP, NPCOL, NPROW, NP_SAVE, ODD_SIZE, OFST,
     $                   PART_OFFSET, PART_SIZE, RETURN_CODE, STORE_M_B,
     $                   STORE_N_A, WORK_SIZE_MIN, WORK_U
*     ..
*     .. Local Arrays ..
      INTEGER            DESCA_1XP( 7 ), DESCB_PX1( 7 ),
     $                   PARAM_CHECK( 18, 3 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_get, blacs_gridexit, blacs_gridinfo,
     $                   cgemm, cgerv2d, cgesd2d, clamov, cmatadd,
     $                   ctbtrs, ctrmm, ctrtrs, desc_convert, globchk,
     $                   pxerbla, reshape
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            NUMROC
      EXTERNAL           lsame, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          ichar, min, mod
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      info = 0
*
*     Convert descriptor into standard form for easy access to
*        parameters, check that grid is of right shape.
*
      desca_1xp( 1 ) = 501
      descb_px1( 1 ) = 502
*
      CALL desc_convert( desca, desca_1xp, return_code )
*
      IF( return_code .NE. 0) THEN
         info = -( 9*100 + 2 )
      ENDIF
*
      CALL desc_convert( descb, descb_px1, return_code )
*
      IF( return_code .NE. 0) THEN
         info = -( 12*100 + 2 )
      ENDIF
*
*     Consistency checks for DESCA and DESCB.
*
*     Context must be the same
      IF( desca_1xp( 2 ) .NE. descb_px1( 2 ) ) THEN
         info = -( 12*100 + 2 )
      ENDIF
*
*        These are alignment restrictions that may or may not be removed
*        in future releases. -Andy Cleary, April 14, 1996.
*
*     Block sizes must be the same
      IF( desca_1xp( 4 ) .NE. descb_px1( 4 ) ) THEN
         info = -( 12*100 + 4 )
      ENDIF
*
*     Source processor must be the same
*
      IF( desca_1xp( 5 ) .NE. descb_px1( 5 ) ) THEN
         info = -( 12*100 + 5 )
      ENDIF
*
*     Get values out of descriptor for use in code.
*
      ictxt = desca_1xp( 2 )
      csrc = desca_1xp( 5 )
      nb = desca_1xp( 4 )
      llda = desca_1xp( 6 )
      store_n_a = desca_1xp( 3 )
      lldb = descb_px1( 6 )
      store_m_b = descb_px1( 3 )
*
*     Get grid parameters
*
*
*     Size of separator blocks is maximum of bandwidths
*
      max_bw = max(bwl,bwu)
      mbw2 = max_bw * max_bw
*
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
      np = nprow * npcol
*
*
*
      IF( lsame( uplo, 'U' ) ) THEN
         idum1 = ichar( 'U' )
      ELSE IF ( lsame( uplo, 'L' ) ) THEN
         idum1 = ichar( 'L' )
      ELSE
         info = -1
      END IF
*
      IF( lsame( trans, 'N' ) ) THEN
         idum2 = ichar( 'N' )
      ELSE IF ( lsame( trans, 'C' ) ) THEN
         idum2 = ichar( 'C' )
      ELSE
         info = -2
      END IF
*
      IF( lwork .LT. -1) THEN
         info = -16
      ELSE IF ( lwork .EQ. -1 ) THEN
         idum3 = -1
      ELSE
         idum3 = 1
      ENDIF
*
      IF( n .LT. 0 ) THEN
         info = -3
      ENDIF
*
      IF( n+ja-1 .GT. store_n_a ) THEN
         info = -( 9*100 + 6 )
      ENDIF
*
      IF(( bwl .GT. n-1 ) .OR.
     $   ( bwl .LT. 0 ) ) THEN
         info = -4
      ENDIF
*
      IF(( bwu .GT. n-1 ) .OR.
     $   ( bwu .LT. 0 ) ) THEN
         info = -5
      ENDIF
*
      IF( llda .LT. (bwl+bwu+1) ) THEN
         info = -( 9*100 + 6 )
      ENDIF
*
      IF( nb .LE. 0 ) THEN
         info = -( 9*100 + 4 )
      ENDIF
*
      IF( n+ib-1 .GT. store_m_b ) THEN
         info = -( 12*100 + 3 )
      ENDIF
*
      IF( lldb .LT. nb ) THEN
         info = -( 12*100 + 6 )
      ENDIF
*
      IF( nrhs .LT. 0 ) THEN
         info = -6
      ENDIF
*
*     Current alignment restriction
*
      IF( ja .NE. ib) THEN
         info = -8
      ENDIF
*
*     Argument checking that is specific to Divide & Conquer routine
*
      IF( nprow .NE. 1 ) THEN
         info = -( 9*100+2 )
      ENDIF
*
      IF( n .GT. np*nb-mod( ja-1, nb )) THEN
         info = -( 3 )
         CALL pxerbla( ictxt,
     $      'PCDBTRSV, D&C alg.: only 1 block per proc',
     $      -info )
         RETURN
      ENDIF
*
      IF((ja+n-1.GT.nb) .AND. ( nb.LT.2*max(bwl,bwu) )) THEN
         info = -( 9*100+4 )
         CALL pxerbla( ictxt,
     $      'PCDBTRSV, D&C alg.: NB too small',
     $      -info )
         RETURN
      ENDIF
*
*
      work_size_min =
     $           max(bwl,bwu)*nrhs
*
      work( 1 ) = work_size_min
*
      IF( lwork .LT. work_size_min ) THEN
         IF( lwork .NE. -1 ) THEN
         info = -16
         CALL pxerbla( ictxt,
     $      'PCDBTRSV: worksize error',
     $      -info )
         ENDIF
         RETURN
      ENDIF
*
*     Pack params and positions into arrays for global consistency check
*
      param_check( 18, 1 ) = descb(5)
      param_check( 17, 1 ) = descb(4)
      param_check( 16, 1 ) = descb(3)
      param_check( 15, 1 ) = descb(2)
      param_check( 14, 1 ) = descb(1)
      param_check( 13, 1 ) = ib
      param_check( 12, 1 ) = desca(5)
      param_check( 11, 1 ) = desca(4)
      param_check( 10, 1 ) = desca(3)
      param_check(  9, 1 ) = desca(1)
      param_check(  8, 1 ) = ja
      param_check(  7, 1 ) = nrhs
      param_check(  6, 1 ) = bwu
      param_check(  5, 1 ) = bwl
      param_check(  4, 1 ) = n
      param_check(  3, 1 ) = idum3
      param_check(  2, 1 ) = idum2
      param_check(  1, 1 ) = idum1
*
      param_check( 18, 2 ) = 1205
      param_check( 17, 2 ) = 1204
      param_check( 16, 2 ) = 1203
      param_check( 15, 2 ) = 1202
      param_check( 14, 2 ) = 1201
      param_check( 13, 2 ) = 11
      param_check( 12, 2 ) = 905
      param_check( 11, 2 ) = 904
      param_check( 10, 2 ) = 903
      param_check(  9, 2 ) = 901
      param_check(  8, 2 ) = 8
      param_check(  7, 2 ) = 6
      param_check(  6, 2 ) = 5
      param_check(  5, 2 ) = 4
      param_check(  4, 2 ) = 3
      param_check(  3, 2 ) = 16
      param_check(  2, 2 ) = 2
      param_check(  1, 2 ) = 1
*
*     Want to find errors with MIN( ), so if no error, set it to a big
*     number. If there already is an error, multiply by the the
*     descriptor multiplier.
*
      IF( info.GE.0 ) THEN
         info = bignum
      ELSE IF( info.LT.-descmult ) THEN
         info = -info
      ELSE
         info = -info * descmult
      END IF
*
*     Check consistency across processors
*
      CALL globchk( ictxt, 18, param_check, 18,
     $              param_check( 1, 3 ), info )
*
*     Prepare output: set info = 0 if no error, and divide by DESCMULT
*     if error is not in a descriptor entry.
*
      IF( info.EQ.bignum ) THEN
         info = 0
      ELSE IF( mod( info, descmult ) .EQ. 0 ) THEN
         info = -info / descmult
      ELSE
         info = -info
      END IF
*
      IF( info.LT.0 ) THEN
         CALL pxerbla( ictxt, 'PCDBTRSV', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( nrhs.EQ.0 )
     $   RETURN
*
*
*     Adjust addressing into matrix space to properly get into
*        the beginning part of the relevant data
*
      part_offset = nb*( (ja-1)/(npcol*nb) )
*
      IF ( (mycol-csrc) .LT. (ja-part_offset-1)/nb ) THEN
         part_offset = part_offset + nb
      ENDIF
*
      IF ( mycol .LT. csrc ) THEN
         part_offset = part_offset - nb
      ENDIF
*
*     Form a new BLACS grid (the "standard form" grid) with only procs
*        holding part of the matrix, of size 1xNP where NP is adjusted,
*        starting at csrc=0, with JA modified to reflect dropped procs.
*
*     First processor to hold part of the matrix:
*
      first_proc = mod( ( ja-1 )/nb+csrc, npcol )
*
*     Calculate new JA one while dropping off unused processors.
*
      ja_new = mod( ja-1, nb ) + 1
*
*     Save and compute new value of NP
*
      np_save = np
      np = ( ja_new+n-2 )/nb + 1
*
*     Call utility routine that forms "standard-form" grid
*
      CALL reshape( ictxt, int_one, ictxt_new, int_one,
     $              first_proc, int_one, np )
*
*     Use new context from standard grid as context.
*
      ictxt_save = ictxt
      ictxt = ictxt_new
      desca_1xp( 2 ) = ictxt_new
      descb_px1( 2 ) = ictxt_new
*
*     Get information about new grid.
*
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Drop out processors that do not have part of the matrix.
*
      IF( myrow .LT. 0 ) THEN
         GOTO 1234
      ENDIF
*
*     ********************************
*     Values reused throughout routine
*
*     User-input value of partition size
*
      part_size = nb
*
*     Number of columns in each processor
*
      my_num_cols = numroc( n, part_size, mycol, 0, npcol )
*
*     Offset in columns to beginning of main partition in each proc
*
      IF ( mycol .EQ. 0 ) THEN
        part_offset = part_offset+mod( ja_new-1, part_size )
        my_num_cols = my_num_cols - mod(ja_new-1, part_size )
      ENDIF
*
*     Offset in elements
*
      ofst = part_offset*llda
*
*     Size of main (or odd) partition in each processor
*
      odd_size = my_num_cols
      IF ( mycol .LT. np-1 ) THEN
         odd_size = odd_size - max_bw
      ENDIF
*
*     Offset to workspace for Upper triangular factor
*
      work_u = bwu*odd_size + 3*mbw2
*
*
*
*     Begin main code
*
      IF ( lsame( uplo, 'L' ) ) THEN
*
      IF ( lsame( trans, 'N' ) ) THEN
*
*        Frontsolve
*
*
******************************************
*       Local computation phase
******************************************
*
*       Use main partition in each processor to solve locally
*
        CALL ctbtrs( uplo, 'N', 'U', odd_size,
     $                    bwl, nrhs,
     $                    a( ofst+1+bwu ), llda,
     $                    b( part_offset+1 ), lldb, info )
*
*
        IF ( mycol .LT. np-1 ) THEN
*         Use factorization of odd-even connection block to modify
*           locally stored portion of right hand side(s)
*
*
*           First copy and multiply it into temporary storage,
*             then use it on RHS
*
            CALL clamov( 'N', bwl, nrhs,
     $                b( part_offset+odd_size-bwl+1), lldb,
     $                work( 1 ), max_bw )
*
            CALL ctrmm( 'L', 'U', 'N', 'N', bwl, nrhs, -cone,
     $                  a(( ofst+(bwl+bwu+1)+(odd_size-bwl)*llda )),
     $                  llda-1, work( 1 ), max_bw )
*
            CALL cmatadd( bwl, nrhs, cone, work( 1 ), max_bw,
     $                cone, b( part_offset+odd_size+1 ), lldb )
*
        ENDIF
*
*       Clear garbage out of workspace block
*
        DO 10               idum1=1, work_size_min
          work( idum1 )=0.0
   10   CONTINUE
*
*
        IF ( mycol .NE. 0 ) THEN
*         Use the "spike" fillin to calculate contribution to previous
*           processor's righthand-side.
*
            CALL cgemm( 'C', 'N', bwu, nrhs, odd_size, -cone, af( 1 ),
     $                  odd_size, b( part_offset+1 ), lldb, czero,
     $                  work( 1+max_bw-bwu ), max_bw )
        ENDIF
*
*
************************************************
*       Formation and solution of reduced system
************************************************
*
*
*       Send modifications to prior processor's right hand sides
*
        IF( mycol .GT. 0) THEN
*
          CALL cgesd2d( ictxt, max_bw, nrhs,
     $                     work( 1 ), max_bw,
     $                     0, mycol - 1 )
*
        ENDIF
*
*       Receive modifications to processor's right hand sides
*
        IF( mycol .LT. npcol-1) THEN
*
          CALL cgerv2d( ictxt, max_bw, nrhs,
     $                     work( 1 ), max_bw,
     $                     0, mycol + 1 )
*
*         Combine contribution to locally stored right hand sides
*
          CALL cmatadd( max_bw, nrhs, cone,
     $                work( 1 ), max_bw, cone,
     $                b( part_offset+odd_size + 1 ), lldb )
*
        ENDIF
*
*
*       The last processor does not participate in the solution of the
*       reduced system, having sent its contribution already.
        IF( mycol .EQ. npcol-1 ) THEN
          GOTO 14
        ENDIF
*
*
*       *************************************
*       Modification Loop
*
*       The distance for sending and receiving for each level starts
*         at 1 for the first level.
        level_dist = 1
*
*       Do until this proc is needed to modify other procs' equations
*
   12   CONTINUE
        IF( mod( (mycol+1)/level_dist, 2) .NE. 0 ) GOTO 11
*
*         Receive and add contribution to righthand sides from left
*
          IF( mycol-level_dist .GE. 0 ) THEN
*
            CALL cgerv2d( ictxt, max_bw, nrhs,
     $                     work( 1 ),
     $                     max_bw, 0, mycol-level_dist )
*
            CALL cmatadd( max_bw, nrhs, cone,
     $                work( 1 ), max_bw, cone,
     $                b( part_offset+odd_size + 1 ), lldb )
*
          ENDIF
*
*         Receive and add contribution to righthand sides from right
*
          IF( mycol+level_dist .LT. npcol-1 ) THEN
*
            CALL cgerv2d( ictxt, max_bw, nrhs,
     $                     work( 1 ),
     $                     max_bw, 0, mycol+level_dist )
*
            CALL cmatadd( max_bw, nrhs, cone,
     $                work( 1 ), max_bw, cone,
     $                b( part_offset+odd_size + 1 ), lldb )
*
          ENDIF
*
          level_dist = level_dist*2
*
        GOTO 12
   11   CONTINUE
*       [End of GOTO Loop]
*
*
*
*       *********************************
*       Calculate and use this proc's blocks to modify other procs
*
*       Solve with diagonal block
*
        CALL ctbtrs( 'L', 'N', 'U', max_bw, min( bwl, max_bw-1 ), nrhs,
     $               af( odd_size*bwu+mbw2+1 ), max_bw+1,
     $               b( part_offset+odd_size+1 ), lldb, info )
*
        IF( info.NE.0 ) THEN
          GO TO 1000
        ENDIF
*
*
*
*       *********
        IF( mycol/level_dist .LE. (npcol-1)/level_dist-2 )THEN
*
*         Calculate contribution from this block to next diagonal block
*
          CALL cgemm( 'C', 'N', max_bw, nrhs, max_bw, -cone,
     $                     af( (odd_size)*bwu+1 ),
     $                     max_bw,
     $                     b( part_offset+odd_size+1 ),
     $                     lldb, czero,
     $                     work( 1 ),
     $                     max_bw )
*
*         Send contribution to diagonal block's owning processor.
*
          CALL cgesd2d( ictxt, max_bw, nrhs,
     $                     work( 1 ),
     $                     max_bw, 0, mycol+level_dist )
*
        ENDIF
*       End of "if( mycol/level_dist .le. (npcol-1)/level_dist-2 )..."
*
*       ************
        IF( (mycol/level_dist .GT. 0 ).AND.
     $      ( mycol/level_dist .LE. (npcol-1)/level_dist-1 ) ) THEN
*
*
*         Use offdiagonal block to calculate modification to diag block
*           of processor to the left
*
          CALL cgemm( 'N', 'N', max_bw, nrhs, max_bw, -cone,
     $                     af( odd_size*bwu+2*mbw2+1 ),
     $                     max_bw,
     $                     b( part_offset+odd_size+1 ),
     $                     lldb, czero,
     $                     work( 1 ),
     $                     max_bw )
*
*         Send contribution to diagonal block's owning processor.
*
          CALL cgesd2d( ictxt, max_bw, nrhs,
     $                     work( 1 ),
     $                     max_bw, 0, mycol-level_dist )
*
        ENDIF
*       End of "if( mycol/level_dist.le. (npcol-1)/level_dist -1 )..."
*
   14  CONTINUE
*
      ELSE
*
******************** BACKSOLVE *************************************
*
********************************************************************
*     .. Begin reduced system phase of algorithm ..
********************************************************************
*
*
*
*       The last processor does not participate in the solution of the
*       reduced system and just waits to receive its solution.
        IF( mycol .EQ. npcol-1 ) THEN
          GOTO 24
        ENDIF
*
*       Determine number of steps in tree loop
*
        level_dist = 1
   27   CONTINUE
        IF( mod( (mycol+1)/level_dist, 2) .NE. 0 ) GOTO 26
*
          level_dist = level_dist*2
*
        GOTO 27
   26   CONTINUE
*
*
        IF( (mycol/level_dist .GT. 0 ).AND.
     $      ( mycol/level_dist .LE. (npcol-1)/level_dist-1 ) ) THEN
*
*         Receive solution from processor to left
*
          CALL cgerv2d( ictxt, max_bw, nrhs,
     $                     work( 1 ),
     $                     max_bw, 0, mycol-level_dist )
*
*
*         Use offdiagonal block to calculate modification to RHS stored
*           on this processor
*
          CALL cgemm( 'C', 'N', max_bw, nrhs, max_bw, -cone,
     $                     af( odd_size*bwu+2*mbw2+1 ),
     $                     max_bw,
     $                     work( 1 ),
     $                     max_bw, cone,
     $                     b( part_offset+odd_size+1 ),
     $                     lldb )
        ENDIF
*       End of "if( mycol/level_dist.le. (npcol-1)/level_dist -1 )..."
*
*
        IF( mycol/level_dist .LE. (npcol-1)/level_dist-2 )THEN
*
*         Receive solution from processor to right
*
          CALL cgerv2d( ictxt, max_bw, nrhs,
     $                     work( 1 ),
     $                     max_bw, 0, mycol+level_dist )
*
*         Calculate contribution from this block to next diagonal block
*
          CALL cgemm( 'N', 'N', max_bw, nrhs, max_bw, -cone,
     $                     af( (odd_size)*bwu+1 ),
     $                     max_bw,
     $                     work( 1 ),
     $                     max_bw, cone,
     $                     b( part_offset+odd_size+1 ),
     $                     lldb )
*
        ENDIF
*       End of "if( mycol/level_dist .le. (npcol-1)/level_dist-2 )..."
*
*
*       Solve with diagonal block
*
        CALL ctbtrs( 'L', 'C', 'U', max_bw, min( bwl, max_bw-1 ), nrhs,
     $               af( odd_size*bwu+mbw2+1 ), max_bw+1,
     $               b( part_offset+odd_size+1 ), lldb, info )
*
        IF( info.NE.0 ) THEN
          GO TO 1000
        ENDIF
*
*
*
***Modification Loop *******
*
   22   CONTINUE
        IF( level_dist .EQ. 1 ) GOTO 21
*
          level_dist = level_dist/2
*
*         Send solution to the right
*
          IF( mycol+level_dist .LT. npcol-1 ) THEN
*
          CALL cgesd2d( ictxt, max_bw, nrhs,
     $                     b( part_offset+odd_size+1 ),
     $                     lldb, 0, mycol+level_dist )
*
          ENDIF
*
*         Send solution to left
*
          IF( mycol-level_dist .GE. 0 ) THEN
*
          CALL cgesd2d( ictxt, max_bw, nrhs,
     $                     b( part_offset+odd_size+1 ),
     $                     lldb, 0, mycol-level_dist )
*
          ENDIF
*
        GOTO 22
   21   CONTINUE
*       [End of GOTO Loop]
*
   24   CONTINUE
*          [Processor npcol - 1 jumped to here to await next stage]
*
*******************************
*       Reduced system has been solved, communicate solutions to nearest
*         neighbors in preparation for local computation phase.
*
*
*       Send elements of solution to next proc
*
        IF( mycol .LT. npcol-1) THEN
*
          CALL cgesd2d( ictxt, max_bw, nrhs,
     $                     b( part_offset+odd_size+1 ), lldb,
     $                     0, mycol +1 )
*
        ENDIF
*
*       Receive modifications to processor's right hand sides
*
        IF( mycol .GT. 0) THEN
*
          CALL cgerv2d( ictxt, max_bw, nrhs,
     $                     work( 1 ), max_bw,
     $                     0, mycol - 1 )
*
        ENDIF
*
*
*
**********************************************
*       Local computation phase
**********************************************
*
        IF ( mycol .NE. 0 ) THEN
*         Use the "spike" fillin to calculate contribution from previous
*           processor's solution.
*
          CALL cgemm( 'N', 'N', odd_size, nrhs, bwu, -cone, af( 1 ),
     $                odd_size, work( 1+max_bw-bwu ), max_bw, cone,
     $                b( part_offset+1 ), lldb )
*
        ENDIF
*
*
        IF ( mycol .LT. np-1 ) THEN
*         Use factorization of odd-even connection block to modify
*           locally stored portion of right hand side(s)
*
*
*         First copy and multiply it into temporary storage,
*           then use it on RHS
*
          CALL clamov( 'N', bwl, nrhs, b( part_offset+odd_size+1), lldb,
     $                 work( 1+max_bw-bwl ), max_bw )
*
          CALL ctrmm( 'L', 'U', 'C', 'N', bwl, nrhs, -cone,
     $                a(( ofst+(bwl+bwu+1)+(odd_size-bwl)*llda )),
     $                llda-1, work( 1+max_bw-bwl ), max_bw )
*
          CALL cmatadd( bwl, nrhs, cone, work( 1+max_bw-bwl ), max_bw,
     $                  cone, b( part_offset+odd_size-bwl+1 ), lldb )
*
        ENDIF
*
*       Use main partition in each processor to solve locally
*
        CALL ctbtrs( uplo, 'C', 'U', odd_size,
     $                    bwl, nrhs,
     $                    a( ofst+1+bwu ),
     $                    llda,  b( part_offset+1 ),
     $                    lldb, info )
*
      ENDIF
*     End of "IF( LSAME( TRANS, 'N' ) )"...
*
*
      ELSE
***************************************************************
*     CASE UPLO = 'U'                                         *
***************************************************************
      IF ( lsame( trans, 'C' ) ) THEN
*
*        Frontsolve
*
*
******************************************
*       Local computation phase
******************************************
*
*       Use main partition in each processor to solve locally
*
        CALL ctbtrs( uplo, 'C', 'N', odd_size,
     $                    bwu, nrhs,
     $                    a( ofst+1 ), llda,
     $                    b( part_offset+1 ), lldb, info )
*
*
        IF ( mycol .LT. np-1 ) THEN
*         Use factorization of odd-even connection block to modify
*           locally stored portion of right hand side(s)
*
*
*           First copy and multiply it into temporary storage,
*             then use it on RHS
*
            CALL clamov( 'N', bwu, nrhs,
     $                b( part_offset+odd_size-bwu+1), lldb,
     $                work( 1 ), max_bw )
*
            CALL ctrmm( 'L', 'L', 'C', 'N', bwu, nrhs, -cone,
     $                  a(( ofst+1+odd_size*llda )), llda-1, work( 1 ),
     $                  max_bw )
*
            CALL cmatadd( bwu, nrhs, cone, work( 1 ), max_bw,
     $                cone, b( part_offset+odd_size+1 ), lldb )
*
        ENDIF
*
*       Clear garbage out of workspace block
*
        DO 20               idum1=1, work_size_min
          work( idum1 )=0.0
   20   CONTINUE
*
*
        IF ( mycol .NE. 0 ) THEN
*         Use the "spike" fillin to calculate contribution to previous
*           processor's righthand-side.
*
            CALL cgemm( 'C', 'N', bwl, nrhs, odd_size, -cone,
     $                  af( work_u+1 ), odd_size, b( part_offset+1 ),
     $                  lldb, czero, work( 1+max_bw-bwl ), max_bw )
        ENDIF
*
*
************************************************
*       Formation and solution of reduced system
************************************************
*
*
*       Send modifications to prior processor's right hand sides
*
        IF( mycol .GT. 0) THEN
*
          CALL cgesd2d( ictxt, max_bw, nrhs,
     $                     work( 1 ), max_bw,
     $                     0, mycol - 1 )
*
        ENDIF
*
*       Receive modifications to processor's right hand sides
*
        IF( mycol .LT. npcol-1) THEN
*
          CALL cgerv2d( ictxt, max_bw, nrhs,
     $                     work( 1 ), max_bw,
     $                     0, mycol + 1 )
*
*         Combine contribution to locally stored right hand sides
*
          CALL cmatadd( max_bw, nrhs, cone,
     $                work( 1 ), max_bw, cone,
     $                b( part_offset+odd_size + 1 ), lldb )
*
        ENDIF
*
*
*       The last processor does not participate in the solution of the
*       reduced system, having sent its contribution already.
        IF( mycol .EQ. npcol-1 ) THEN
          GOTO 44
        ENDIF
*
*
*       *************************************
*       Modification Loop
*
*       The distance for sending and receiving for each level starts
*         at 1 for the first level.
        level_dist = 1
*
*       Do until this proc is needed to modify other procs' equations
*
   42   CONTINUE
        IF( mod( (mycol+1)/level_dist, 2) .NE. 0 ) GOTO 41
*
*         Receive and add contribution to righthand sides from left
*
          IF( mycol-level_dist .GE. 0 ) THEN
*
            CALL cgerv2d( ictxt, max_bw, nrhs,
     $                     work( 1 ),
     $                     max_bw, 0, mycol-level_dist )
*
            CALL cmatadd( max_bw, nrhs, cone,
     $                work( 1 ), max_bw, cone,
     $                b( part_offset+odd_size + 1 ), lldb )
*
          ENDIF
*
*         Receive and add contribution to righthand sides from right
*
          IF( mycol+level_dist .LT. npcol-1 ) THEN
*
            CALL cgerv2d( ictxt, max_bw, nrhs,
     $                     work( 1 ),
     $                     max_bw, 0, mycol+level_dist )
*
            CALL cmatadd( max_bw, nrhs, cone,
     $                work( 1 ), max_bw, cone,
     $                b( part_offset+odd_size + 1 ), lldb )
*
          ENDIF
*
          level_dist = level_dist*2
*
        GOTO 42
   41   CONTINUE
*       [End of GOTO Loop]
*
*
*
*       *********************************
*       Calculate and use this proc's blocks to modify other procs
*
*       Solve with diagonal block
*
        CALL ctbtrs( 'U', 'C', 'N', max_bw, min( bwu, max_bw-1 ), nrhs,
     $               af( odd_size*bwu+mbw2+1-min( bwu, max_bw-1 ) ),
     $               max_bw+1, b( part_offset+odd_size+1 ), lldb,
     $               info )
*
        IF( info.NE.0 ) THEN
          GO TO 1000
        ENDIF
*
*
*
*       *********
        IF( mycol/level_dist .LE. (npcol-1)/level_dist-2 )THEN
*
*         Calculate contribution from this block to next diagonal block
*
          CALL cgemm( 'C', 'N', max_bw, nrhs, max_bw, -cone,
     $                     af( work_u+(odd_size)*bwl+1 ),
     $                     max_bw,
     $                     b( part_offset+odd_size+1 ),
     $                     lldb, czero,
     $                     work( 1 ),
     $                     max_bw )
*
*         Send contribution to diagonal block's owning processor.
*
          CALL cgesd2d( ictxt, max_bw, nrhs,
     $                     work( 1 ),
     $                     max_bw, 0, mycol+level_dist )
*
        ENDIF
*       End of "if( mycol/level_dist .le. (npcol-1)/level_dist-2 )..."
*
*       ************
        IF( (mycol/level_dist .GT. 0 ).AND.
     $      ( mycol/level_dist .LE. (npcol-1)/level_dist-1 ) ) THEN
*
*
*         Use offdiagonal block to calculate modification to diag block
*           of processor to the left
*
          CALL cgemm( 'N', 'N', max_bw, nrhs, max_bw, -cone,
     $                     af( work_u+odd_size*bwl+2*mbw2+1 ),
     $                     max_bw,
     $                     b( part_offset+odd_size+1 ),
     $                     lldb, czero,
     $                     work( 1 ),
     $                     max_bw )
*
*         Send contribution to diagonal block's owning processor.
*
          CALL cgesd2d( ictxt, max_bw, nrhs,
     $                     work( 1 ),
     $                     max_bw, 0, mycol-level_dist )
*
        ENDIF
*       End of "if( mycol/level_dist.le. (npcol-1)/level_dist -1 )..."
*
   44  CONTINUE
*
      ELSE
*
******************** BACKSOLVE *************************************
*
********************************************************************
*     .. Begin reduced system phase of algorithm ..
********************************************************************
*
*
*
*       The last processor does not participate in the solution of the
*       reduced system and just waits to receive its solution.
        IF( mycol .EQ. npcol-1 ) THEN
          GOTO 54
        ENDIF
*
*       Determine number of steps in tree loop
*
        level_dist = 1
   57   CONTINUE
        IF( mod( (mycol+1)/level_dist, 2) .NE. 0 ) GOTO 56
*
          level_dist = level_dist*2
*
        GOTO 57
   56   CONTINUE
*
*
        IF( (mycol/level_dist .GT. 0 ).AND.
     $      ( mycol/level_dist .LE. (npcol-1)/level_dist-1 ) ) THEN
*
*         Receive solution from processor to left
*
          CALL cgerv2d( ictxt, max_bw, nrhs,
     $                     work( 1 ),
     $                     max_bw, 0, mycol-level_dist )
*
*
*         Use offdiagonal block to calculate modification to RHS stored
*           on this processor
*
          CALL cgemm( 'C', 'N', max_bw, nrhs, max_bw, -cone,
     $                     af( work_u+odd_size*bwl+2*mbw2+1 ),
     $                     max_bw,
     $                     work( 1 ),
     $                     max_bw, cone,
     $                     b( part_offset+odd_size+1 ),
     $                     lldb )
        ENDIF
*       End of "if( mycol/level_dist.le. (npcol-1)/level_dist -1 )..."
*
*
        IF( mycol/level_dist .LE. (npcol-1)/level_dist-2 )THEN
*
*         Receive solution from processor to right
*
          CALL cgerv2d( ictxt, max_bw, nrhs,
     $                     work( 1 ),
     $                     max_bw, 0, mycol+level_dist )
*
*         Calculate contribution from this block to next diagonal block
*
          CALL cgemm( 'N', 'N', max_bw, nrhs, max_bw, -cone,
     $                     af( work_u+(odd_size)*bwl+1 ),
     $                     max_bw,
     $                     work( 1 ),
     $                     max_bw, cone,
     $                     b( part_offset+odd_size+1 ),
     $                     lldb )
*
        ENDIF
*       End of "if( mycol/level_dist .le. (npcol-1)/level_dist-2 )..."
*
*
*       Solve with diagonal block
*
        CALL ctbtrs( 'U', 'N', 'N', max_bw, min( bwu, max_bw-1 ), nrhs,
     $               af( odd_size*bwu+mbw2+1-min( bwu, max_bw-1 ) ),
     $               max_bw+1, b( part_offset+odd_size+1 ), lldb,
     $               info )
*
        IF( info.NE.0 ) THEN
          GO TO 1000
        ENDIF
*
*
*
***Modification Loop *******
*
   52   CONTINUE
        IF( level_dist .EQ. 1 ) GOTO 51
*
          level_dist = level_dist/2
*
*         Send solution to the right
*
          IF( mycol+level_dist .LT. npcol-1 ) THEN
*
          CALL cgesd2d( ictxt, max_bw, nrhs,
     $                     b( part_offset+odd_size+1 ),
     $                     lldb, 0, mycol+level_dist )
*
          ENDIF
*
*         Send solution to left
*
          IF( mycol-level_dist .GE. 0 ) THEN
*
          CALL cgesd2d( ictxt, max_bw, nrhs,
     $                     b( part_offset+odd_size+1 ),
     $                     lldb, 0, mycol-level_dist )
*
          ENDIF
*
        GOTO 52
   51   CONTINUE
*       [End of GOTO Loop]
*
   54   CONTINUE
*          [Processor npcol - 1 jumped to here to await next stage]
*
*******************************
*       Reduced system has been solved, communicate solutions to nearest
*         neighbors in preparation for local computation phase.
*
*
*       Send elements of solution to next proc
*
        IF( mycol .LT. npcol-1) THEN
*
          CALL cgesd2d( ictxt, max_bw, nrhs,
     $                     b( part_offset+odd_size+1 ), lldb,
     $                     0, mycol +1 )
*
        ENDIF
*
*       Receive modifications to processor's right hand sides
*
        IF( mycol .GT. 0) THEN
*
          CALL cgerv2d( ictxt, max_bw, nrhs,
     $                     work( 1 ), max_bw,
     $                     0, mycol - 1 )
*
        ENDIF
*
*
*
**********************************************
*       Local computation phase
**********************************************
*
        IF ( mycol .NE. 0 ) THEN
*         Use the "spike" fillin to calculate contribution from previous
*           processor's solution.
*
          CALL cgemm( 'N', 'N', odd_size, nrhs, bwl, -cone,
     $                af( work_u+1 ), odd_size, work( 1+max_bw-bwl ),
     $                max_bw, cone, b( part_offset+1 ), lldb )
*
        ENDIF
*
*
        IF ( mycol .LT. np-1 ) THEN
*         Use factorization of odd-even connection block to modify
*           locally stored portion of right hand side(s)
*
*
*         First copy and multiply it into temporary storage,
*           then use it on RHS
*
          CALL clamov( 'N', bwu, nrhs, b( part_offset+odd_size+1), lldb,
     $                 work( 1+max_bw-bwu ), max_bw+bwl )
*
          CALL ctrmm( 'L', 'L', 'N', 'N', bwu, nrhs, -cone,
     $                a(( ofst+1+odd_size*llda )), llda-1,
     $                work( 1+max_bw-bwu ), max_bw+bwl )
*
          CALL cmatadd( bwu, nrhs, cone, work( 1+max_bw-bwu ),
     $                  max_bw+bwl, cone,
     $                  b( part_offset+odd_size-bwu+1 ), lldb )
*
        ENDIF
*
*       Use main partition in each processor to solve locally
*
        CALL ctbtrs( uplo, 'N', 'N', odd_size,
     $                    bwu, nrhs,
     $                    a( ofst+1 ),
     $                    llda,  b( part_offset+1 ),
     $                    lldb, info )
*
      ENDIF
*     End of "IF( LSAME( TRANS, 'N' ) )"...
*
*
      ENDIF
*     End of "IF( LSAME( UPLO, 'L' ) )"...
 1000 CONTINUE
*
*
*     Free BLACS space used to hold standard-form grid.
*
      IF( ictxt_save .NE. ictxt_new ) THEN
         CALL blacs_gridexit( ictxt_new )
      ENDIF
*
 1234 CONTINUE
*
*     Restore saved input parameters
*
      ictxt = ictxt_save
      np = np_save
*
*     Output minimum worksize
*
      work( 1 ) = work_size_min
*
*
      RETURN
*
*     End of PCDBTRSV
*

Here is the call graph for this function:

Here is the caller graph for this function: