pstrtri.f

Go to the documentation of this file.

      SUBROUTINE pstrtri( UPLO, DIAG, N, A, IA, JA, DESCA, INFO )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, UPLO
      INTEGER            IA, INFO, JA, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      REAL               A( * )
*     ..
*
*  Purpose
*  =======
*
*  PSTRTRI computes the inverse of a upper or lower triangular
*  distributed matrix sub( A ) = A(IA:IA+N-1,JA:JA+N-1).
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  UPLO    (global input) CHARACTER
*          Specifies whether the distributed matrix sub( A ) is upper
*          or lower triangular:
*          = 'U':  Upper triangular,
*          = 'L':  Lower triangular.
*
*  DIAG    (global input) CHARACTER
*          Specifies whether or not the distributed matrix sub( A )
*          is unit triangular:
*          = 'N':  Non-unit triangular,
*          = 'U':  Unit triangular.
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) REAL pointer into the
*          local memory to an array of dimension (LLD_A,LOCc(JA+N-1)).
*          On entry, this array contains the local pieces of the
*          triangular matrix sub( A ).  If UPLO = 'U', the leading
*          N-by-N upper triangular part of the matrix sub( A ) contains
*          the upper triangular matrix to be inverted, and the strictly
*          lower triangular part of sub( A ) is not referenced.
*          If UPLO = 'L', the leading N-by-N lower triangular part of
*          the matrix sub( A ) contains the lower triangular matrix,
*          and the strictly upper triangular part of sub( A ) is not
*          referenced.
*          On exit, the (triangular) inverse of the original matrix.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*            > 0:  If INFO = K, A(IA+K-1,JA+K-1) is exactly zero.  The
*                  triangular matrix sub( A ) is singular and its
*                  inverse can not be computed.
*
*  ====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOUNIT, UPPER
      INTEGER            I, ICOFF, ICTXT, IROFF, ICURCOL, ICURROW,
     $                   IDUMMY, II, IOFFA, J, JB, JJ, JN, LDA, MYCOL,
     $                   MYROW, NN, NPCOL, NPROW
*     ..
*     .. Local Arrays ..
      INTEGER            IDUM1( 2 ), IDUM2( 2 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, igamx2d, infog2l,
     $                   pchk1mat, pstrti2, pstrmm, pstrsm,
     $                   pxerbla
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICEIL
      EXTERNAL           iceil, lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          ichar, min, mod
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test input parameters
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(700+ctxt_)
      ELSE
         upper = lsame( uplo, 'U' )
         nounit = lsame( diag, 'N' )
*
         CALL chk1mat( n, 3, n, 3, ia, ja, desca, 7, info )
         IF( info.EQ.0 ) THEN
            iroff = mod( ia-1, desca( mb_ ) )
            icoff = mod( ja-1, desca( nb_ ) )
            IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
               info = -1
            ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
               info = -2
            ELSE IF( iroff.NE.icoff .OR. iroff.NE.0 ) THEN
               info = -6
            ELSE IF( desca( mb_ ).NE.desca( nb_ ) ) THEN
               info = -(700+nb_)
            END IF
         END IF
*
         IF( upper ) THEN
            idum1( 1 ) = ichar( 'U' )
         ELSE
            idum1( 1 ) = ichar( 'L' )
         END IF
         idum2( 1 ) = 1
         IF( nounit ) THEN
            idum1( 2 ) = ichar( 'N' )
         ELSE
            idum1( 2 ) = ichar( 'U' )
         END IF
         idum2( 2 ) = 2
*
         CALL pchk1mat( n, 3, n, 3, ia, ja, desca, 7, 2, idum1, idum2,
     $                  info )
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PSTRTRI', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Check for singularity if non-unit.
*
      jn = min( iceil( ja, desca( nb_ ) ) * desca( nb_ ), ja+n-1 )
      IF( nounit ) THEN
         CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol,
     $                 ii, jj, icurrow, icurcol )
*
*        Handle first block separately
*
         jb = jn-ja+1
         lda = desca( lld_ )
         IF( myrow.EQ.icurrow .AND. mycol.EQ.icurcol ) THEN
            ioffa = ii+(jj-1)*lda
            DO 10 i = 0, jb-1
               IF( a( ioffa ).EQ.zero .AND. info.EQ.0 )
     $            info = i + 1
               ioffa = ioffa + lda + 1
   10       CONTINUE
         END IF
         IF( myrow.EQ.icurrow )
     $      ii = ii + jb
         IF( mycol.EQ.icurcol )
     $      jj = jj + jb
         icurrow = mod( icurrow+1, nprow )
         icurcol = mod( icurcol+1, npcol )
*
*        Loop over remaining blocks of columns
*
         DO 30 j = jn+1, ja+n-1, desca( nb_ )
            jb = min( ja+n-j, desca( nb_ ) )
            IF( myrow.EQ.icurrow .AND. mycol.EQ.icurcol ) THEN
               ioffa = ii+(jj-1)*lda
               DO 20 i = 0, jb-1
                  IF( a( ioffa ).EQ.zero .AND. info.EQ.0 )
     $               info = j + i - ja + 1
                  ioffa = ioffa + lda + 1
   20          CONTINUE
            END IF
            IF( myrow.EQ.icurrow )
     $         ii = ii + jb
            IF( mycol.EQ.icurcol )
     $         jj = jj + jb
            icurrow = mod( icurrow+1, nprow )
            icurcol = mod( icurcol+1, npcol )
   30    CONTINUE
         CALL igamx2d( ictxt, 'All', ' ', 1, 1, info, 1, idummy,
     $                 idummy, -1, -1, mycol )
         IF( info.NE.0 )
     $      RETURN
      END IF
*
*     Use blocked code
*
      IF( upper ) THEN
*
*        Compute inverse of upper triangular matrix
*
         jb = jn-ja+1
*
*        Handle first block of column separately
*
         CALL pstrti2( uplo, diag, jb, a, ia, ja, desca, info )
*
*        Loop over remaining block of columns
*
         DO 40 j = jn+1, ja+n-1, desca( nb_ )
            jb = min( desca( nb_ ), ja+n-j )
            i = ia + j - ja
*
*           Compute rows 1:j-1 of current block column
*
            CALL pstrmm( 'Left', uplo, 'No transpose', diag, j-ja, jb,
     $                   one, a, ia, ja, desca, a, ia, j, desca )
            CALL pstrsm( 'Right', uplo, 'No transpose', diag, j-ja,
     $                   jb, -one, a, i, j, desca, a, ia, j, desca )
*
*           Compute inverse of current diagonal block
*
            CALL pstrti2( uplo, diag, jb, a, i, j, desca, info )
*
   40    CONTINUE
*
      ELSE
*
*        Compute inverse of lower triangular matrix
*
         nn = ( ( ja+n-2 ) / desca( nb_ ) )*desca( nb_ ) + 1
         DO 50 j = nn, jn+1, -desca( nb_ )
            jb = min( desca( nb_ ), ja+n-j )
            i = ia + j - ja
            IF( j+jb.LE.ja+n-1 ) THEN
*
*              Compute rows j+jb:ja+n-1 of current block column
*
               CALL pstrmm( 'Left', uplo, 'No transpose', diag,
     $                      ja+n-j-jb, jb, one, a, i+jb, j+jb, desca,
     $                      a, i+jb, j, desca )
               CALL pstrsm( 'Right', uplo, 'No transpose', diag,
     $                      ja+n-j-jb, jb, -one, a, i, j, desca,
     $                      a, i+jb, j, desca )
            END IF
*
*           Compute inverse of current diagonal block
*
            CALL pstrti2( uplo, diag, jb, a, i, j, desca, info )
*
   50    CONTINUE
*
*        Handle the last block of columns separately
*
         jb = jn-ja+1
         IF( ja+jb.LE.ja+n-1 ) THEN
*
*           Compute rows ja+jb:ja+n-1 of current block column
*
            CALL pstrmm( 'Left', uplo, 'No transpose', diag, n-jb, jb,
     $                   one, a, ia+jb, ja+jb, desca, a, ia+jb, ja,
     $                   desca )
            CALL pstrsm( 'Right', uplo, 'No transpose', diag, n-jb, jb,
     $                   -one, a, ia, ja, desca, a, ia+jb, ja, desca )
         END IF
*
*        Compute inverse of current diagonal block
*
         CALL pstrti2( uplo, diag, jb, a, ia, ja, desca, info )
*
      END IF
*
      RETURN
*
*     End PSTRTRI
*
      END