pddtlaschk()

subroutine pddtlaschk	(	character	symm,
		character	uplo,
		character	trans,
		integer	n,
		integer	bwl,
		integer	bwu,
		integer	nrhs,
		double precision, dimension( * )	x,
		integer	ix,
		integer	jx,
		integer, dimension( * )	descx,
		integer	iaseed,
		double precision, dimension( * )	a,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		integer	ibseed,
		double precision	anorm,
		double precision	resid,
		double precision, dimension( * )	work,
		integer	worksiz
	)

Definition at line 1 of file pddtlaschk.f.

*
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     November 15, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          SYMM, TRANS, UPLO
      INTEGER            BWL, BWU, IA, IASEED, IBSEED,
     $                   IX, JA, JX, N, NRHS, WORKSIZ
      DOUBLE PRECISION   ANORM, RESID
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCX( * )
      DOUBLE PRECISION   A( * ), WORK( * ), X( * )
*     .. External Functions ..
      LOGICAL            LSAME
*     ..
*
*  Purpose
*  =======
*
*  PDDTLASCHK computes the residual
*  || sub( A )*sub( X ) - B || / (|| sub( A ) ||*|| sub( X ) ||*eps*N)
*  to check the accuracy of the factorization and solve steps in the
*  LU and Cholesky decompositions, where sub( A ) denotes
*  A(IA:IA+N-1,JA,JA+N-1), sub( X ) denotes X(IX:IX+N-1, JX:JX+NRHS-1).
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  SYMM      (global input) CHARACTER
*          if SYMM = 'S', sub( A ) is a symmetric distributed band
*          matrix, otherwise sub( A ) is a general distributed matrix.
*
*  UPLO    (global input) CHARACTER
*          if SYMM = 'S', then
*            if UPLO = 'L', the lower half of the matrix is stored
*            if UPLO = 'U', the upper half of the matrix is stored
*          if SYMM != 'S' or 'H', then
*            if UPLO = 'D', the matrix is stable during factorization
*                           without interchanges
*            if UPLO != 'D', the matrix is general
*
*  TRANS   if TRANS= 'T', A 'Transpose' is used as the
*            coefficient matrix in the solve.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on, i.e. the number of
*          columns of the distributed submatrix sub( A ). N >= 0.
*
*  NRHS    (global input) INTEGER
*          The number of right-hand-sides, i.e the number of columns
*          of the distributed matrix sub( X ). NRHS >= 1.
*
*  X       (local input) DOUBLE PRECISION pointer into the local memory
*          to an array of dimension (LLD_X,LOCq(JX+NRHS-1). This array
*          contains the local pieces of the answer vector(s) sub( X ) of
*          sub( A ) sub( X ) - B, split up over a column of processes.
*
*  IX      (global input) INTEGER
*          The row index in the global array X indicating the first
*          row of sub( X ).
*
*  DESCX   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix X.
*
*  IASEED  (global input) INTEGER
*          The seed number to generate the original matrix Ao.
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  IBSEED  (global input) INTEGER
*          The seed number to generate the original matrix B.
*
*  ANORM   (global input) DOUBLE PRECISION
*          The 1-norm or infinity norm of the distributed matrix
*          sub( A ).
*
*  RESID   (global output) DOUBLE PRECISION
*          The residual error:
*          ||sub( A )*sub( X )-B|| / (||sub( A )||*||sub( X )||*eps*N).
*
*  WORK    (local workspace) DOUBLE PRECISION array, dimension (LWORK)
*          IF SYMM='S'
*          LWORK >= max(5,NB)+2*NB
*          IF SYMM!='S' or 'H'
*          LWORK >= max(5,NB)+2*NB
*
*  WORKSIZ (local input) size of WORK.
*
*  =====================================================================
*
*  Code Developer: Andrew J. Cleary, University of Tennessee.
*    Current address: Lawrence Livermore National Labs.
*  This version released: August, 2001.
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( one = 1.0d+0, zero = 0.0d+0 )
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      INTEGER            INT_ONE
      parameter( int_one = 1 )
*     ..
*     .. Local Scalars ..
      INTEGER            IACOL, IAROW, ICTXT,
     $                   IIA, IIX, IPB, IPW,
     $                   IXCOL, IXROW, J, JJA, JJX, LDA,
     $                   MYCOL, MYROW, NB, NP, NPCOL, NPROW, NQ
      INTEGER            I, START
      INTEGER            BW, INFO, IPPRODUCT, WORK_MIN
      DOUBLE PRECISION   DIVISOR, EPS, RESID1, NORMX
*     ..
*     .. Local Arrays ..
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, dgamx2d, dgebr2d,
     $                   dgebs2d, dgemm, dgerv2d, dgesd2d,
     $                   dgsum2d, dlaset, pbdtran, pdmatgen
*     ..
*     .. External Functions ..
      INTEGER            IDAMAX, NUMROC
      DOUBLE PRECISION   PDLAMCH
      EXTERNAL           idamax, numroc, pdlamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, max, min, mod
*     ..
*     .. Executable Statements ..
*
*     Get needed initial parameters
*
      ictxt = desca( ctxt_ )
      nb = desca( nb_ )
*
      IF( lsame( symm, 'S' ) ) THEN
         bw = bwl
         start = 1
         work_min = max(5,nb)+2*nb
      ELSE
         bw = max(bwl, bwu)
         IF( lsame( uplo, 'D' )) THEN
            start = 1
         ELSE
            start = 2
         ENDIF
         work_min = max(5,nb)+2*nb
      ENDIF
*
      IF ( worksiz .LT. work_min ) THEN
       CALL pxerbla( ictxt, 'PDTLASCHK', -18 )
       RETURN
      END IF
*
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      eps = pdlamch( ictxt, 'eps' )
      resid = 0.0d+0
      divisor = anorm * eps * dble( n )
*
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, iia, jja,
     $              iarow, iacol )
      CALL infog2l( ix, jx, descx, nprow, npcol, myrow, mycol, iix, jjx,
     $              ixrow, ixcol )
      np = numroc( (3), desca( mb_ ), myrow, 0, nprow )
      nq = numroc( n, desca( nb_ ), mycol, 0, npcol )
*
      ipb = 1
      ipproduct = 1 + desca( nb_ )
      ipw = 1 + 2*desca( nb_ )
*
      lda = desca( lld_ )
*
*     Regenerate A
*
               IF( lsame( symm, 'S' )) THEN
                 CALL pdbmatgen( ictxt, uplo, 'D', bw, bw, n, bw+1,
     $                           desca( nb_ ), a, desca( lld_ ), 0, 0,
     $                           iaseed, myrow, mycol, nprow, npcol )
               ELSE
*
                 CALL pdbmatgen( ictxt, 'N', uplo, bwl, bwu, n,
     $                           desca( mb_ ), desca( nb_ ), a,
     $                           desca( lld_ ), 0, 0, iaseed, myrow,
     $                           mycol, nprow, npcol )
               ENDIF
*
*           Matrix formed above has the diagonals shifted from what was
*              input to the tridiagonal routine. Shift them back.
*
*              Send elements to neighboring processors
*
               IF( mycol.GT.0 ) THEN
                  CALL dgesd2d( ictxt, 1, 1, a( start+2), lda,
     $                     myrow, mycol-1 )
               ENDIF
*
               IF( mycol.LT.npcol-1 ) THEN
                  CALL dgesd2d( ictxt, 1, 1,
     $                     a( start+( desca( nb_ )-1 )*lda ),
     $                     lda, myrow, mycol+1 )
               ENDIF
*
*              Shift local elements
*
               DO 220 i=0,desca( nb_ )-1
                  a( start+2+(i)*lda ) = a( start+2+(i+1)*lda )
  220          CONTINUE
*
               DO 230 i=desca( nb_ )-1,0,-1
                  a( start+(i+1)*lda ) = a( start+(i)*lda )
  230          CONTINUE
*
*              Receive elements from neighboring processors
*
               IF( mycol.LT.npcol-1 ) THEN
                  CALL dgerv2d( ictxt, 1, 1,
     $                     a( start+2+( desca( nb_ )-1 )*lda ),
     $                     lda, myrow, mycol+1 )
               ENDIF
*
               IF( mycol.GT.0 ) THEN
                  CALL dgerv2d( ictxt, 1, 1, a( start), lda,
     $                               myrow, mycol-1 )
               ENDIF
*
*     Loop over the rhs
*
      resid = 0.0
*
      DO 40 j = 1, nrhs
*
*           Multiply A * current column of X
*
*
            CALL pdgbdcmv( bwl+bwu+1, bwl, bwu, trans, n, a, 1, desca,
     $                     1, x( 1 + (j-1)*descx( lld_ )), 1, descx,
     $                     work( ipproduct ), work( ipw ),
     $                     (int_one+2)*int_one, info )
*
*
*           Regenerate column of B
*
            CALL pdmatgen( descx( ctxt_ ), 'No', 'No', descx( m_ ),
     $                     descx( n_ ), descx( mb_ ), descx( nb_ ),
     $                     work( ipb ), descx( lld_ ), descx( rsrc_ ),
     $                     descx( csrc_ ), ibseed, 0, nq, j-1, 1, mycol,
     $                     myrow, npcol, nprow )
*
*           Figure || A * X - B || & || X ||
*
            CALL pdaxpy( n, -one, work( ipproduct ), 1, 1, descx, 1,
     $                   work( ipb ), 1, 1, descx, 1 )
*
            CALL pdnrm2( n, normx,
     $           x, 1, j, descx, 1 )
*
            CALL pdnrm2( n, resid1,
     $           work( ipb ), 1, 1, descx, 1 )
*
*
*           Calculate residual = ||Ax-b|| / (||x||*||A||*eps*N)
*
            resid1 = resid1 / ( normx*divisor )
*
            resid = max( resid, resid1 )
*
   40 CONTINUE
*
      RETURN
*
*     End of PDTLASCHK
*

Here is the call graph for this function:

Here is the caller graph for this function: