zzdotc.f

Go to the documentation of this file.

      SUBROUTINE zzdotc( N, DOTC, X, INCX, Y, INCY )
*
*  -- ScaLAPACK tools routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            INCX, INCY, N
      COMPLEX*16         DOTC
*     ..
*     .. Array Arguments ..
      COMPLEX*16         X( * ), Y( * )
*     ..
*
*  Purpose
*  =======
*
*  ZZDOTC is a simple FORTRAN wrapper around the BLAS function
*  ZDOTC returning the result in the parameter list instead.
*
*  =====================================================================
*
*     .. Local Scalars ..
      COMPLEX*16         ZTEMP
      INTEGER            I,IX,IY
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC dconjg
*     ..
*     .. Executable Statements ..
*
      ztemp = (0.0d0,0.0d0)
      dotc = (0.0d0,0.0d0)
      IF (n.LE.0) RETURN
      IF (incx.EQ.1 .AND. incy.EQ.1) THEN
*
*        code for both increments equal to 1
*
         DO i = 1,n
            ztemp = ztemp + dconjg(x(i))*y(i)
         END DO
      ELSE
*
*        code for unequal increments or equal increments
*          not equal to 1
*
         ix = 1
         iy = 1
         IF (incx.LT.0) ix = (-n+1)*incx + 1
         IF (incy.LT.0) iy = (-n+1)*incy + 1
         DO i = 1,n
            ztemp = ztemp + dconjg(x(ix))*y(iy)
            ix = ix + incx
            iy = iy + incy
         END DO
      END IF
      dotc = ztemp
*
      RETURN
*
*     End of ZZDOTC
*
      END