pzpotf2()

subroutine pzpotf2	(	character	uplo,
		integer	n,
		complex*16, dimension( * )	a,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		integer	info
	)

Definition at line 1 of file pzpotf2.f.

*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            IA, INFO, JA, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      COMPLEX*16         A( * )
*     ..
*
*  Purpose
*  =======
*
*  PZPOTF2 computes the Cholesky factorization of a complex hermitian
*  positive definite distributed matrix sub( A )=A(IA:IA+N-1,JA:JA+N-1).
*
*  The factorization has the form
*
*            sub( A ) = U' * U ,  if UPLO = 'U', or
*
*            sub( A ) = L  * L',  if UPLO = 'L',
*
*  where U is an upper triangular matrix and L is lower triangular.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  This routine requires N <= NB_A-MOD(JA-1, NB_A) and square block
*  decomposition ( MB_A = NB_A ).
*
*  Arguments
*  =========
*
*  UPLO    (global input) CHARACTER
*          = 'U':  Upper triangle of sub( A ) is stored;
*          = 'L':  Lower triangle of sub( A ) is stored.
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) COMPLEX*16 pointer into the
*          local memory to an array of dimension (LLD_A, LOCc(JA+N-1)).
*          On entry, this array contains the local pieces of the
*          N-by-N symmetric distributed matrix sub( A ) to be factored.
*          If UPLO = 'U', the leading N-by-N upper triangular part of
*          sub( A ) contains the upper triangular part of the matrix,
*          and its strictly lower triangular part is not referenced.
*          If UPLO = 'L', the leading N-by-N lower triangular part of
*          sub( A ) contains the lower triangular part of the distribu-
*          ted matrix, and its strictly upper triangular part is not
*          referenced.  On exit, if UPLO = 'U', the upper triangular
*          part of the distributed matrix contains the Cholesky factor
*          U, if UPLO = 'L', the lower triangular part of the distribu-
*          ted matrix contains the Cholesky factor L.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  INFO    (local output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*          > 0:  If INFO = K, the leading minor of order K,
*                A(IA:IA+K-1,JA:JA+K-1) is not positive definite, and
*                the factorization could not be completed.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
      COMPLEX*16         CONE
      parameter( cone = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      CHARACTER          COLBTOP, ROWBTOP
      INTEGER            IACOL, IAROW, ICOFF, ICTXT, ICURR, IDIAG, IIA,
     $                   IOFFA, IROFF, J, JJA, LDA, MYCOL, MYROW,
     $                   NPCOL, NPROW
      DOUBLE PRECISION   AJJ
      COMPLEX*16         DOT
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_abort, blacs_gridinfo, chk1mat, igebr2d,
     $                   igebs2d, infog2l, pb_topget, pxerbla, zgemv,
     $                   zlacgv, zdscal, zzdotc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, mod, sqrt
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters.
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(600+ctxt_)
      ELSE
         CALL chk1mat( n, 2, n, 2, ia, ja, desca, 6, info )
         IF( info.EQ.0 ) THEN
            upper = lsame( uplo, 'U' )
            iroff = mod( ia-1, desca( mb_ ) )
            icoff = mod( ja-1, desca( nb_ ) )
            IF ( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
               info = -1
            ELSE IF( n+icoff.GT.desca( nb_ ) ) THEN
               info = -2
            ELSE IF( iroff.NE.0 ) THEN
               info = -4
            ELSE IF( icoff.NE.0 ) THEN
               info = -5
            ELSE IF( desca( mb_ ).NE.desca( nb_ ) ) THEN
               info = -(600+nb_)
            END IF
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PZPOTF2', -info )
         CALL blacs_abort( ictxt, 1 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Compute local information
*
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, iia, jja,
     $              iarow, iacol )
      CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      IF ( upper ) THEN
*
*        Process (IAROW, IACOL) owns block to be factorized
*
         IF( myrow.EQ.iarow ) THEN
            IF( mycol.EQ.iacol ) THEN
*
*              Compute the Cholesky factorization A = U'*U.
*
               lda = desca( lld_ )
               idiag = iia + ( jja - 1 ) * lda
               ioffa = idiag
*
               DO 10 j = ja, ja+n-1
*
*                 Compute U(J,J) and test for non-positive-definiteness.
*
                  CALL zzdotc( j-ja, dot, a( ioffa ), 1, a( ioffa ), 1 )
                  ajj = dble( a( idiag ) - dot )
                  IF( ajj.LE.zero ) THEN
                     a( idiag ) = ajj
                     info = j - ja + 1
                     GO TO 20
                  END IF
                  ajj = sqrt( ajj )
                  a( idiag ) = ajj
*
*                 Compute elements J+1:JA+N-1 of row J.
*
                  IF( j.LT.ja+n-1 ) THEN
                     icurr = idiag + lda
                     CALL zlacgv( j-ja, a( ioffa ), 1 )
                     CALL zgemv( 'Transpose', j-ja, ja+n-j-1, -cone,
     $                           a( ioffa+lda ), lda, a( ioffa ), 1,
     $                           cone, a( icurr ), lda )
                     CALL zlacgv( j-ja, a( ioffa ), 1 )
                     CALL zdscal( ja+n-j-1, one / ajj, a( icurr ),
     $                            lda )
                  END IF
                  idiag = idiag + lda + 1
                  ioffa = ioffa + lda
   10          CONTINUE
*
   20          CONTINUE
*
*              Broadcast INFO to all processes in my IAROW.
*
               CALL igebs2d( ictxt, 'Rowwise', rowbtop, 1, 1, info, 1 )
*
            ELSE
*
               CALL igebr2d( ictxt, 'Rowwise', rowbtop, 1, 1, info, 1,
     $                       myrow, iacol )
            END IF
*
*           IAROW bcasts along columns so that everyone has INFO
*
            CALL igebs2d( ictxt, 'Columnwise', colbtop, 1, 1, info, 1 )
*
         ELSE
*
            CALL igebr2d( ictxt, 'Columnwise', colbtop, 1, 1, info, 1,
     $                    iarow, mycol )
*
         END IF
*
      ELSE
*
*        Process (IAROW, IACOL) owns block to be factorized
*
         IF( mycol.EQ.iacol ) THEN
            IF( myrow.EQ.iarow ) THEN
*
*              Compute the Cholesky factorization A = L*L'.
*
               lda = desca( lld_ )
               idiag = iia + ( jja - 1 ) * lda
               ioffa = idiag
*
               DO 30 j = ja, ja+n-1
*
*                 Compute L(J,J) and test for non-positive-definiteness.
*
                  CALL zzdotc( j-ja, dot, a( ioffa ), lda, a( ioffa ),
     $                         lda )
                  ajj = dble( a( idiag ) - dot )
                  IF ( ajj.LE.zero ) THEN
                     a( idiag ) = ajj
                     info = j - ja + 1
                     GO TO 40
                  END IF
                  ajj = sqrt( ajj )
                  a( idiag ) = ajj
*
*                 Compute elements J+1:JA+N-1 of column J.
*
                  IF( j.LT.ja+n-1 ) THEN
                     icurr = idiag + 1
                     CALL zlacgv( j-ja, a( ioffa ), lda )
                     CALL zgemv( 'No transpose', ja+n-j-1, j-ja, -cone,
     $                           a( ioffa+1 ), lda, a( ioffa ), lda,
     $                           cone, a( icurr ), 1 )
                     CALL zlacgv( j-ja, a( ioffa ), lda )
                     CALL zdscal( ja+n-j-1, one / ajj, a( icurr ), 1 )
                  END IF
                  idiag = idiag + lda + 1
                  ioffa = ioffa + 1
   30          CONTINUE
*
   40          CONTINUE
*
*              Broadcast INFO to everyone in IACOL
*
               CALL igebs2d( ictxt, 'Columnwise', colbtop, 1, 1, info,
     $                       1 )
*
            ELSE
*
               CALL igebr2d( ictxt, 'Columnwise', colbtop, 1, 1, info,
     $                       1, iarow, mycol )
*
            END IF
*
*           IACOL bcasts INFO along rows so that everyone has it
*
            CALL igebs2d( ictxt, 'Rowwise', rowbtop, 1, 1, info, 1 )
*
         ELSE
*
            CALL igebr2d( ictxt, 'Rowwise', rowbtop, 1, 1, info, 1,
     $                    myrow, iacol )
*
         END IF
*
      END IF
*
      RETURN
*
*     End of PZPOTF2
*

Here is the call graph for this function:

Here is the caller graph for this function: