LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
slarft.f
Go to the documentation of this file.
1 *> \brief \b SLARFT forms the triangular factor T of a block reflector H = I - vtvH
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download SLARFT + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slarft.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slarft.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slarft.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE SLARFT( DIRECT, STOREV, N, K, V, LDV, TAU, T, LDT )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER DIRECT, STOREV
25 * INTEGER K, LDT, LDV, N
26 * ..
27 * .. Array Arguments ..
28 * REAL T( LDT, * ), TAU( * ), V( LDV, * )
29 * ..
30 *
31 *
32 *> \par Purpose:
33 * =============
34 *>
35 *> \verbatim
36 *>
37 *> SLARFT forms the triangular factor T of a real block reflector H
38 *> of order n, which is defined as a product of k elementary reflectors.
39 *>
40 *> If DIRECT = 'F', H = H(1) H(2) . . . H(k) and T is upper triangular;
41 *>
42 *> If DIRECT = 'B', H = H(k) . . . H(2) H(1) and T is lower triangular.
43 *>
44 *> If STOREV = 'C', the vector which defines the elementary reflector
45 *> H(i) is stored in the i-th column of the array V, and
46 *>
47 *> H = I - V * T * V**T
48 *>
49 *> If STOREV = 'R', the vector which defines the elementary reflector
50 *> H(i) is stored in the i-th row of the array V, and
51 *>
52 *> H = I - V**T * T * V
53 *> \endverbatim
54 *
55 * Arguments:
56 * ==========
57 *
58 *> \param[in] DIRECT
59 *> \verbatim
60 *> DIRECT is CHARACTER*1
61 *> Specifies the order in which the elementary reflectors are
62 *> multiplied to form the block reflector:
63 *> = 'F': H = H(1) H(2) . . . H(k) (Forward)
64 *> = 'B': H = H(k) . . . H(2) H(1) (Backward)
65 *> \endverbatim
66 *>
67 *> \param[in] STOREV
68 *> \verbatim
69 *> STOREV is CHARACTER*1
70 *> Specifies how the vectors which define the elementary
71 *> reflectors are stored (see also Further Details):
72 *> = 'C': columnwise
73 *> = 'R': rowwise
74 *> \endverbatim
75 *>
76 *> \param[in] N
77 *> \verbatim
78 *> N is INTEGER
79 *> The order of the block reflector H. N >= 0.
80 *> \endverbatim
81 *>
82 *> \param[in] K
83 *> \verbatim
84 *> K is INTEGER
85 *> The order of the triangular factor T (= the number of
86 *> elementary reflectors). K >= 1.
87 *> \endverbatim
88 *>
89 *> \param[in] V
90 *> \verbatim
91 *> V is REAL array, dimension
92 *> (LDV,K) if STOREV = 'C'
93 *> (LDV,N) if STOREV = 'R'
94 *> The matrix V. See further details.
95 *> \endverbatim
96 *>
97 *> \param[in] LDV
98 *> \verbatim
99 *> LDV is INTEGER
100 *> The leading dimension of the array V.
101 *> If STOREV = 'C', LDV >= max(1,N); if STOREV = 'R', LDV >= K.
102 *> \endverbatim
103 *>
104 *> \param[in] TAU
105 *> \verbatim
106 *> TAU is REAL array, dimension (K)
107 *> TAU(i) must contain the scalar factor of the elementary
108 *> reflector H(i).
109 *> \endverbatim
110 *>
111 *> \param[out] T
112 *> \verbatim
113 *> T is REAL array, dimension (LDT,K)
114 *> The k by k triangular factor T of the block reflector.
115 *> If DIRECT = 'F', T is upper triangular; if DIRECT = 'B', T is
116 *> lower triangular. The rest of the array is not used.
117 *> \endverbatim
118 *>
119 *> \param[in] LDT
120 *> \verbatim
121 *> LDT is INTEGER
122 *> The leading dimension of the array T. LDT >= K.
123 *> \endverbatim
124 *
125 * Authors:
126 * ========
127 *
128 *> \author Univ. of Tennessee
129 *> \author Univ. of California Berkeley
130 *> \author Univ. of Colorado Denver
131 *> \author NAG Ltd.
132 *
133 *> \ingroup realOTHERauxiliary
134 *
135 *> \par Further Details:
136 * =====================
137 *>
138 *> \verbatim
139 *>
140 *> The shape of the matrix V and the storage of the vectors which define
141 *> the H(i) is best illustrated by the following example with n = 5 and
142 *> k = 3. The elements equal to 1 are not stored.
143 *>
144 *> DIRECT = 'F' and STOREV = 'C': DIRECT = 'F' and STOREV = 'R':
145 *>
146 *> V = ( 1 ) V = ( 1 v1 v1 v1 v1 )
147 *> ( v1 1 ) ( 1 v2 v2 v2 )
148 *> ( v1 v2 1 ) ( 1 v3 v3 )
149 *> ( v1 v2 v3 )
150 *> ( v1 v2 v3 )
151 *>
152 *> DIRECT = 'B' and STOREV = 'C': DIRECT = 'B' and STOREV = 'R':
153 *>
154 *> V = ( v1 v2 v3 ) V = ( v1 v1 1 )
155 *> ( v1 v2 v3 ) ( v2 v2 v2 1 )
156 *> ( 1 v2 v3 ) ( v3 v3 v3 v3 1 )
157 *> ( 1 v3 )
158 *> ( 1 )
159 *> \endverbatim
160 *>
161 * =====================================================================
162  SUBROUTINE slarft( DIRECT, STOREV, N, K, V, LDV, TAU, T, LDT )
163 *
164 * -- LAPACK auxiliary routine --
165 * -- LAPACK is a software package provided by Univ. of Tennessee, --
166 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
167 *
168 * .. Scalar Arguments ..
169  CHARACTER DIRECT, STOREV
170  INTEGER K, LDT, LDV, N
171 * ..
172 * .. Array Arguments ..
173  REAL T( LDT, * ), TAU( * ), V( LDV, * )
174 * ..
175 *
176 * =====================================================================
177 *
178 * .. Parameters ..
179  REAL ONE, ZERO
180  parameter( one = 1.0e+0, zero = 0.0e+0 )
181 * ..
182 * .. Local Scalars ..
183  INTEGER I, J, PREVLASTV, LASTV
184 * ..
185 * .. External Subroutines ..
186  EXTERNAL sgemv, strmv
187 * ..
188 * .. External Functions ..
189  LOGICAL LSAME
190  EXTERNAL lsame
191 * ..
192 * .. Executable Statements ..
193 *
194 * Quick return if possible
195 *
196  IF( n.EQ.0 )
197  $ RETURN
198 *
199  IF( lsame( direct, 'F' ) ) THEN
200  prevlastv = n
201  DO i = 1, k
202  prevlastv = max( i, prevlastv )
203  IF( tau( i ).EQ.zero ) THEN
204 *
205 * H(i) = I
206 *
207  DO j = 1, i
208  t( j, i ) = zero
209  END DO
210  ELSE
211 *
212 * general case
213 *
214  IF( lsame( storev, 'C' ) ) THEN
215 * Skip any trailing zeros.
216  DO lastv = n, i+1, -1
217  IF( v( lastv, i ).NE.zero ) EXIT
218  END DO
219  DO j = 1, i-1
220  t( j, i ) = -tau( i ) * v( i , j )
221  END DO
222  j = min( lastv, prevlastv )
223 *
224 * T(1:i-1,i) := - tau(i) * V(i:j,1:i-1)**T * V(i:j,i)
225 *
226  CALL sgemv( 'Transpose', j-i, i-1, -tau( i ),
227  $ v( i+1, 1 ), ldv, v( i+1, i ), 1, one,
228  $ t( 1, i ), 1 )
229  ELSE
230 * Skip any trailing zeros.
231  DO lastv = n, i+1, -1
232  IF( v( i, lastv ).NE.zero ) EXIT
233  END DO
234  DO j = 1, i-1
235  t( j, i ) = -tau( i ) * v( j , i )
236  END DO
237  j = min( lastv, prevlastv )
238 *
239 * T(1:i-1,i) := - tau(i) * V(1:i-1,i:j) * V(i,i:j)**T
240 *
241  CALL sgemv( 'No transpose', i-1, j-i, -tau( i ),
242  $ v( 1, i+1 ), ldv, v( i, i+1 ), ldv,
243  $ one, t( 1, i ), 1 )
244  END IF
245 *
246 * T(1:i-1,i) := T(1:i-1,1:i-1) * T(1:i-1,i)
247 *
248  CALL strmv( 'Upper', 'No transpose', 'Non-unit', i-1, t,
249  $ ldt, t( 1, i ), 1 )
250  t( i, i ) = tau( i )
251  IF( i.GT.1 ) THEN
252  prevlastv = max( prevlastv, lastv )
253  ELSE
254  prevlastv = lastv
255  END IF
256  END IF
257  END DO
258  ELSE
259  prevlastv = 1
260  DO i = k, 1, -1
261  IF( tau( i ).EQ.zero ) THEN
262 *
263 * H(i) = I
264 *
265  DO j = i, k
266  t( j, i ) = zero
267  END DO
268  ELSE
269 *
270 * general case
271 *
272  IF( i.LT.k ) THEN
273  IF( lsame( storev, 'C' ) ) THEN
274 * Skip any leading zeros.
275  DO lastv = 1, i-1
276  IF( v( lastv, i ).NE.zero ) EXIT
277  END DO
278  DO j = i+1, k
279  t( j, i ) = -tau( i ) * v( n-k+i , j )
280  END DO
281  j = max( lastv, prevlastv )
282 *
283 * T(i+1:k,i) = -tau(i) * V(j:n-k+i,i+1:k)**T * V(j:n-k+i,i)
284 *
285  CALL sgemv( 'Transpose', n-k+i-j, k-i, -tau( i ),
286  $ v( j, i+1 ), ldv, v( j, i ), 1, one,
287  $ t( i+1, i ), 1 )
288  ELSE
289 * Skip any leading zeros.
290  DO lastv = 1, i-1
291  IF( v( i, lastv ).NE.zero ) EXIT
292  END DO
293  DO j = i+1, k
294  t( j, i ) = -tau( i ) * v( j, n-k+i )
295  END DO
296  j = max( lastv, prevlastv )
297 *
298 * T(i+1:k,i) = -tau(i) * V(i+1:k,j:n-k+i) * V(i,j:n-k+i)**T
299 *
300  CALL sgemv( 'No transpose', k-i, n-k+i-j,
301  $ -tau( i ), v( i+1, j ), ldv, v( i, j ), ldv,
302  $ one, t( i+1, i ), 1 )
303  END IF
304 *
305 * T(i+1:k,i) := T(i+1:k,i+1:k) * T(i+1:k,i)
306 *
307  CALL strmv( 'Lower', 'No transpose', 'Non-unit', k-i,
308  $ t( i+1, i+1 ), ldt, t( i+1, i ), 1 )
309  IF( i.GT.1 ) THEN
310  prevlastv = min( prevlastv, lastv )
311  ELSE
312  prevlastv = lastv
313  END IF
314  END IF
315  t( i, i ) = tau( i )
316  END IF
317  END DO
318  END IF
319  RETURN
320 *
321 * End of SLARFT
322 *
323  END
subroutine slarft(DIRECT, STOREV, N, K, V, LDV, TAU, T, LDT)
SLARFT forms the triangular factor T of a block reflector H = I - vtvH
Definition: slarft.f:163
subroutine strmv(UPLO, TRANS, DIAG, N, A, LDA, X, INCX)
STRMV
Definition: strmv.f:147
subroutine sgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
SGEMV
Definition: sgemv.f:156