LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
sorgrq.f
Go to the documentation of this file.
1*> \brief \b SORGRQ
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sorgrq.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sorgrq.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sorgrq.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE SORGRQ( M, N, K, A, LDA, TAU, WORK, LWORK, INFO )
22*
23* .. Scalar Arguments ..
24* INTEGER INFO, K, LDA, LWORK, M, N
25* ..
26* .. Array Arguments ..
27* REAL A( LDA, * ), TAU( * ), WORK( * )
28* ..
29*
30*
31*> \par Purpose:
32* =============
33*>
34*> \verbatim
35*>
36*> SORGRQ generates an M-by-N real matrix Q with orthonormal rows,
37*> which is defined as the last M rows of a product of K elementary
38*> reflectors of order N
39*>
40*> Q = H(1) H(2) . . . H(k)
41*>
42*> as returned by SGERQF.
43*> \endverbatim
44*
45* Arguments:
46* ==========
47*
48*> \param[in] M
49*> \verbatim
50*> M is INTEGER
51*> The number of rows of the matrix Q. M >= 0.
52*> \endverbatim
53*>
54*> \param[in] N
55*> \verbatim
56*> N is INTEGER
57*> The number of columns of the matrix Q. N >= M.
58*> \endverbatim
59*>
60*> \param[in] K
61*> \verbatim
62*> K is INTEGER
63*> The number of elementary reflectors whose product defines the
64*> matrix Q. M >= K >= 0.
65*> \endverbatim
66*>
67*> \param[in,out] A
68*> \verbatim
69*> A is REAL array, dimension (LDA,N)
70*> On entry, the (m-k+i)-th row must contain the vector which
71*> defines the elementary reflector H(i), for i = 1,2,...,k, as
72*> returned by SGERQF in the last k rows of its array argument
73*> A.
74*> On exit, the M-by-N matrix Q.
75*> \endverbatim
76*>
77*> \param[in] LDA
78*> \verbatim
79*> LDA is INTEGER
80*> The first dimension of the array A. LDA >= max(1,M).
81*> \endverbatim
82*>
83*> \param[in] TAU
84*> \verbatim
85*> TAU is REAL array, dimension (K)
86*> TAU(i) must contain the scalar factor of the elementary
87*> reflector H(i), as returned by SGERQF.
88*> \endverbatim
89*>
90*> \param[out] WORK
91*> \verbatim
92*> WORK is REAL array, dimension (MAX(1,LWORK))
93*> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
94*> \endverbatim
95*>
96*> \param[in] LWORK
97*> \verbatim
98*> LWORK is INTEGER
99*> The dimension of the array WORK. LWORK >= max(1,M).
100*> For optimum performance LWORK >= M*NB, where NB is the
101*> optimal blocksize.
102*>
103*> If LWORK = -1, then a workspace query is assumed; the routine
104*> only calculates the optimal size of the WORK array, returns
105*> this value as the first entry of the WORK array, and no error
106*> message related to LWORK is issued by XERBLA.
107*> \endverbatim
108*>
109*> \param[out] INFO
110*> \verbatim
111*> INFO is INTEGER
112*> = 0: successful exit
113*> < 0: if INFO = -i, the i-th argument has an illegal value
114*> \endverbatim
115*
116* Authors:
117* ========
118*
119*> \author Univ. of Tennessee
120*> \author Univ. of California Berkeley
121*> \author Univ. of Colorado Denver
122*> \author NAG Ltd.
123*
124*> \ingroup ungrq
125*
126* =====================================================================
127 SUBROUTINE sorgrq( M, N, K, A, LDA, TAU, WORK, LWORK, INFO )
128*
129* -- LAPACK computational routine --
130* -- LAPACK is a software package provided by Univ. of Tennessee, --
131* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
132*
133* .. Scalar Arguments ..
134 INTEGER INFO, K, LDA, LWORK, M, N
135* ..
136* .. Array Arguments ..
137 REAL A( LDA, * ), TAU( * ), WORK( * )
138* ..
139*
140* =====================================================================
141*
142* .. Parameters ..
143 REAL ZERO
144 parameter( zero = 0.0e+0 )
145* ..
146* .. Local Scalars ..
147 LOGICAL LQUERY
148 INTEGER I, IB, II, IINFO, IWS, J, KK, L, LDWORK,
149 \$ LWKOPT, NB, NBMIN, NX
150* ..
151* .. External Subroutines ..
152 EXTERNAL slarfb, slarft, sorgr2, xerbla
153* ..
154* .. Intrinsic Functions ..
155 INTRINSIC max, min
156* ..
157* .. External Functions ..
158 INTEGER ILAENV
159 REAL SROUNDUP_LWORK
160 EXTERNAL ilaenv, sroundup_lwork
161* ..
162* .. Executable Statements ..
163*
164* Test the input arguments
165*
166 info = 0
167 lquery = ( lwork.EQ.-1 )
168 IF( m.LT.0 ) THEN
169 info = -1
170 ELSE IF( n.LT.m ) THEN
171 info = -2
172 ELSE IF( k.LT.0 .OR. k.GT.m ) THEN
173 info = -3
174 ELSE IF( lda.LT.max( 1, m ) ) THEN
175 info = -5
176 END IF
177*
178 IF( info.EQ.0 ) THEN
179 IF( m.LE.0 ) THEN
180 lwkopt = 1
181 ELSE
182 nb = ilaenv( 1, 'SORGRQ', ' ', m, n, k, -1 )
183 lwkopt = m*nb
184 END IF
185 work( 1 ) = sroundup_lwork(lwkopt)
186*
187 IF( lwork.LT.max( 1, m ) .AND. .NOT.lquery ) THEN
188 info = -8
189 END IF
190 END IF
191*
192 IF( info.NE.0 ) THEN
193 CALL xerbla( 'SORGRQ', -info )
194 RETURN
195 ELSE IF( lquery ) THEN
196 RETURN
197 END IF
198*
199* Quick return if possible
200*
201 IF( m.LE.0 ) THEN
202 RETURN
203 END IF
204*
205 nbmin = 2
206 nx = 0
207 iws = m
208 IF( nb.GT.1 .AND. nb.LT.k ) THEN
209*
210* Determine when to cross over from blocked to unblocked code.
211*
212 nx = max( 0, ilaenv( 3, 'SORGRQ', ' ', m, n, k, -1 ) )
213 IF( nx.LT.k ) THEN
214*
215* Determine if workspace is large enough for blocked code.
216*
217 ldwork = m
218 iws = ldwork*nb
219 IF( lwork.LT.iws ) THEN
220*
221* Not enough workspace to use optimal NB: reduce NB and
222* determine the minimum value of NB.
223*
224 nb = lwork / ldwork
225 nbmin = max( 2, ilaenv( 2, 'SORGRQ', ' ', m, n, k, -1 ) )
226 END IF
227 END IF
228 END IF
229*
230 IF( nb.GE.nbmin .AND. nb.LT.k .AND. nx.LT.k ) THEN
231*
232* Use blocked code after the first block.
233* The last kk rows are handled by the block method.
234*
235 kk = min( k, ( ( k-nx+nb-1 ) / nb )*nb )
236*
237* Set A(1:m-kk,n-kk+1:n) to zero.
238*
239 DO 20 j = n - kk + 1, n
240 DO 10 i = 1, m - kk
241 a( i, j ) = zero
242 10 CONTINUE
243 20 CONTINUE
244 ELSE
245 kk = 0
246 END IF
247*
248* Use unblocked code for the first or only block.
249*
250 CALL sorgr2( m-kk, n-kk, k-kk, a, lda, tau, work, iinfo )
251*
252 IF( kk.GT.0 ) THEN
253*
254* Use blocked code
255*
256 DO 50 i = k - kk + 1, k, nb
257 ib = min( nb, k-i+1 )
258 ii = m - k + i
259 IF( ii.GT.1 ) THEN
260*
261* Form the triangular factor of the block reflector
262* H = H(i+ib-1) . . . H(i+1) H(i)
263*
264 CALL slarft( 'Backward', 'Rowwise', n-k+i+ib-1, ib,
265 \$ a( ii, 1 ), lda, tau( i ), work, ldwork )
266*
267* Apply H**T to A(1:m-k+i-1,1:n-k+i+ib-1) from the right
268*
269 CALL slarfb( 'Right', 'Transpose', 'Backward', 'Rowwise',
270 \$ ii-1, n-k+i+ib-1, ib, a( ii, 1 ), lda, work,
271 \$ ldwork, a, lda, work( ib+1 ), ldwork )
272 END IF
273*
274* Apply H**T to columns 1:n-k+i+ib-1 of current block
275*
276 CALL sorgr2( ib, n-k+i+ib-1, ib, a( ii, 1 ), lda, tau( i ),
277 \$ work, iinfo )
278*
279* Set columns n-k+i+ib:n of current block to zero
280*
281 DO 40 l = n - k + i + ib, n
282 DO 30 j = ii, ii + ib - 1
283 a( j, l ) = zero
284 30 CONTINUE
285 40 CONTINUE
286 50 CONTINUE
287 END IF
288*
289 work( 1 ) = sroundup_lwork(iws)
290 RETURN
291*
292* End of SORGRQ
293*
294 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine slarfb(side, trans, direct, storev, m, n, k, v, ldv, t, ldt, c, ldc, work, ldwork)
SLARFB applies a block reflector or its transpose to a general rectangular matrix.
Definition slarfb.f:197
subroutine slarft(direct, storev, n, k, v, ldv, tau, t, ldt)
SLARFT forms the triangular factor T of a block reflector H = I - vtvH
Definition slarft.f:163
subroutine sorgr2(m, n, k, a, lda, tau, work, info)
SORGR2 generates all or part of the orthogonal matrix Q from an RQ factorization determined by sgerqf...
Definition sorgr2.f:114
subroutine sorgrq(m, n, k, a, lda, tau, work, lwork, info)
SORGRQ
Definition sorgrq.f:128