LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
dtrmv.f
Go to the documentation of this file.
1*> \brief \b DTRMV
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* SUBROUTINE DTRMV(UPLO,TRANS,DIAG,N,A,LDA,X,INCX)
12*
13* .. Scalar Arguments ..
14* INTEGER INCX,LDA,N
15* CHARACTER DIAG,TRANS,UPLO
16* ..
17* .. Array Arguments ..
18* DOUBLE PRECISION A(LDA,*),X(*)
19* ..
20*
21*
22*> \par Purpose:
23* =============
24*>
25*> \verbatim
26*>
27*> DTRMV performs one of the matrix-vector operations
28*>
29*> x := A*x, or x := A**T*x,
30*>
31*> where x is an n element vector and A is an n by n unit, or non-unit,
32*> upper or lower triangular matrix.
33*> \endverbatim
34*
35* Arguments:
36* ==========
37*
38*> \param[in] UPLO
39*> \verbatim
40*> UPLO is CHARACTER*1
41*> On entry, UPLO specifies whether the matrix is an upper or
42*> lower triangular matrix as follows:
43*>
44*> UPLO = 'U' or 'u' A is an upper triangular matrix.
45*>
46*> UPLO = 'L' or 'l' A is a lower triangular matrix.
47*> \endverbatim
48*>
49*> \param[in] TRANS
50*> \verbatim
51*> TRANS is CHARACTER*1
52*> On entry, TRANS specifies the operation to be performed as
53*> follows:
54*>
55*> TRANS = 'N' or 'n' x := A*x.
56*>
57*> TRANS = 'T' or 't' x := A**T*x.
58*>
59*> TRANS = 'C' or 'c' x := A**T*x.
60*> \endverbatim
61*>
62*> \param[in] DIAG
63*> \verbatim
64*> DIAG is CHARACTER*1
65*> On entry, DIAG specifies whether or not A is unit
66*> triangular as follows:
67*>
68*> DIAG = 'U' or 'u' A is assumed to be unit triangular.
69*>
70*> DIAG = 'N' or 'n' A is not assumed to be unit
71*> triangular.
72*> \endverbatim
73*>
74*> \param[in] N
75*> \verbatim
76*> N is INTEGER
77*> On entry, N specifies the order of the matrix A.
78*> N must be at least zero.
79*> \endverbatim
80*>
81*> \param[in] A
82*> \verbatim
83*> A is DOUBLE PRECISION array, dimension ( LDA, N )
84*> Before entry with UPLO = 'U' or 'u', the leading n by n
85*> upper triangular part of the array A must contain the upper
86*> triangular matrix and the strictly lower triangular part of
87*> A is not referenced.
88*> Before entry with UPLO = 'L' or 'l', the leading n by n
89*> lower triangular part of the array A must contain the lower
90*> triangular matrix and the strictly upper triangular part of
91*> A is not referenced.
92*> Note that when DIAG = 'U' or 'u', the diagonal elements of
93*> A are not referenced either, but are assumed to be unity.
94*> \endverbatim
95*>
96*> \param[in] LDA
97*> \verbatim
98*> LDA is INTEGER
99*> On entry, LDA specifies the first dimension of A as declared
100*> in the calling (sub) program. LDA must be at least
101*> max( 1, n ).
102*> \endverbatim
103*>
104*> \param[in,out] X
105*> \verbatim
106*> X is DOUBLE PRECISION array, dimension at least
107*> ( 1 + ( n - 1 )*abs( INCX ) ).
108*> Before entry, the incremented array X must contain the n
109*> element vector x. On exit, X is overwritten with the
110*> transformed vector x.
111*> \endverbatim
112*>
113*> \param[in] INCX
114*> \verbatim
115*> INCX is INTEGER
116*> On entry, INCX specifies the increment for the elements of
117*> X. INCX must not be zero.
118*> \endverbatim
119*
120* Authors:
121* ========
122*
123*> \author Univ. of Tennessee
124*> \author Univ. of California Berkeley
125*> \author Univ. of Colorado Denver
126*> \author NAG Ltd.
127*
128*> \ingroup trmv
129*
130*> \par Further Details:
131* =====================
132*>
133*> \verbatim
134*>
135*> Level 2 Blas routine.
136*> The vector and matrix arguments are not referenced when N = 0, or M = 0
137*>
138*> -- Written on 22-October-1986.
139*> Jack Dongarra, Argonne National Lab.
140*> Jeremy Du Croz, Nag Central Office.
141*> Sven Hammarling, Nag Central Office.
142*> Richard Hanson, Sandia National Labs.
143*> \endverbatim
144*>
145* =====================================================================
146 SUBROUTINE dtrmv(UPLO,TRANS,DIAG,N,A,LDA,X,INCX)
147*
148* -- Reference BLAS level2 routine --
149* -- Reference BLAS is a software package provided by Univ. of Tennessee, --
150* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
151*
152* .. Scalar Arguments ..
153 INTEGER INCX,LDA,N
154 CHARACTER DIAG,TRANS,UPLO
155* ..
156* .. Array Arguments ..
157 DOUBLE PRECISION A(LDA,*),X(*)
158* ..
159*
160* =====================================================================
161*
162* .. Parameters ..
163 DOUBLE PRECISION ZERO
164 parameter(zero=0.0d+0)
165* ..
166* .. Local Scalars ..
167 DOUBLE PRECISION TEMP
168 INTEGER I,INFO,IX,J,JX,KX
169 LOGICAL NOUNIT
170* ..
171* .. External Functions ..
172 LOGICAL LSAME
173 EXTERNAL lsame
174* ..
175* .. External Subroutines ..
176 EXTERNAL xerbla
177* ..
178* .. Intrinsic Functions ..
179 INTRINSIC max
180* ..
181*
182* Test the input parameters.
183*
184 info = 0
185 IF (.NOT.lsame(uplo,'U') .AND. .NOT.lsame(uplo,'L')) THEN
186 info = 1
187 ELSE IF (.NOT.lsame(trans,'N') .AND.
188 + .NOT.lsame(trans,'T') .AND.
189 + .NOT.lsame(trans,'C')) THEN
190 info = 2
191 ELSE IF (.NOT.lsame(diag,'U') .AND.
192 + .NOT.lsame(diag,'N')) THEN
193 info = 3
194 ELSE IF (n.LT.0) THEN
195 info = 4
196 ELSE IF (lda.LT.max(1,n)) THEN
197 info = 6
198 ELSE IF (incx.EQ.0) THEN
199 info = 8
200 END IF
201 IF (info.NE.0) THEN
202 CALL xerbla('DTRMV ',info)
203 RETURN
204 END IF
205*
206* Quick return if possible.
207*
208 IF (n.EQ.0) RETURN
209*
210 nounit = lsame(diag,'N')
211*
212* Set up the start point in X if the increment is not unity. This
213* will be ( N - 1 )*INCX too small for descending loops.
214*
215 IF (incx.LE.0) THEN
216 kx = 1 - (n-1)*incx
217 ELSE IF (incx.NE.1) THEN
218 kx = 1
219 END IF
220*
221* Start the operations. In this version the elements of A are
222* accessed sequentially with one pass through A.
223*
224 IF (lsame(trans,'N')) THEN
225*
226* Form x := A*x.
227*
228 IF (lsame(uplo,'U')) THEN
229 IF (incx.EQ.1) THEN
230 DO 20 j = 1,n
231 IF (x(j).NE.zero) THEN
232 temp = x(j)
233 DO 10 i = 1,j - 1
234 x(i) = x(i) + temp*a(i,j)
235 10 CONTINUE
236 IF (nounit) x(j) = x(j)*a(j,j)
237 END IF
238 20 CONTINUE
239 ELSE
240 jx = kx
241 DO 40 j = 1,n
242 IF (x(jx).NE.zero) THEN
243 temp = x(jx)
244 ix = kx
245 DO 30 i = 1,j - 1
246 x(ix) = x(ix) + temp*a(i,j)
247 ix = ix + incx
248 30 CONTINUE
249 IF (nounit) x(jx) = x(jx)*a(j,j)
250 END IF
251 jx = jx + incx
252 40 CONTINUE
253 END IF
254 ELSE
255 IF (incx.EQ.1) THEN
256 DO 60 j = n,1,-1
257 IF (x(j).NE.zero) THEN
258 temp = x(j)
259 DO 50 i = n,j + 1,-1
260 x(i) = x(i) + temp*a(i,j)
261 50 CONTINUE
262 IF (nounit) x(j) = x(j)*a(j,j)
263 END IF
264 60 CONTINUE
265 ELSE
266 kx = kx + (n-1)*incx
267 jx = kx
268 DO 80 j = n,1,-1
269 IF (x(jx).NE.zero) THEN
270 temp = x(jx)
271 ix = kx
272 DO 70 i = n,j + 1,-1
273 x(ix) = x(ix) + temp*a(i,j)
274 ix = ix - incx
275 70 CONTINUE
276 IF (nounit) x(jx) = x(jx)*a(j,j)
277 END IF
278 jx = jx - incx
279 80 CONTINUE
280 END IF
281 END IF
282 ELSE
283*
284* Form x := A**T*x.
285*
286 IF (lsame(uplo,'U')) THEN
287 IF (incx.EQ.1) THEN
288 DO 100 j = n,1,-1
289 temp = x(j)
290 IF (nounit) temp = temp*a(j,j)
291 DO 90 i = j - 1,1,-1
292 temp = temp + a(i,j)*x(i)
293 90 CONTINUE
294 x(j) = temp
295 100 CONTINUE
296 ELSE
297 jx = kx + (n-1)*incx
298 DO 120 j = n,1,-1
299 temp = x(jx)
300 ix = jx
301 IF (nounit) temp = temp*a(j,j)
302 DO 110 i = j - 1,1,-1
303 ix = ix - incx
304 temp = temp + a(i,j)*x(ix)
305 110 CONTINUE
306 x(jx) = temp
307 jx = jx - incx
308 120 CONTINUE
309 END IF
310 ELSE
311 IF (incx.EQ.1) THEN
312 DO 140 j = 1,n
313 temp = x(j)
314 IF (nounit) temp = temp*a(j,j)
315 DO 130 i = j + 1,n
316 temp = temp + a(i,j)*x(i)
317 130 CONTINUE
318 x(j) = temp
319 140 CONTINUE
320 ELSE
321 jx = kx
322 DO 160 j = 1,n
323 temp = x(jx)
324 ix = jx
325 IF (nounit) temp = temp*a(j,j)
326 DO 150 i = j + 1,n
327 ix = ix + incx
328 temp = temp + a(i,j)*x(ix)
329 150 CONTINUE
330 x(jx) = temp
331 jx = jx + incx
332 160 CONTINUE
333 END IF
334 END IF
335 END IF
336*
337 RETURN
338*
339* End of DTRMV
340*
341 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine dtrmv(uplo, trans, diag, n, a, lda, x, incx)
DTRMV
Definition dtrmv.f:147