cchksy_rook()

subroutine cchksy_rook	(	logical, dimension( * )	dotype,
		integer	nn,
		integer, dimension( * )	nval,
		integer	nnb,
		integer, dimension( * )	nbval,
		integer	nns,
		integer, dimension( * )	nsval,
		real	thresh,
		logical	tsterr,
		integer	nmax,
		complex, dimension( * )	a,
		complex, dimension( * )	afac,
		complex, dimension( * )	ainv,
		complex, dimension( * )	b,
		complex, dimension( * )	x,
		complex, dimension( * )	xact,
		complex, dimension( * )	work,
		real, dimension( * )	rwork,
		integer, dimension( * )	iwork,
		integer	nout )

CCHKSY_ROOK

Purpose:

!>
!> CCHKSY_ROOK tests CSYTRF_ROOK, -TRI_ROOK, -TRS_ROOK,
!> and -CON_ROOK.
!> 

Parameters

[in]	DOTYPE	!> DOTYPE is LOGICAL array, dimension (NTYPES) !> The matrix types to be used for testing. Matrices of type j !> (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) = !> .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used. !>
[in]	NN	!> NN is INTEGER !> The number of values of N contained in the vector NVAL. !>
[in]	NVAL	!> NVAL is INTEGER array, dimension (NN) !> The values of the matrix dimension N. !>
[in]	NNB	!> NNB is INTEGER !> The number of values of NB contained in the vector NBVAL. !>
[in]	NBVAL	!> NBVAL is INTEGER array, dimension (NNB) !> The values of the blocksize NB. !>
[in]	NNS	!> NNS is INTEGER !> The number of values of NRHS contained in the vector NSVAL. !>
[in]	NSVAL	!> NSVAL is INTEGER array, dimension (NNS) !> The values of the number of right hand sides NRHS. !>
[in]	THRESH	!> THRESH is REAL !> The threshold value for the test ratios. A result is !> included in the output file if RESULT >= THRESH. To have !> every test ratio printed, use THRESH = 0. !>
[in]	TSTERR	!> TSTERR is LOGICAL !> Flag that indicates whether error exits are to be tested. !>
[in]	NMAX	!> NMAX is INTEGER !> The maximum value permitted for N, used in dimensioning the !> work arrays. !>
[out]	A	!> A is COMPLEX array, dimension (NMAX*NMAX) !>
[out]	AFAC	!> AFAC is COMPLEX array, dimension (NMAX*NMAX) !>
[out]	AINV	!> AINV is COMPLEX array, dimension (NMAX*NMAX) !>
[out]	B	!> B is COMPLEX array, dimension (NMAX*NSMAX) !> where NSMAX is the largest entry in NSVAL. !>
[out]	X	!> X is COMPLEX array, dimension (NMAX*NSMAX) !>
[out]	XACT	!> XACT is COMPLEX array, dimension (NMAX*NSMAX) !>
[out]	WORK	!> WORK is COMPLEX array, dimension (NMAX*max(3,NSMAX)) !>
[out]	RWORK	!> RWORK is REAL array, dimension (max(NMAX,2*NSMAX)) !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (2*NMAX) !>
[in]	NOUT	!> NOUT is INTEGER !> The unit number for output. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 169 of file cchksy_rook.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NMAX, NN, NNB, NNS, NOUT
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            IWORK( * ), NBVAL( * ), NSVAL( * ), NVAL( * )
      REAL               RWORK( * )
      COMPLEX            A( * ), AFAC( * ), AINV( * ), B( * ),
     $                   WORK( * ), X( * ), XACT( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      REAL               ONEHALF
      parameter( onehalf = 0.5e+0 )
      REAL               EIGHT, SEVTEN
      parameter( eight = 8.0e+0, sevten = 17.0e+0 )
      COMPLEX            CZERO
      parameter( czero = ( 0.0e+0, 0.0e+0 ) )
      INTEGER            NTYPES
      parameter( ntypes = 11 )
      INTEGER            NTESTS
      parameter( ntests = 7 )
*     ..
*     .. Local Scalars ..
      LOGICAL            TRFCON, ZEROT
      CHARACTER          DIST, TYPE, UPLO, XTYPE
      CHARACTER*3        PATH, MATPATH
      INTEGER            I, I1, I2, IMAT, IN, INB, INFO, IOFF, IRHS,
     $                   IUPLO, IZERO, J, K, KL, KU, LDA, LWORK, MODE,
     $                   N, NB, NERRS, NFAIL, NIMAT, NRHS, NRUN, NT
      REAL               ALPHA, ANORM, CNDNUM, CONST, SING_MAX,
     $                   SING_MIN, RCOND, RCONDC, STEMP
*     ..
*     .. Local Arrays ..
      CHARACTER          UPLOS( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      REAL               RESULT( NTESTS )
      COMPLEX            BLOCK( 2, 2 ), CDUMMY( 1 )
*     ..
*     .. External Functions ..
      REAL               CLANGE, CLANSY, SGET06
      EXTERNAL           clange, clansy, sget06
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, cerrsy, cgesvd, cget04,
     $                   clacpy, clarhs, clatb4, clatms, clatsy, csyt02,
     $                   csyt03, csycon_rook, csyt01_rook, csytrf_rook,
     $                   csytri_rook, csytrs_rook, xlaenv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, sqrt
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      alpha = ( one+sqrt( sevten ) ) / eight
*
*     Test path
*
      path( 1: 1 ) = 'Complex precision'
      path( 2: 3 ) = 'SR'
*
*     Path to generate matrices
*
      matpath( 1: 1 ) = 'Complex precision'
      matpath( 2: 3 ) = 'SY'
*
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL cerrsy( path, nout )
      infot = 0
*
*     Set the minimum block size for which the block routine should
*     be used, which will be later returned by ILAENV
*
      CALL xlaenv( 2, 2 )
*
*     Do for each value of N in NVAL
*
      DO 270 in = 1, nn
         n = nval( in )
         lda = max( n, 1 )
         xtype = 'N'
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         izero = 0
*
*        Do for each value of matrix type IMAT
*
         DO 260 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 260
*
*           Skip types 3, 4, 5, or 6 if the matrix size is too small.
*
            zerot = imat.GE.3 .AND. imat.LE.6
            IF( zerot .AND. n.LT.imat-2 )
     $         GO TO 260
*
*           Do first for UPLO = 'U', then for UPLO = 'L'
*
            DO 250 iuplo = 1, 2
               uplo = uplos( iuplo )
*
*              Begin generate test matrix A.
*
               IF( imat.NE.ntypes ) THEN
*
*                 Set up parameters with CLATB4 for the matrix generator
*                 based on the type of matrix to be generated.
*
                  CALL clatb4( matpath, imat, n, n, TYPE, KL, KU, ANORM,
     $                         MODE, CNDNUM, DIST )
*
*                 Generate a matrix with CLATMS.
*
                  srnamt = 'CLATMS'
                  CALL clatms( n, n, dist, iseed, TYPE, RWORK, MODE,
     $                         CNDNUM, ANORM, KL, KU, UPLO, A, LDA,
     $                         WORK, INFO )
*
*                 Check error code from CLATMS and handle error.
*
                  IF( info.NE.0 ) THEN
                     CALL alaerh( path, 'CLATMS', info, 0, uplo, n, n,
     $                            -1, -1, -1, imat, nfail, nerrs, nout )
*
*                    Skip all tests for this generated matrix
*
                     GO TO 250
                  END IF
*
*                 For matrix types 3-6, zero one or more rows and
*                 columns of the matrix to test that INFO is returned
*                 correctly.
*
                  IF( zerot ) THEN
                     IF( imat.EQ.3 ) THEN
                        izero = 1
                     ELSE IF( imat.EQ.4 ) THEN
                        izero = n
                     ELSE
                        izero = n / 2 + 1
                     END IF
*
                     IF( imat.LT.6 ) THEN
*
*                       Set row and column IZERO to zero.
*
                        IF( iuplo.EQ.1 ) THEN
                           ioff = ( izero-1 )*lda
                           DO 20 i = 1, izero - 1
                              a( ioff+i ) = czero
   20                      CONTINUE
                           ioff = ioff + izero
                           DO 30 i = izero, n
                              a( ioff ) = czero
                              ioff = ioff + lda
   30                      CONTINUE
                        ELSE
                           ioff = izero
                           DO 40 i = 1, izero - 1
                              a( ioff ) = czero
                              ioff = ioff + lda
   40                      CONTINUE
                           ioff = ioff - izero
                           DO 50 i = izero, n
                              a( ioff+i ) = czero
   50                      CONTINUE
                        END IF
                     ELSE
                        IF( iuplo.EQ.1 ) THEN
*
*                          Set the first IZERO rows and columns to zero.
*
                           ioff = 0
                           DO 70 j = 1, n
                              i2 = min( j, izero )
                              DO 60 i = 1, i2
                                 a( ioff+i ) = czero
   60                         CONTINUE
                              ioff = ioff + lda
   70                      CONTINUE
                        ELSE
*
*                          Set the last IZERO rows and columns to zero.
*
                           ioff = 0
                           DO 90 j = 1, n
                              i1 = max( j, izero )
                              DO 80 i = i1, n
                                 a( ioff+i ) = czero
   80                         CONTINUE
                              ioff = ioff + lda
   90                      CONTINUE
                        END IF
                     END IF
                  ELSE
                     izero = 0
                  END IF
*
               ELSE
*
*                 For matrix kind IMAT = 11, generate special block
*                 diagonal matrix to test alternate code
*                 for the 2 x 2 blocks.
*
                  CALL clatsy( uplo, n, a, lda, iseed )
*
               END IF
*
*              End generate test matrix A.
*
*
*              Do for each value of NB in NBVAL
*
               DO 240 inb = 1, nnb
*
*                 Set the optimal blocksize, which will be later
*                 returned by ILAENV.
*
                  nb = nbval( inb )
                  CALL xlaenv( 1, nb )
*
*                 Copy the test matrix A into matrix AFAC which
*                 will be factorized in place. This is needed to
*                 preserve the test matrix A for subsequent tests.
*
                  CALL clacpy( uplo, n, n, a, lda, afac, lda )
*
*                 Compute the L*D*L**T or U*D*U**T factorization of the
*                 matrix. IWORK stores details of the interchanges and
*                 the block structure of D. AINV is a work array for
*                 block factorization, LWORK is the length of AINV.
*
                  lwork = max( 2, nb )*lda
                  srnamt = 'CSYTRF_ROOK'
                  CALL csytrf_rook( uplo, n, afac, lda, iwork, ainv,
     $                              lwork, info )
*
*                 Adjust the expected value of INFO to account for
*                 pivoting.
*
                  k = izero
                  IF( k.GT.0 ) THEN
  100                CONTINUE
                     IF( iwork( k ).LT.0 ) THEN
                        IF( iwork( k ).NE.-k ) THEN
                           k = -iwork( k )
                           GO TO 100
                        END IF
                     ELSE IF( iwork( k ).NE.k ) THEN
                        k = iwork( k )
                        GO TO 100
                     END IF
                  END IF
*
*                 Check error code from CSYTRF_ROOK and handle error.
*
                  IF( info.NE.k)
     $               CALL alaerh( path, 'CSYTRF_ROOK', info, k,
     $                            uplo, n, n, -1, -1, nb, imat,
     $                            nfail, nerrs, nout )
*
*                 Set the condition estimate flag if the INFO is not 0.
*
                  IF( info.NE.0 ) THEN
                     trfcon = .true.
                  ELSE
                     trfcon = .false.
                  END IF
*
*+    TEST 1
*                 Reconstruct matrix from factors and compute residual.
*
                  CALL csyt01_rook( uplo, n, a, lda, afac, lda, iwork,
     $                              ainv, lda, rwork, result( 1 ) )
                  nt = 1
*
*+    TEST 2
*                 Form the inverse and compute the residual,
*                 if the factorization was competed without INFO > 0
*                 (i.e. there is no zero rows and columns).
*                 Do it only for the first block size.
*
                  IF( inb.EQ.1 .AND. .NOT.trfcon ) THEN
                     CALL clacpy( uplo, n, n, afac, lda, ainv, lda )
                     srnamt = 'CSYTRI_ROOK'
                     CALL csytri_rook( uplo, n, ainv, lda, iwork, work,
     $                                 info )
*
*                    Check error code from CSYTRI_ROOK and handle error.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'CSYTRI_ROOK', info, -1,
     $                               uplo, n, n, -1, -1, -1, imat,
     $                               nfail, nerrs, nout )
*
*                    Compute the residual for a symmetric matrix times
*                    its inverse.
*
                     CALL csyt03( uplo, n, a, lda, ainv, lda, work, lda,
     $                            rwork, rcondc, result( 2 ) )
                     nt = 2
                  END IF
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  DO 110 k = 1, nt
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9999 )uplo, n, nb, imat, k,
     $                     result( k )
                        nfail = nfail + 1
                     END IF
  110             CONTINUE
                  nrun = nrun + nt
*
*+    TEST 3
*                 Compute largest element in U or L
*
                  result( 3 ) = zero
                  stemp = zero
*
                  const = ( ( alpha**2-one ) / ( alpha**2-onehalf ) ) /
     $                    ( one-alpha )
*
                  IF( iuplo.EQ.1 ) THEN
*
*                 Compute largest element in U
*
                     k = n
  120                CONTINUE
                     IF( k.LE.1 )
     $                  GO TO 130
*
                     IF( iwork( k ).GT.zero ) THEN
*
*                       Get max absolute value from elements
*                       in column k in in U
*
                        stemp = clange( 'M', k-1, 1,
     $                          afac( ( k-1 )*lda+1 ), lda, rwork )
                     ELSE
*
*                       Get max absolute value from elements
*                       in columns k and k-1 in U
*
                        stemp = clange( 'M', k-2, 2,
     $                          afac( ( k-2 )*lda+1 ), lda, rwork )
                        k = k - 1
*
                     END IF
*
*                    STEMP should be bounded by CONST
*
                     stemp = stemp - const + thresh
                     IF( stemp.GT.result( 3 ) )
     $                  result( 3 ) = stemp
*
                     k = k - 1
*
                     GO TO 120
  130                CONTINUE
*
                  ELSE
*
*                 Compute largest element in L
*
                     k = 1
  140                CONTINUE
                     IF( k.GE.n )
     $                  GO TO 150
*
                     IF( iwork( k ).GT.zero ) THEN
*
*                       Get max absolute value from elements
*                       in column k in in L
*
                        stemp = clange( 'M', n-k, 1,
     $                          afac( ( k-1 )*lda+k+1 ), lda, rwork )
                     ELSE
*
*                       Get max absolute value from elements
*                       in columns k and k+1 in L
*
                        stemp = clange( 'M', n-k-1, 2,
     $                          afac( ( k-1 )*lda+k+2 ), lda, rwork )
                        k = k + 1
*
                     END IF
*
*                    STEMP should be bounded by CONST
*
                     stemp = stemp - const + thresh
                     IF( stemp.GT.result( 3 ) )
     $                  result( 3 ) = stemp
*
                     k = k + 1
*
                     GO TO 140
  150                CONTINUE
                  END IF
*
*
*+    TEST 4
*                 Compute largest 2-Norm (condition number)
*                 of 2-by-2 diag blocks
*
                  result( 4 ) = zero
                  stemp = zero
*
                  const = ( ( alpha**2-one ) / ( alpha**2-onehalf ) )*
     $                    ( ( one + alpha ) / ( one - alpha ) )
*
                  IF( iuplo.EQ.1 ) THEN
*
*                    Loop backward for UPLO = 'U'
*
                     k = n
  160                CONTINUE
                     IF( k.LE.1 )
     $                  GO TO 170
*
                     IF( iwork( k ).LT.zero ) THEN
*
*                       Get the two singular values
*                       (real and non-negative) of a 2-by-2 block,
*                       store them in RWORK array
*
                        block( 1, 1 ) = afac( ( k-2 )*lda+k-1 )
                        block( 1, 2 ) = afac( (k-1)*lda+k-1 )
                        block( 2, 1 ) = block( 1, 2 )
                        block( 2, 2 ) = afac( (k-1)*lda+k )
*
                        CALL cgesvd( 'N', 'N', 2, 2, block, 2, rwork,
     $                               cdummy, 1, cdummy, 1,
     $                               work, 6, rwork( 3 ), info )
*
*
                        sing_max = rwork( 1 )
                        sing_min = rwork( 2 )
*
                        stemp = sing_max / sing_min
*
*                       STEMP should be bounded by CONST
*
                        stemp = stemp - const + thresh
                        IF( stemp.GT.result( 4 ) )
     $                     result( 4 ) = stemp
                        k = k - 1
*
                     END IF
*
                     k = k - 1
*
                     GO TO 160
  170                CONTINUE
*
                  ELSE
*
*                    Loop forward for UPLO = 'L'
*
                     k = 1
  180                CONTINUE
                     IF( k.GE.n )
     $                  GO TO 190
*
                     IF( iwork( k ).LT.zero ) THEN
*
*                       Get the two singular values
*                       (real and non-negative) of a 2-by-2 block,
*                       store them in RWORK array
*
                        block( 1, 1 ) = afac( ( k-1 )*lda+k )
                        block( 2, 1 ) = afac( ( k-1 )*lda+k+1 )
                        block( 1, 2 ) = block( 2, 1 )
                        block( 2, 2 ) = afac( k*lda+k+1 )
*
                        CALL cgesvd( 'N', 'N', 2, 2, block, 2, rwork,
     $                               cdummy, 1, cdummy, 1,
     $                               work, 6, rwork(3), info )
*
                        sing_max = rwork( 1 )
                        sing_min = rwork( 2 )
*
                        stemp = sing_max / sing_min
*
*                       STEMP should be bounded by CONST
*
                        stemp = stemp - const + thresh
                        IF( stemp.GT.result( 4 ) )
     $                     result( 4 ) = stemp
                        k = k + 1
*
                     END IF
*
                     k = k + 1
*
                     GO TO 180
  190                CONTINUE
                  END IF
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  DO 200 k = 3, 4
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9999 )uplo, n, nb, imat, k,
     $                     result( k )
                        nfail = nfail + 1
                     END IF
  200             CONTINUE
                  nrun = nrun + 2
*
*                 Skip the other tests if this is not the first block
*                 size.
*
                  IF( inb.GT.1 )
     $               GO TO 240
*
*                 Do only the condition estimate if INFO is not 0.
*
                  IF( trfcon ) THEN
                     rcondc = zero
                     GO TO 230
                  END IF
*
*                 Do for each value of NRHS in NSVAL.
*
                  DO 220 irhs = 1, nns
                     nrhs = nsval( irhs )
*
*+    TEST 5 ( Using TRS_ROOK)
*                 Solve and compute residual for  A * X = B.
*
*                    Choose a set of NRHS random solution vectors
*                    stored in XACT and set up the right hand side B
*
                     srnamt = 'CLARHS'
                     CALL clarhs( matpath, xtype, uplo, ' ', n, n,
     $                            kl, ku, nrhs, a, lda, xact, lda,
     $                            b, lda, iseed, info )
                     CALL clacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                     srnamt = 'CSYTRS_ROOK'
                     CALL csytrs_rook( uplo, n, nrhs, afac, lda, iwork,
     $                                 x, lda, info )
*
*                    Check error code from CSYTRS_ROOK and handle error.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'CSYTRS_ROOK', info, 0,
     $                               uplo, n, n, -1, -1, nrhs, imat,
     $                               nfail, nerrs, nout )
*
                     CALL clacpy( 'Full', n, nrhs, b, lda, work, lda )
*
*                    Compute the residual for the solution
*
                     CALL csyt02( uplo, n, nrhs, a, lda, x, lda, work,
     $                            lda, rwork, result( 5 ) )
*
*+    TEST 6
*                 Check solution from generated exact solution.
*
                     CALL cget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                            result( 6 ) )
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     DO 210 k = 5, 6
                        IF( result( k ).GE.thresh ) THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL alahd( nout, path )
                           WRITE( nout, fmt = 9998 )uplo, n, nrhs,
     $                        imat, k, result( k )
                           nfail = nfail + 1
                        END IF
  210                CONTINUE
                     nrun = nrun + 2
*
*                 End do for each value of NRHS in NSVAL.
*
  220             CONTINUE
*
*+    TEST 7
*                 Get an estimate of RCOND = 1/CNDNUM.
*
  230             CONTINUE
                  anorm = clansy( '1', uplo, n, a, lda, rwork )
                  srnamt = 'CSYCON_ROOK'
                  CALL csycon_rook( uplo, n, afac, lda, iwork, anorm,
     $                              rcond, work, info )
*
*                 Check error code from CSYCON_ROOK and handle error.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'CSYCON_ROOK', info, 0,
     $                             uplo, n, n, -1, -1, -1, imat,
     $                             nfail, nerrs, nout )
*
*                 Compute the test ratio to compare values of RCOND
*
                  result( 7 ) = sget06( rcond, rcondc )
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  IF( result( 7 ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9997 )uplo, n, imat, 7,
     $                  result( 7 )
                     nfail = nfail + 1
                  END IF
                  nrun = nrun + 1
  240          CONTINUE
*
  250       CONTINUE
  260    CONTINUE
  270 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', NB =', i4, ', type ',
     $      i2, ', test ', i2, ', ratio =', g12.5 )
 9998 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', NRHS=', i3, ', type ',
     $      i2, ', test(', i2, ') =', g12.5 )
 9997 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ',', 10x, ' type ', i2,
     $      ', test(', i2, ') =', g12.5 )
      RETURN
*
*     End of CCHKSY_ROOK
*

Here is the call graph for this function:

Here is the caller graph for this function: