LAPACK  3.10.1
LAPACK: Linear Algebra PACKage
clansy.f
Go to the documentation of this file.
1 *> \brief \b CLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex symmetric matrix.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download CLANSY + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/clansy.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/clansy.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/clansy.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * REAL FUNCTION CLANSY( NORM, UPLO, N, A, LDA, WORK )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER NORM, UPLO
25 * INTEGER LDA, N
26 * ..
27 * .. Array Arguments ..
28 * REAL WORK( * )
29 * COMPLEX A( LDA, * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> CLANSY returns the value of the one norm, or the Frobenius norm, or
39 *> the infinity norm, or the element of largest absolute value of a
40 *> complex symmetric matrix A.
41 *> \endverbatim
42 *>
43 *> \return CLANSY
44 *> \verbatim
45 *>
46 *> CLANSY = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47 *> (
48 *> ( norm1(A), NORM = '1', 'O' or 'o'
49 *> (
50 *> ( normI(A), NORM = 'I' or 'i'
51 *> (
52 *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53 *>
54 *> where norm1 denotes the one norm of a matrix (maximum column sum),
55 *> normI denotes the infinity norm of a matrix (maximum row sum) and
56 *> normF denotes the Frobenius norm of a matrix (square root of sum of
57 *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58 *> \endverbatim
59 *
60 * Arguments:
61 * ==========
62 *
63 *> \param[in] NORM
64 *> \verbatim
65 *> NORM is CHARACTER*1
66 *> Specifies the value to be returned in CLANSY as described
67 *> above.
68 *> \endverbatim
69 *>
70 *> \param[in] UPLO
71 *> \verbatim
72 *> UPLO is CHARACTER*1
73 *> Specifies whether the upper or lower triangular part of the
74 *> symmetric matrix A is to be referenced.
75 *> = 'U': Upper triangular part of A is referenced
76 *> = 'L': Lower triangular part of A is referenced
77 *> \endverbatim
78 *>
79 *> \param[in] N
80 *> \verbatim
81 *> N is INTEGER
82 *> The order of the matrix A. N >= 0. When N = 0, CLANSY is
83 *> set to zero.
84 *> \endverbatim
85 *>
86 *> \param[in] A
87 *> \verbatim
88 *> A is COMPLEX array, dimension (LDA,N)
89 *> The symmetric matrix A. If UPLO = 'U', the leading n by n
90 *> upper triangular part of A contains the upper triangular part
91 *> of the matrix A, and the strictly lower triangular part of A
92 *> is not referenced. If UPLO = 'L', the leading n by n lower
93 *> triangular part of A contains the lower triangular part of
94 *> the matrix A, and the strictly upper triangular part of A is
95 *> not referenced.
96 *> \endverbatim
97 *>
98 *> \param[in] LDA
99 *> \verbatim
100 *> LDA is INTEGER
101 *> The leading dimension of the array A. LDA >= max(N,1).
102 *> \endverbatim
103 *>
104 *> \param[out] WORK
105 *> \verbatim
106 *> WORK is REAL array, dimension (MAX(1,LWORK)),
107 *> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
108 *> WORK is not referenced.
109 *> \endverbatim
110 *
111 * Authors:
112 * ========
113 *
114 *> \author Univ. of Tennessee
115 *> \author Univ. of California Berkeley
116 *> \author Univ. of Colorado Denver
117 *> \author NAG Ltd.
118 *
119 *> \ingroup complexSYauxiliary
120 *
121 * =====================================================================
122  REAL function clansy( norm, uplo, n, a, lda, work )
123 *
124 * -- LAPACK auxiliary routine --
125 * -- LAPACK is a software package provided by Univ. of Tennessee, --
126 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
127 *
128 * .. Scalar Arguments ..
129  CHARACTER norm, uplo
130  INTEGER lda, n
131 * ..
132 * .. Array Arguments ..
133  REAL work( * )
134  COMPLEX a( lda, * )
135 * ..
136 *
137 * =====================================================================
138 *
139 * .. Parameters ..
140  REAL one, zero
141  parameter( one = 1.0e+0, zero = 0.0e+0 )
142 * ..
143 * .. Local Scalars ..
144  INTEGER i, j
145  REAL absa, scale, sum, value
146 * ..
147 * .. External Functions ..
148  LOGICAL lsame, sisnan
149  EXTERNAL lsame, sisnan
150 * ..
151 * .. External Subroutines ..
152  EXTERNAL classq
153 * ..
154 * .. Intrinsic Functions ..
155  INTRINSIC abs, sqrt
156 * ..
157 * .. Executable Statements ..
158 *
159  IF( n.EQ.0 ) THEN
160  VALUE = zero
161  ELSE IF( lsame( norm, 'M' ) ) THEN
162 *
163 * Find max(abs(A(i,j))).
164 *
165  VALUE = zero
166  IF( lsame( uplo, 'U' ) ) THEN
167  DO 20 j = 1, n
168  DO 10 i = 1, j
169  sum = abs( a( i, j ) )
170  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
171  10 CONTINUE
172  20 CONTINUE
173  ELSE
174  DO 40 j = 1, n
175  DO 30 i = j, n
176  sum = abs( a( i, j ) )
177  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
178  30 CONTINUE
179  40 CONTINUE
180  END IF
181  ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
182  $ ( norm.EQ.'1' ) ) THEN
183 *
184 * Find normI(A) ( = norm1(A), since A is symmetric).
185 *
186  VALUE = zero
187  IF( lsame( uplo, 'U' ) ) THEN
188  DO 60 j = 1, n
189  sum = zero
190  DO 50 i = 1, j - 1
191  absa = abs( a( i, j ) )
192  sum = sum + absa
193  work( i ) = work( i ) + absa
194  50 CONTINUE
195  work( j ) = sum + abs( a( j, j ) )
196  60 CONTINUE
197  DO 70 i = 1, n
198  sum = work( i )
199  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
200  70 CONTINUE
201  ELSE
202  DO 80 i = 1, n
203  work( i ) = zero
204  80 CONTINUE
205  DO 100 j = 1, n
206  sum = work( j ) + abs( a( j, j ) )
207  DO 90 i = j + 1, n
208  absa = abs( a( i, j ) )
209  sum = sum + absa
210  work( i ) = work( i ) + absa
211  90 CONTINUE
212  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
213  100 CONTINUE
214  END IF
215  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
216 *
217 * Find normF(A).
218 *
219  scale = zero
220  sum = one
221  IF( lsame( uplo, 'U' ) ) THEN
222  DO 110 j = 2, n
223  CALL classq( j-1, a( 1, j ), 1, scale, sum )
224  110 CONTINUE
225  ELSE
226  DO 120 j = 1, n - 1
227  CALL classq( n-j, a( j+1, j ), 1, scale, sum )
228  120 CONTINUE
229  END IF
230  sum = 2*sum
231  CALL classq( n, a, lda+1, scale, sum )
232  VALUE = scale*sqrt( sum )
233  END IF
234 *
235  clansy = VALUE
236  RETURN
237 *
238 * End of CLANSY
239 *
240  END
subroutine classq(n, x, incx, scl, sumsq)
CLASSQ updates a sum of squares represented in scaled form.
Definition: classq.f90:137
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:59
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
real function clansy(NORM, UPLO, N, A, LDA, WORK)
CLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: clansy.f:123