srqt01()

subroutine srqt01	(	integer	m,
		integer	n,
		real, dimension( lda, * )	a,
		real, dimension( lda, * )	af,
		real, dimension( lda, * )	q,
		real, dimension( lda, * )	r,
		integer	lda,
		real, dimension( * )	tau,
		real, dimension( lwork )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		real, dimension( * )	result )

SRQT01

Purpose:

!>
!> SRQT01 tests SGERQF, which computes the RQ factorization of an m-by-n
!> matrix A, and partially tests SORGRQ which forms the n-by-n
!> orthogonal matrix Q.
!>
!> SRQT01 compares R with A*Q', and checks that Q is orthogonal.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in]	A	!> A is REAL array, dimension (LDA,N) !> The m-by-n matrix A. !>
[out]	AF	!> AF is REAL array, dimension (LDA,N) !> Details of the RQ factorization of A, as returned by SGERQF. !> See SGERQF for further details. !>
[out]	Q	!> Q is REAL array, dimension (LDA,N) !> The n-by-n orthogonal matrix Q. !>
[out]	R	!> R is REAL array, dimension (LDA,max(M,N)) !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the arrays A, AF, Q and L. !> LDA >= max(M,N). !>
[out]	TAU	!> TAU is REAL array, dimension (min(M,N)) !> The scalar factors of the elementary reflectors, as returned !> by SGERQF. !>
[out]	WORK	!> WORK is REAL array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. !>
[out]	RWORK	!> RWORK is REAL array, dimension (max(M,N)) !>
[out]	RESULT	!> RESULT is REAL array, dimension (2) !> The test ratios: !> RESULT(1) = norm( R - A*Q' ) / ( N * norm(A) * EPS ) !> RESULT(2) = norm( I - Q*Q' ) / ( N * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 124 of file srqt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
     $                   R( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
     $                   WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      REAL               ROGUE
      parameter( rogue = -1.0e+10 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO, MINMN
      REAL               ANORM, EPS, RESID
*     ..
*     .. External Functions ..
      REAL               SLAMCH, SLANGE, SLANSY
      EXTERNAL           slamch, slange, slansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, sgerqf, slacpy, slaset, sorgrq, ssyrk
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      minmn = min( m, n )
      eps = slamch( 'Epsilon' )
*
*     Copy the matrix A to the array AF.
*
      CALL slacpy( 'Full', m, n, a, lda, af, lda )
*
*     Factorize the matrix A in the array AF.
*
      srnamt = 'SGERQF'
      CALL sgerqf( m, n, af, lda, tau, work, lwork, info )
*
*     Copy details of Q
*
      CALL slaset( 'Full', n, n, rogue, rogue, q, lda )
      IF( m.LE.n ) THEN
         IF( m.GT.0 .AND. m.LT.n )
     $      CALL slacpy( 'Full', m, n-m, af, lda, q( n-m+1, 1 ), lda )
         IF( m.GT.1 )
     $      CALL slacpy( 'Lower', m-1, m-1, af( 2, n-m+1 ), lda,
     $                   q( n-m+2, n-m+1 ), lda )
      ELSE
         IF( n.GT.1 )
     $      CALL slacpy( 'Lower', n-1, n-1, af( m-n+2, 1 ), lda,
     $                   q( 2, 1 ), lda )
      END IF
*
*     Generate the n-by-n matrix Q
*
      srnamt = 'SORGRQ'
      CALL sorgrq( n, n, minmn, q, lda, tau, work, lwork, info )
*
*     Copy R
*
      CALL slaset( 'Full', m, n, zero, zero, r, lda )
      IF( m.LE.n ) THEN
         IF( m.GT.0 )
     $      CALL slacpy( 'Upper', m, m, af( 1, n-m+1 ), lda,
     $                   r( 1, n-m+1 ), lda )
      ELSE
         IF( m.GT.n .AND. n.GT.0 )
     $      CALL slacpy( 'Full', m-n, n, af, lda, r, lda )
         IF( n.GT.0 )
     $      CALL slacpy( 'Upper', n, n, af( m-n+1, 1 ), lda,
     $                   r( m-n+1, 1 ), lda )
      END IF
*
*     Compute R - A*Q'
*
      CALL sgemm( 'No transpose', 'Transpose', m, n, n, -one, a, lda, q,
     $            lda, one, r, lda )
*
*     Compute norm( R - Q'*A ) / ( N * norm(A) * EPS ) .
*
      anorm = slange( '1', m, n, a, lda, rwork )
      resid = slange( '1', m, n, r, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / real( max( 1, n ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL slaset( 'Full', n, n, zero, one, r, lda )
      CALL ssyrk( 'Upper', 'No transpose', n, n, -one, q, lda, one, r,
     $            lda )
*
*     Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
      resid = slansy( '1', 'Upper', n, r, lda, rwork )
*
      result( 2 ) = ( resid / real( max( 1, n ) ) ) / eps
*
      RETURN
*
*     End of SRQT01
*

Here is the call graph for this function:

Here is the caller graph for this function: