pzpotrf()

subroutine pzpotrf	(	character	uplo,
		integer	n,
		complex*16, dimension( * )	a,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		integer	info
	)

Definition at line 1 of file pzpotrf.f.

*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 25, 2001
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            IA, INFO, JA, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      COMPLEX*16         A( * )
*     ..
*
*  Purpose
*  =======
*
*  PZPOTRF computes the Cholesky factorization of an N-by-N complex
*  hermitian positive definite distributed matrix sub( A ) denoting
*  A(IA:IA+N-1, JA:JA+N-1).
*
*  The factorization has the form
*
*            sub( A ) = U' * U ,  if UPLO = 'U', or
*
*            sub( A ) = L  * L',  if UPLO = 'L',
*
*  where U is an upper triangular matrix and L is lower triangular.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  This routine requires square block decomposition ( MB_A = NB_A ).
*
*  Arguments
*  =========
*
*  UPLO    (global input) CHARACTER
*          = 'U':  Upper triangle of sub( A ) is stored;
*          = 'L':  Lower triangle of sub( A ) is stored.
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) COMPLEX*16 pointer into the
*          local memory to an array of dimension (LLD_A, LOCc(JA+N-1)).
*          On entry, this array contains the local pieces of the
*          N-by-N Hermitian distributed matrix sub( A ) to be factored.
*          If UPLO = 'U', the leading N-by-N upper triangular part of
*          sub( A ) contains the upper triangular part of the matrix,
*          and its strictly lower triangular part is not referenced.
*          If UPLO = 'L', the leading N-by-N lower triangular part of
*          sub( A ) contains the lower triangular part of the distribu-
*          ted matrix, and its strictly upper triangular part is not
*          referenced. On exit, if UPLO = 'U', the upper triangular
*          part of the distributed matrix contains the Cholesky factor
*          U, if UPLO = 'L', the lower triangular part of the distribu-
*          ted matrix contains the Cholesky factor L.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*          > 0:  If INFO = K, the leading minor of order K,
*                A(IA:IA+K-1,JA:JA+K-1) is not positive definite, and
*                the factorization could not be completed.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d+0 )
      COMPLEX*16         CONE
      parameter( cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      CHARACTER          COLBTOP, ROWBTOP
      INTEGER            I, ICOFF, ICTXT, IROFF, J, JB, JN, MYCOL,
     $                   MYROW, NPCOL, NPROW
*     ..
*     .. Local Arrays ..
      INTEGER            IDUM1( 1 ), IDUM2( 1 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, pchk1mat, pb_topget,
     $                   pb_topset, pxerbla, pzpotf2, pzherk,
     $                   pztrsm
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICEIL
      EXTERNAL           iceil, lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          ichar, min, mod
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(600+ctxt_)
      ELSE
         CALL chk1mat( n, 2, n, 2, ia, ja, desca, 6, info )
         upper = lsame( uplo, 'U' )
         IF( info.EQ.0 ) THEN
            iroff = mod( ia-1, desca( mb_ ) )
            icoff = mod( ja-1, desca( nb_ ) )
            IF ( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
               info = -1
            ELSE IF( iroff.NE.0 ) THEN
               info = -4
            ELSE IF( icoff.NE.0 ) THEN
               info = -5
            ELSE IF( desca( mb_ ).NE.desca( nb_ ) ) THEN
               info = -(600+nb_)
            END IF
         END IF
         IF( upper ) THEN
            idum1( 1 ) = ichar( 'U' )
         ELSE
            idum1( 1 ) = ichar( 'L' )
         END IF
         idum2( 1 ) = 1
         CALL pchk1mat( n, 2, n, 2, ia, ja, desca, 6, 1, idum1, idum2,
     $                  info )
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PZPOTRF', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      IF( upper ) THEN
*
*        Split-ring topology for the communication along process
*        columns, 1-tree topology along process rows.
*
         CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', ' ' )
         CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', 'S-ring' )
*
*        A is upper triangular, compute Cholesky factorization A = U'*U.
*
*        Handle the first block of columns separately
*
         jn = min( iceil( ja, desca( nb_ ) )*desca(nb_), ja+n-1 )
         jb = jn - ja + 1
*
*        Perform unblocked Cholesky factorization on JB block
*
         CALL pzpotf2( uplo, jb, a, ia, ja, desca, info )
         IF( info.NE.0 )
     $      GO TO 30
*
         IF( jb+1.LE.n ) THEN
*
*           Form the row panel of U using the triangular solver
*
            CALL pztrsm( 'Left', uplo, 'Conjugate transpose',
     $                   'Non-Unit', jb, n-jb, cone, a, ia, ja, desca,
     $                   a, ia, ja+jb, desca )
*
*           Update the trailing matrix, A = A - U'*U
*
            CALL pzherk( uplo, 'Conjugate transpose', n-jb, jb, -one, a,
     $                   ia, ja+jb, desca, one, a, ia+jb, ja+jb, desca )
         END IF
*
*        Loop over remaining block of columns
*
         DO 10 j = jn+1, ja+n-1, desca( nb_ )
            jb = min( n-j+ja, desca( nb_ ) )
            i = ia + j - ja
*
*           Perform unblocked Cholesky factorization on JB block
*
            CALL pzpotf2( uplo, jb, a, i, j, desca, info )
            IF( info.NE.0 ) THEN
               info = info + j - ja
               GO TO 30
            END IF
*
            IF( j-ja+jb+1.LE.n ) THEN
*
*              Form the row panel of U using the triangular solver
*
               CALL pztrsm( 'Left', uplo, 'Conjugate transpose',
     $                      'Non-Unit', jb, n-j-jb+ja, cone, a, i, j,
     $                      desca, a, i, j+jb, desca )
*
*              Update the trailing matrix, A = A - U'*U
*
               CALL pzherk( uplo, 'Conjugate transpose', n-j-jb+ja, jb,
     $                      -one, a, i, j+jb, desca, one, a, i+jb,
     $                      j+jb, desca )
            END IF
   10    CONTINUE
*
      ELSE
*
*        1-tree topology for the communication along process columns,
*        Split-ring topology along process rows.
*
         CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', 'S-ring' )
         CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', ' ' )
*
*        A is lower triangular, compute Cholesky factorization A = L*L'
*        (right-looking)
*
*        Handle the first block of columns separately
*
         jn = min( iceil( ja, desca( nb_ ) )*desca( nb_ ), ja+n-1 )
         jb = jn - ja + 1
*
*        Perform unblocked Cholesky factorization on JB block
*
         CALL pzpotf2( uplo, jb, a, ia, ja, desca, info )
         IF( info.NE.0 )
     $      GO TO 30
*
         IF( jb+1.LE.n ) THEN
*
*           Form the column panel of L using the triangular solver
*
            CALL pztrsm( 'Right', uplo, 'Conjugate transpose',
     $                   'Non-Unit', n-jb, jb, cone, a, ia, ja, desca,
     $                   a, ia+jb, ja, desca )
*
*           Update the trailing matrix, A = A - L*L'
*
            CALL pzherk( uplo, 'No Transpose', n-jb, jb, -one, a, ia+jb,
     $                   ja, desca, one, a, ia+jb, ja+jb, desca )
*
         END IF
*
         DO 20 j = jn+1, ja+n-1, desca( nb_ )
            jb = min( n-j+ja, desca( nb_ ) )
            i = ia + j - ja
*
*           Perform unblocked Cholesky factorization on JB block
*
            CALL pzpotf2( uplo, jb, a, i, j, desca, info )
            IF( info.NE.0 ) THEN
               info = info + j - ja
               GO TO 30
            END IF
*
            IF( j-ja+jb+1.LE.n ) THEN
*
*              Form the column panel of L using the triangular solver
*
               CALL pztrsm( 'Right', uplo, 'Conjugate transpose',
     $                      'Non-Unit', n-j-jb+ja, jb, cone, a, i, j,
     $                      desca, a, i+jb, j, desca )
*
*              Update the trailing matrix, A = A - L*L'
*
               CALL pzherk( uplo, 'No Transpose', n-j-jb+ja, jb, -one,
     $                      a, i+jb, j, desca, one, a, i+jb, j+jb,
     $                      desca )
*
            END IF
   20    CONTINUE
*
      END IF
*
   30 CONTINUE
*
      CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      RETURN
*
*     End of PZPOTRF
*

Here is the call graph for this function:

Here is the caller graph for this function: