pdpoequ.f

Go to the documentation of this file.

      SUBROUTINE pdpoequ( N, A, IA, JA, DESCA, SR, SC, SCOND, AMAX,
     $                    INFO )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 25, 2001
*
*     .. Scalar Arguments ..
      INTEGER            IA, INFO, JA, N
      DOUBLE PRECISION   AMAX, SCOND
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      DOUBLE PRECISION   A( * ), SC( * ), SR( * )
*     ..
*
*  Purpose
*  =======
*
*  PDPOEQU computes row and column scalings intended to
*  equilibrate a distributed symmetric positive definite matrix
*  sub( A ) = A(IA:IA+N-1,JA:JA+N-1) and reduce its condition number
*  (with respect to the two-norm).  SR and SC contain the scale
*  factors, S(i) = 1/sqrt(A(i,i)), chosen so that the scaled distri-
*  buted matrix B with elements B(i,j) = S(i)*A(i,j)*S(j) has ones on
*  the  diagonal.  This choice of SR and SC puts the condition number
*  of B within a factor N of the smallest possible condition number
*  over all possible diagonal scalings.
*
*  The scaling factor are stored along process rows in SR and along
*  process columns in SC. The duplication of information simplifies
*  greatly the application of the factors.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on i.e the
*          order of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input) DOUBLE PRECISION pointer into the local memory
*          to an array of local dimension ( LLD_A, LOCc(JA+N-1) ), the
*          N-by-N symmetric positive definite distributed matrix
*          sub( A ) whose scaling factors are to be computed.  Only the
*          diagonal elements of sub( A ) are referenced.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  SR      (local output) DOUBLE PRECISION array, dimension LOCr(M_A)
*          If INFO = 0, SR(IA:IA+N-1) contains the row scale factors
*          for sub( A ). SR is aligned with the distributed matrix A,
*          and replicated across every process column. SR is tied to the
*          distributed matrix A.
*
*  SC      (local output) DOUBLE PRECISION array, dimension LOCc(N_A)
*          If INFO = 0, SC(JA:JA+N-1) contains the column scale factors
*          for A(IA:IA+M-1,JA:JA+N-1). SC is aligned with the distribu-
*          ted matrix A, and replicated down every process row. SC is
*          tied to the distributed matrix A.
*
*  SCOND   (global output) DOUBLE PRECISION
*          If INFO = 0, SCOND contains the ratio of the smallest SR(i)
*          (or SC(j)) to the largest SR(i) (or SC(j)), with
*          IA <= i <= IA+N-1 and JA <= j <= JA+N-1. If SCOND >= 0.1
*          and AMAX is neither too large nor too small, it is not worth
*          scaling by SR (or SC).
*
*  AMAX    (global output) DOUBLE PRECISION
*          Absolute value of largest matrix element.  If AMAX is very
*          close to overflow or very close to underflow, the matrix
*          should be scaled.
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*          > 0:  If INFO = K, the K-th diagonal entry of sub( A ) is
*                nonpositive.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      CHARACTER          ALLCTOP, COLCTOP, ROWCTOP
      INTEGER            IACOL, IAROW, ICOFF, ICTXT, ICURCOL, ICURROW,
     $                   idumm, ii, iia, ioffa, ioffd, iroff, j, jb, jj,
     $                   jja, jn, lda, ll, mycol, myrow, np, npcol,
     $                   nprow, nq
      DOUBLE PRECISION   AII, SMIN
*     ..
*     .. Local Arrays ..
      INTEGER            DESCSC( DLEN_ ), DESCSR( DLEN_ )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, descset, dgamn2d,
     $                   dgamx2d, dgsum2d, igamn2d, infog2l,
     $                   pchk1mat, pb_topget, pxerbla
*     ..
*     .. External Functions ..
      INTEGER            ICEIL, NUMROC
      DOUBLE PRECISION   PDLAMCH
      EXTERNAL           iceil, numroc, pdlamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, mod, sqrt
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters.
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(500+ctxt_)
      ELSE
         CALL chk1mat( n, 1, n, 1, ia, ja, desca, 5, info )
         CALL pchk1mat( n, 1, n, 1, ia, ja, desca, 5, 0, idumm, idumm,
     $                  info )
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PDPOEQU', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 ) THEN
         scond = one
         amax = zero
         RETURN
      END IF
*
      CALL pb_topget( ictxt, 'Combine', 'All', allctop )
      CALL pb_topget( ictxt, 'Combine', 'Rowwise', rowctop )
      CALL pb_topget( ictxt, 'Combine', 'Columnwise', colctop )
*
*     Compute some local indexes
*
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, iia, jja,
     $              iarow, iacol )
      iroff = mod( ia-1, desca( mb_ ) )
      icoff = mod( ja-1, desca( nb_ ) )
      np = numroc( n+iroff, desca( mb_ ), myrow, iarow, nprow )
      nq = numroc( n+icoff, desca( nb_ ), mycol, iacol, npcol )
      IF( myrow.EQ.iarow )
     $   np = np - iroff
      IF( mycol.EQ.iacol )
     $   nq = nq - icoff
      jn = min( iceil( ja, desca( nb_ ) ) * desca( nb_ ), ja+n-1 )
      lda = desca( lld_ )
*
*     Assign descriptors for SR and SC arrays
*
      CALL descset( descsr, n, 1, desca( mb_ ), 1, 0, 0, ictxt,
     $               max( 1, np ) )
      CALL descset( descsc, 1, n, 1, desca( nb_ ), 0, 0, ictxt, 1 )
*
*     Initialize the scaling factors to zero.
*
      DO 10 ii = iia, iia+np-1
         sr( ii ) = zero
   10 CONTINUE
*
      DO 20 jj = jja, jja+nq-1
         sc( jj ) = zero
   20 CONTINUE
*
*     Find the minimum and maximum diagonal elements.
*     Handle first block separately.
*
      ii = iia
      jj = jja
      jb = jn-ja+1
      smin = one / pdlamch( ictxt, 'S' )
      amax = zero
*
      ioffa = ii+(jj-1)*lda
      IF( myrow.EQ.iarow .AND. mycol.EQ.iacol ) THEN
         ioffd = ioffa
         DO 30 ll = 0, jb-1
            aii = a( ioffd  )
            sr( ii+ll ) = aii
            sc( jj+ll ) = aii
            smin = min( smin, aii )
            amax = max( amax, aii )
            IF( aii.LE.zero .AND. info.EQ.0 )
     $         info = ll + 1
            ioffd = ioffd + lda + 1
   30    CONTINUE
      END IF
*
      IF( myrow.EQ.iarow ) THEN
         ii = ii + jb
         ioffa = ioffa + jb
      END IF
      IF( mycol.EQ.iacol ) THEN
         jj = jj + jb
         ioffa = ioffa + jb*lda
      END IF
      icurrow = mod( iarow+1, nprow )
      icurcol = mod( iacol+1, npcol )
*
*     Loop over remaining blocks of columns
*
      DO 50 j = jn+1, ja+n-1, desca( nb_ )
         jb = min( n-j+ja, desca( nb_ ) )
*
         IF( myrow.EQ.icurrow .AND. mycol.EQ.icurcol ) THEN
            ioffd = ioffa
            DO 40 ll = 0, jb-1
               aii = a( ioffd )
               sr( ii+ll ) = aii
               sc( jj+ll ) = aii
               smin = min( smin, aii )
               amax = max( amax, aii )
               IF( aii.LE.zero .AND. info.EQ.0 )
     $            info = j + ll - ja + 1
               ioffd = ioffd + lda + 1
   40       CONTINUE
         END IF
*
         IF( myrow.EQ.icurrow ) THEN
            ii = ii + jb
            ioffa = ioffa + jb
         END IF
         IF( mycol.EQ.icurcol ) THEN
            jj = jj + jb
            ioffa = ioffa + jb*lda
         END IF
         icurrow = mod( icurrow+1, nprow )
         icurcol = mod( icurcol+1, npcol )
*
   50 CONTINUE
*
*     Compute scaling factors
*
      CALL dgsum2d( ictxt, 'Columnwise', colctop, 1, nq, sc( jja ),
     $              1, -1, mycol )
      CALL dgsum2d( ictxt, 'Rowwise', rowctop, np, 1, sr( iia ),
     $              max( 1, np ), -1, mycol )
*
      CALL dgamx2d( ictxt, 'All', allctop, 1, 1, amax, 1, idumm, idumm,
     $              -1, -1, mycol )
      CALL dgamn2d( ictxt, 'All', allctop, 1, 1, smin, 1, idumm, idumm,
     $              -1, -1, mycol )
*
      IF( smin.LE.zero ) THEN
*
*        Find the first non-positive diagonal element and return.
*
         CALL igamn2d( ictxt, 'All', allctop, 1, 1, info, 1, ii, jj, -1,
     $                 -1, mycol )
         RETURN
*
      ELSE
*
*        Set the scale factors to the reciprocals
*        of the diagonal elements.
*
         DO 60 ii = iia, iia+np-1
            sr( ii ) = one / sqrt( sr( ii ) )
   60    CONTINUE
*
         DO 70 jj = jja, jja+nq-1
            sc( jj ) = one / sqrt( sc( jj ) )
   70    CONTINUE
*
*        Compute SCOND = min(S(I)) / max(S(I))
*
         scond = sqrt( smin ) / sqrt( amax )
*
      END IF
*
      RETURN
*
*     End of PDPOEQU
*
      SUBROUTINE pdpoequ( N, A, IA, JA, DESCA, SR, SC, SCOND, AMAX, …
      END