pzgebdrv()

subroutine pzgebdrv	(	integer	m,
		integer	n,
		complex*16, dimension( * )	a,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		double precision, dimension( * )	d,
		double precision, dimension( * )	e,
		complex*16, dimension( * )	tauq,
		complex*16, dimension( * )	taup,
		complex*16, dimension( * )	work,
		integer	info
	)

Definition at line 1 of file pzgebdrv.f.

*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER              INFO, IA, JA, M, N
*     ..
*     .. Array Arguments ..
      INTEGER              DESCA( * )
      DOUBLE PRECISION   D( * ), E( * )
      COMPLEX*16         A( * ), TAUP( * ), TAUQ( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PZGEBDRV computes sub( A ) = A(IA:IA+M-1,JA:JA+N-1) from sub( A ),
*  Q, P returned by PZGEBRD:
*
*                         sub( A ) := Q * B * P'.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  M       (global input) INTEGER
*          The number of rows to be operated on, i.e. the number of rows
*          of the distributed submatrix sub( A ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on, i.e. the number of
*          columns of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) COMPLEX*16 pointer into the
*          local memory to an array of dimension (LLD_A, LOCc(JA+N-1)).
*          On entry, this array contains the local pieces of sub( A )
*          as returned by PZGEBRD. On exit, the original distribu-
*          ted matrix sub( A ) is restored.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  D       (local input) DOUBLE PRECISION array, dimension
*          LOCc(JA+MIN(M,N)-1) if M >= N; LOCr(IA+MIN(M,N)-1) otherwise.
*          The distributed diagonal elements of the bidiagonal matrix
*          B: D(i) = A(i,i). D is tied to the distributed matrix A.
*
*  E       (local input) DOUBLE PRECISION array, dimension
*          LOCr(IA+MIN(M,N)-1) if M >= N; LOCc(JA+MIN(M,N)-2) otherwise.
*          The distributed off-diagonal elements of the bidiagonal
*          distributed matrix B:
*          if m >= n, E(i) = A(i,i+1) for i = 1,2,...,n-1;
*          if m < n, E(i) = A(i+1,i) for i = 1,2,...,m-1.
*          E is tied to the distributed matrix A.
*
*  TAUQ    (local input) COMPLEX*16 array dimension
*          LOCc(JA+MIN(M,N)-1). The scalar factors of the elementary
*          reflectors which represent the unitary matrix Q. TAUQ is
*          tied to the distributed matrix A. See Further Details.
*
*  TAUP    (local input) COMPLEX*16 array, dimension
*          LOCr(IA+MIN(M,N)-1). The scalar factors of the elementary
*          reflectors which represent the unitary matrix P. TAUP is
*          tied to the distributed matrix A. See Further Details.
*
*  WORK    (local workspace) COMPLEX*16 array, dimension (LWORK)
*          LWORK >= 2*NB*( MP + NQ + NB )
*
*          where NB = MB_A = NB_A,
*          IROFFA = MOD( IA-1, NB ), ICOFFA = MOD( JA-1, NB ),
*          IAROW = INDXG2P( IA, NB, MYROW, RSRC_A, NPROW ),
*          IACOL = INDXG2P( JA, NB, MYCOL, CSRC_A, NPCOL ),
*          MP = NUMROC( M+IROFFA, NB, MYROW, IAROW, NPROW ),
*          NQ = NUMROC( N+ICOFFA, NB, MYCOL, IACOL, NPCOL ).
*
*          INDXG2P and NUMROC are ScaLAPACK tool functions;
*          MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*          the subroutine BLACS_GRIDINFO.
*
*  INFO    (global output) INTEGER
*          On exit, if INFO <> 0, a discrepancy has been found between
*          the diagonal and off-diagonal elements of A and the copies
*          contained in the arrays D and E.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      DOUBLE PRECISION   REIGHT, RZERO
      parameter( reight = 8.0d+0, rzero = 0.0d+0 )
      COMPLEX*16         ONE, ZERO
      parameter( one = ( 1.0d+0, 0.0d+0 ),
     $                   zero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IACOL, IAROW, ICTXT, IIA, IL, IPTP, IPTQ,
     $                   IPV, IPW, IPWK, IOFF, IV, J, JB, JJA, JL, JV,
     $                   K, MN, MP, MYCOL, MYROW, NB, NPCOL, NPROW, NQ
      DOUBLE PRECISION   ADDBND, D2, E2
      COMPLEX*16         D1, E1
*     ..
*     .. Local Arrays ..
      INTEGER            DESCD( DLEN_ ), DESCE( DLEN_ ), DESCV( DLEN_ ),
     $                   DESCW( DLEN_ )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, descset, igsum2d, infog2l,
     $                   pdelget, pzlacpy, pzlarfb, pzlarft,
     $                   pzlaset, pzelget
*     ..
*     .. External Functions ..
      INTEGER            INDXG2P, NUMROC
      DOUBLE PRECISION   PDLAMCH
      EXTERNAL           indxg2p, numroc, pdlamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dcmplx, max, min, mod
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      info = 0
      nb = desca( mb_ )
      ioff = mod( ia-1, nb )
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, iia, jja,
     $              iarow, iacol )
      mp = numroc( m+ioff, nb, myrow, iarow, nprow )
      nq = numroc( n+ioff, nb, mycol, iacol, npcol )
      ipv  = 1
      ipw  = ipv + mp*nb
      iptp = ipw + nq*nb
      iptq = iptp + nb*nb
      ipwk = iptq + nb*nb
*
      iv = 1
      jv = 1
      mn = min( m, n )
      il = max( ( (ia+mn-2) / nb )*nb + 1, ia )
      jl = max( ( (ja+mn-2) / nb )*nb + 1, ja )
      iarow = indxg2p( il, nb, myrow, desca( rsrc_ ), nprow )
      iacol = indxg2p( jl, nb, mycol, desca( csrc_ ), npcol )
      CALL descset( descv, ia+m-il, nb, nb, nb, iarow, iacol, ictxt,
     $              max( 1, mp ) )
      CALL descset( descw, nb, ja+n-jl, nb, nb, iarow, iacol, ictxt,
     $              nb )
*
      addbnd = reight * pdlamch( ictxt, 'eps' )
*
*     When A is an upper bidiagonal form
*
      IF( m.GE.n ) THEN
*
         CALL descset( descd, 1, ja+mn-1, 1, desca( nb_ ), myrow,
     $                 desca( csrc_ ), desca( ctxt_ ), 1 )
         CALL descset( desce, ia+mn-1, 1, desca( mb_ ), 1,
     $                 desca( rsrc_ ), mycol, desca( ctxt_ ),
     $                 desca( lld_ ) )
*
         DO 10 j = 0, mn-1
            d1 = zero
            e1 = zero
            d2 = rzero
            e2 = rzero
            CALL pdelget( ' ', ' ', d2, d, 1, ja+j, descd )
            CALL pzelget( 'Columnwise', ' ', d1, a, ia+j, ja+j, desca )
            IF( j.LT.(mn-1) ) THEN
               CALL pdelget( ' ', ' ', e2, e, ia+j, 1, desce )
               CALL pzelget( 'Rowwise', ' ', e1, a, ia+j, ja+j+1,
     $                       desca )
            END IF
*
            IF( ( abs( d1-dcmplx( d2 ) ).GT.( abs( d2 )*addbnd ) ) .OR.
     $          ( abs( e1-dcmplx( e2 ) ).GT.( abs( e2 )*addbnd ) ) )
     $         info = info + 1
   10    CONTINUE
*
         DO 20 j = jl, ja+nb-ioff, -nb
            jb = min( ja+n-j, nb )
            i  = ia + j - ja
            k  = i - ia + 1
*
*           Compute upper triangular matrix TQ from TAUQ.
*
            CALL pzlarft( 'Forward', 'Columnwise', m-k+1, jb, a, i, j,
     $                    desca, tauq, work( iptq ), work( ipwk ) )
*
*           Copy Householder vectors into workspace.
*
            CALL pzlacpy( 'Lower', m-k+1, jb, a, i, j, desca,
     $                    work( ipv ), iv, jv, descv )
            CALL pzlaset( 'Upper', m-k+1, jb, zero, one, work( ipv ),
     $                    iv, jv, descv )
*
*           Zero out the strict lower triangular part of A.
*
            CALL pzlaset( 'Lower', m-k, jb, zero, zero, a, i+1, j,
     $                    desca )
*
*           Compute upper triangular matrix TP from TAUP.
*
            CALL pzlarft( 'Forward', 'Rowwise', n-k, jb, a, i, j+1,
     $                    desca, taup, work( iptp ), work( ipwk ) )
*
*           Copy Householder vectors into workspace.
*
            CALL pzlacpy( 'Upper', jb, n-k, a, i, j+1, desca,
     $                    work( ipw ), iv, jv+1, descw )
            CALL pzlaset( 'Lower', jb, n-k, zero, one, work( ipw ), iv,
     $                    jv+1, descw )
*
*           Zero out the strict+1 upper triangular part of A.
*
            CALL pzlaset( 'Upper', jb, n-k-1, zero, zero, a, i, j+2,
     $                    desca )
*
*           Apply block Householder transformation from Left.
*
            CALL pzlarfb( 'Left', 'No transpose', 'Forward',
     $                    'Columnwise', m-k+1, n-k+1, jb, work( ipv ),
     $                    iv, jv, descv, work( iptq ), a, i, j, desca,
     $                    work( ipwk ) )
*
*           Apply block Householder transformation from Right.
*
            CALL pzlarfb( 'Right', 'Conjugate transpose', 'Forward',
     $                    'Rowwise', m-k+1, n-k, jb, work( ipw ), iv,
     $                    jv+1, descw, work( iptp ), a, i, j+1, desca,
     $                    work( ipwk ) )
*
            descv( m_ ) = descv( m_ ) + nb
            descv( rsrc_ ) = mod( descv( rsrc_ ) + nprow - 1, nprow )
            descv( csrc_ ) = mod( descv( csrc_ ) + npcol - 1, npcol )
            descw( n_ ) = descw( n_ ) + nb
            descw( rsrc_ ) = descv( rsrc_ )
            descw( csrc_ ) = descv( csrc_ )
*
   20    CONTINUE
*
*        Handle first block separately
*
         jb = min( n, nb - ioff )
         iv = ioff + 1
         jv = ioff + 1
*
*        Compute upper triangular matrix TQ from TAUQ.
*
         CALL pzlarft( 'Forward', 'Columnwise', m, jb, a, ia, ja, desca,
     $                 tauq, work( iptq ), work( ipwk ) )
*
*        Copy Householder vectors into workspace.
*
         CALL pzlacpy( 'Lower', m, jb, a, ia, ja, desca, work( ipv ),
     $                 iv, jv, descv )
         CALL pzlaset( 'Upper', m, jb, zero, one, work( ipv ), iv, jv,
     $                 descv )
*
*        Zero out the strict lower triangular part of A.
*
         CALL pzlaset( 'Lower', m-1, jb, zero, zero, a, ia+1, ja,
     $                 desca )
*
*        Compute upper triangular matrix TP from TAUP.
*
         CALL pzlarft( 'Forward', 'Rowwise', n-1, jb, a, ia, ja+1,
     $                 desca, taup, work( iptp ), work( ipwk ) )
*
*        Copy Householder vectors into workspace.
*
         CALL pzlacpy( 'Upper', jb, n-1, a, ia, ja+1, desca,
     $                 work( ipw ), iv, jv+1, descw )
         CALL pzlaset( 'Lower', jb, n-1, zero, one, work( ipw ), iv,
     $                 jv+1, descw )
*
*        Zero out the strict+1 upper triangular part of A.
*
         CALL pzlaset( 'Upper', jb, n-2, zero, zero, a, ia, ja+2,
     $                 desca )
*
*        Apply block Householder transformation from left.
*
         CALL pzlarfb( 'Left', 'No transpose', 'Forward', 'Columnwise',
     $                 m, n, jb, work( ipv ), iv, jv, descv,
     $                 work( iptq ), a, ia, ja, desca, work( ipwk ) )
*
*        Apply block Householder transformation from right.
*
         CALL pzlarfb( 'Right', 'Conjugate transpose', 'Forward',
     $                 'Rowwise', m, n-1, jb, work( ipw ), iv, jv+1,
     $                 descw, work( iptp ), a, ia, ja+1, desca,
     $                 work( ipwk ) )
*
      ELSE
*
         CALL descset( descd, ia+mn-1, 1, desca( mb_ ), 1,
     $                 desca( rsrc_ ), mycol, desca( ctxt_ ),
     $                 desca( lld_ ) )
         CALL descset( desce, 1, ja+mn-2, 1, desca( nb_ ), myrow,
     $                 desca( csrc_ ), desca( ctxt_ ), 1 )
*
         DO 30 j = 0, mn-1
            d1 = zero
            e1 = zero
            d2 = rzero
            e2 = rzero
            CALL pdelget( ' ', ' ', d2, d, ia+j, 1, descd )
            CALL pzelget( 'Rowwise', ' ', d1, a, ia+j, ja+j, desca )
            IF( j.LT.(mn-1) ) THEN
               CALL pdelget( ' ', ' ', e2, e, 1, ja+j, desce )
               CALL pzelget( 'Columnwise', ' ', e1, a, ia+j+1, ja+j,
     $                       desca )
            END IF
*
            IF( ( abs( d1-dcmplx( d2 ) ).GT.( abs( d2 )*addbnd ) ) .OR.
     $          ( abs( e1-dcmplx( e2 ) ).GT.( abs( e2 )*addbnd ) ) )
     $         info = info + 1
   30    CONTINUE
*
         DO 40 i = il, ia+nb-ioff, -nb
            jb = min( ia+m-i, nb )
            j  = ja + i - ia
            k  = j - ja + 1
*
*           Compute upper triangular matrix TQ from TAUQ.
*
            CALL pzlarft( 'Forward', 'Columnwise', m-k, jb, a, i+1, j,
     $                    desca, tauq, work( iptq ), work( ipwk ) )
*
*           Copy Householder vectors into workspace.
*
            CALL pzlacpy( 'Lower', m-k, jb, a, i+1, j, desca,
     $                    work( ipv ), iv+1, jv, descv )
            CALL pzlaset( 'Upper', m-k, jb, zero, one, work( ipv ),
     $                    iv+1, jv, descv )
*
*           Zero out the strict lower triangular part of A.
*
            CALL pzlaset( 'Lower', m-k-1, jb, zero, zero, a, i+2, j,
     $                    desca )
*
*           Compute upper triangular matrix TP from TAUP.
*
            CALL pzlarft( 'Forward', 'Rowwise', n-k+1, jb, a, i, j,
     $                    desca, taup, work( iptp ), work( ipwk ) )
*
*           Copy Householder vectors into workspace.
*
            CALL pzlacpy( 'Upper', jb, n-k+1, a, i, j, desca,
     $                    work( ipw ), iv, jv, descw )
            CALL pzlaset( 'Lower', jb, n-k+1, zero, one, work( ipw ),
     $                    iv, jv, descw )
*
*           Zero out the strict+1 upper triangular part of A.
*
            CALL pzlaset( 'Upper', jb, n-k, zero, zero, a, i, j+1,
     $                    desca )
*
*           Apply block Householder transformation from Left.
*
            CALL pzlarfb( 'Left', 'No transpose', 'Forward',
     $                    'Columnwise', m-k, n-k+1, jb, work( ipv ),
     $                    iv+1, jv, descv, work( iptq ), a, i+1, j,
     $                    desca, work( ipwk ) )
*
*           Apply block Householder transformation from Right.
*
            CALL pzlarfb( 'Right', 'Conjugate transpose', 'Forward',
     $                    'Rowwise', m-k+1, n-k+1, jb, work( ipw ), iv,
     $                    jv, descw, work( iptp ), a, i, j, desca,
     $                    work( ipwk ) )
*
            descv( m_ ) = descv( m_ ) + nb
            descv( rsrc_ ) = mod( descv( rsrc_ ) + nprow - 1, nprow )
            descv( csrc_ ) = mod( descv( csrc_ ) + npcol - 1, npcol )
            descw( n_ ) = descw( n_ ) + nb
            descw( rsrc_ ) = descv( rsrc_ )
            descw( csrc_ ) = descv( csrc_ )
*
   40    CONTINUE
*
*        Handle first block separately
*
         jb = min( m, nb - ioff )
         iv = ioff + 1
         jv = ioff + 1
*
*        Compute upper triangular matrix TQ from TAUQ.
*
         CALL pzlarft( 'Forward', 'Columnwise', m-1, jb, a, ia+1, ja,
     $                 desca, tauq, work( iptq ), work( ipwk ) )
*
*        Copy Householder vectors into workspace.
*
         CALL pzlacpy( 'Lower', m-1, jb, a, ia+1, ja, desca,
     $                 work( ipv ), iv+1, jv, descv )
         CALL pzlaset( 'Upper', m-1, jb, zero, one, work( ipv ), iv+1,
     $                 jv, descv )
*
*        Zero out the strict lower triangular part of A.
*
         CALL pzlaset( 'Lower', m-2, jb, zero, zero, a, ia+2, ja,
     $                 desca )
*
*        Compute upper triangular matrix TP from TAUP.
*
         CALL pzlarft( 'Forward', 'Rowwise', n, jb, a, ia, ja, desca,
     $                 taup, work( iptp ), work( ipwk ) )
*
*        Copy Householder vectors into workspace.
*
         CALL pzlacpy( 'Upper', jb, n, a, ia, ja, desca, work( ipw ),
     $                 iv, jv, descw )
         CALL pzlaset( 'Lower', jb, n, zero, one, work( ipw ), iv, jv,
     $                 descw )
*
*        Zero out the strict+1 upper triangular part of A.
*
         CALL pzlaset( 'Upper', jb, n-1, zero, zero, a, ia, ja+1,
     $                 desca )
*
*        Apply block Householder transformation from left
*
         CALL pzlarfb( 'Left', 'No transpose', 'Forward', 'Columnwise',
     $                 m-1, n, jb, work( ipv ), iv+1, jv, descv,
     $                 work( iptq ), a, ia+1, ja, desca, work( ipwk ) )
*
*        Apply block Householder transformation from right
*
         CALL pzlarfb( 'Right', 'Conjugate transpose', 'Forward',
     $                 'Rowwise', m, n, jb, work( ipw ), iv, jv, descw,
     $                 work( iptp ), a, ia, ja, desca, work( ipwk ) )
      END IF
*
      CALL igsum2d( ictxt, 'All', ' ', 1, 1, info, 1, -1, 0 )
*
      RETURN
*
*     End of PZGEBDRV
*

Here is the call graph for this function:

Here is the caller graph for this function: