zlanhp.f

Go to the documentation of this file.

*> \brief \b ZLANHP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix supplied in packed form.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> Download ZLANHP + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlanhp.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlanhp.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlanhp.f">
*> [TXT]</a>
*
*  Definition:
*  ===========
*
*       DOUBLE PRECISION FUNCTION ZLANHP( NORM, UPLO, N, AP, WORK )
*
*       .. Scalar Arguments ..
*       CHARACTER          NORM, UPLO
*       INTEGER            N
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   WORK( * )
*       COMPLEX*16         AP( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZLANHP  returns the value of the one norm,  or the Frobenius norm, or
*> the  infinity norm,  or the  element of  largest absolute value  of a
*> complex hermitian matrix A,  supplied in packed form.
*> \endverbatim
*>
*> \return ZLANHP
*> \verbatim
*>
*>    ZLANHP = ( max(abs(A(i,j))), NORM = 'M' or 'm'
*>             (
*>             ( norm1(A),         NORM = '1', 'O' or 'o'
*>             (
*>             ( normI(A),         NORM = 'I' or 'i'
*>             (
*>             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
*>
*> where  norm1  denotes the  one norm of a matrix (maximum column sum),
*> normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
*> normF  denotes the  Frobenius norm of a matrix (square root of sum of
*> squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] NORM
*> \verbatim
*>          NORM is CHARACTER*1
*>          Specifies the value to be returned in ZLANHP as described
*>          above.
*> \endverbatim
*>
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the upper or lower triangular part of the
*>          hermitian matrix A is supplied.
*>          = 'U':  Upper triangular part of A is supplied
*>          = 'L':  Lower triangular part of A is supplied
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.  When N = 0, ZLANHP is
*>          set to zero.
*> \endverbatim
*>
*> \param[in] AP
*> \verbatim
*>          AP is COMPLEX*16 array, dimension (N*(N+1)/2)
*>          The upper or lower triangle of the hermitian matrix A, packed
*>          columnwise in a linear array.  The j-th column of A is stored
*>          in the array AP as follows:
*>          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
*>          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
*>          Note that the  imaginary parts of the diagonal elements need
*>          not be set and are assumed to be zero.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
*>          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
*>          WORK is not referenced.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup lanhp
*
*  =====================================================================
      DOUBLE PRECISION FUNCTION zlanhp( NORM, UPLO, N, AP, WORK )
*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          norm, uplo
      INTEGER            n
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   work( * )
      COMPLEX*16         ap( * )
*     ..
*
* =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one, zero
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j, k
      DOUBLE PRECISION   absa, scale, sum, value
*     ..
*     .. External Functions ..
      LOGICAL            lsame, disnan
      EXTERNAL           lsame, disnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           zlassq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, sqrt
*     ..
*     .. Executable Statements ..
*
      IF( n.EQ.0 ) THEN
         VALUE = zero
      ELSE IF( lsame( norm, 'M' ) ) THEN
*
*        Find max(abs(A(i,j))).
*
         VALUE = zero
         IF( lsame( uplo, 'U' ) ) THEN
            k = 0
            DO 20 j = 1, n
               DO 10 i = k + 1, k + j - 1
                  sum = abs( ap( i ) )
                  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
   10          CONTINUE
               k = k + j
               sum = abs( dble( ap( k ) ) )
               IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
   20       CONTINUE
         ELSE
            k = 1
            DO 40 j = 1, n
               sum = abs( dble( ap( k ) ) )
               IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
               DO 30 i = k + 1, k + n - j
                  sum = abs( ap( i ) )
                  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
   30          CONTINUE
               k = k + n - j + 1
   40       CONTINUE
         END IF
      ELSE IF( ( lsame( norm, 'I' ) ) .OR.
     $         ( lsame( norm, 'O' ) ) .OR.
     $         ( norm.EQ.'1' ) ) THEN
*
*        Find normI(A) ( = norm1(A), since A is hermitian).
*
         VALUE = zero
         k = 1
         IF( lsame( uplo, 'U' ) ) THEN
            DO 60 j = 1, n
               sum = zero
               DO 50 i = 1, j - 1
                  absa = abs( ap( k ) )
                  sum = sum + absa
                  work( i ) = work( i ) + absa
                  k = k + 1
   50          CONTINUE
               work( j ) = sum + abs( dble( ap( k ) ) )
               k = k + 1
   60       CONTINUE
            DO 70 i = 1, n
               sum = work( i )
               IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
   70       CONTINUE
         ELSE
            DO 80 i = 1, n
               work( i ) = zero
   80       CONTINUE
            DO 100 j = 1, n
               sum = work( j ) + abs( dble( ap( k ) ) )
               k = k + 1
               DO 90 i = j + 1, n
                  absa = abs( ap( k ) )
                  sum = sum + absa
                  work( i ) = work( i ) + absa
                  k = k + 1
   90          CONTINUE
               IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
  100       CONTINUE
         END IF
      ELSE IF( ( lsame( norm, 'F' ) ) .OR.
     $         ( lsame( norm, 'E' ) ) ) THEN
*
*        Find normF(A).
*
         scale = zero
         sum = one
         k = 2
         IF( lsame( uplo, 'U' ) ) THEN
            DO 110 j = 2, n
               CALL zlassq( j-1, ap( k ), 1, scale, sum )
               k = k + j
  110       CONTINUE
         ELSE
            DO 120 j = 1, n - 1
               CALL zlassq( n-j, ap( k ), 1, scale, sum )
               k = k + n - j + 1
  120       CONTINUE
         END IF
         sum = 2*sum
         k = 1
         DO 130 i = 1, n
            IF( dble( ap( k ) ).NE.zero ) THEN
               absa = abs( dble( ap( k ) ) )
               IF( scale.LT.absa ) THEN
                  sum = one + sum*( scale / absa )**2
                  scale = absa
               ELSE
                  sum = sum + ( absa / scale )**2
               END IF
            END IF
            IF( lsame( uplo, 'U' ) ) THEN
               k = k + i + 1
            ELSE
               k = k + n - i + 1
            END IF
  130    CONTINUE
         VALUE = scale*sqrt( sum )
      END IF
*
      zlanhp = VALUE
      RETURN
*
*     End of ZLANHP
*
      END