LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
dlange.f
Go to the documentation of this file.
1 *> \brief \b DLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of a general rectangular matrix.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download DLANGE + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlange.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlange.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlange.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * DOUBLE PRECISION FUNCTION DLANGE( NORM, M, N, A, LDA, WORK )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER NORM
25 * INTEGER LDA, M, N
26 * ..
27 * .. Array Arguments ..
28 * DOUBLE PRECISION A( LDA, * ), WORK( * )
29 * ..
30 *
31 *
32 *> \par Purpose:
33 * =============
34 *>
35 *> \verbatim
36 *>
37 *> DLANGE returns the value of the one norm, or the Frobenius norm, or
38 *> the infinity norm, or the element of largest absolute value of a
39 *> real matrix A.
40 *> \endverbatim
41 *>
42 *> \return DLANGE
43 *> \verbatim
44 *>
45 *> DLANGE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
46 *> (
47 *> ( norm1(A), NORM = '1', 'O' or 'o'
48 *> (
49 *> ( normI(A), NORM = 'I' or 'i'
50 *> (
51 *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
52 *>
53 *> where norm1 denotes the one norm of a matrix (maximum column sum),
54 *> normI denotes the infinity norm of a matrix (maximum row sum) and
55 *> normF denotes the Frobenius norm of a matrix (square root of sum of
56 *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
57 *> \endverbatim
58 *
59 * Arguments:
60 * ==========
61 *
62 *> \param[in] NORM
63 *> \verbatim
64 *> NORM is CHARACTER*1
65 *> Specifies the value to be returned in DLANGE as described
66 *> above.
67 *> \endverbatim
68 *>
69 *> \param[in] M
70 *> \verbatim
71 *> M is INTEGER
72 *> The number of rows of the matrix A. M >= 0. When M = 0,
73 *> DLANGE is set to zero.
74 *> \endverbatim
75 *>
76 *> \param[in] N
77 *> \verbatim
78 *> N is INTEGER
79 *> The number of columns of the matrix A. N >= 0. When N = 0,
80 *> DLANGE is set to zero.
81 *> \endverbatim
82 *>
83 *> \param[in] A
84 *> \verbatim
85 *> A is DOUBLE PRECISION array, dimension (LDA,N)
86 *> The m by n matrix A.
87 *> \endverbatim
88 *>
89 *> \param[in] LDA
90 *> \verbatim
91 *> LDA is INTEGER
92 *> The leading dimension of the array A. LDA >= max(M,1).
93 *> \endverbatim
94 *>
95 *> \param[out] WORK
96 *> \verbatim
97 *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
98 *> where LWORK >= M when NORM = 'I'; otherwise, WORK is not
99 *> referenced.
100 *> \endverbatim
101 *
102 * Authors:
103 * ========
104 *
105 *> \author Univ. of Tennessee
106 *> \author Univ. of California Berkeley
107 *> \author Univ. of Colorado Denver
108 *> \author NAG Ltd.
109 *
110 *> \ingroup doubleGEauxiliary
111 *
112 * =====================================================================
113  DOUBLE PRECISION FUNCTION dlange( NORM, M, N, A, LDA, WORK )
114 *
115 * -- LAPACK auxiliary routine --
116 * -- LAPACK is a software package provided by Univ. of Tennessee, --
117 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
118 *
119  IMPLICIT NONE
120 * .. Scalar Arguments ..
121  CHARACTER norm
122  INTEGER lda, m, n
123 * ..
124 * .. Array Arguments ..
125  DOUBLE PRECISION a( lda, * ), work( * )
126 * ..
127 *
128 * =====================================================================
129 *
130 * .. Parameters ..
131  DOUBLE PRECISION one, zero
132  parameter( one = 1.0d+0, zero = 0.0d+0 )
133 * ..
134 * .. Local Scalars ..
135  INTEGER i, j
136  DOUBLE PRECISION sum, VALUE, temp
137 * ..
138 * .. Local Arrays ..
139  DOUBLE PRECISION ssq( 2 ), colssq( 2 )
140 * ..
141 * .. External Subroutines ..
142  EXTERNAL dlassq, dcombssq
143 * ..
144 * .. External Functions ..
145  LOGICAL lsame, disnan
146  EXTERNAL lsame, disnan
147 * ..
148 * .. Intrinsic Functions ..
149  INTRINSIC abs, min, sqrt
150 * ..
151 * .. Executable Statements ..
152 *
153  IF( min( m, n ).EQ.0 ) THEN
154  VALUE = zero
155  ELSE IF( lsame( norm, 'M' ) ) THEN
156 *
157 * Find max(abs(A(i,j))).
158 *
159  VALUE = zero
160  DO 20 j = 1, n
161  DO 10 i = 1, m
162  temp = abs( a( i, j ) )
163  IF( VALUE.LT.temp .OR. disnan( temp ) ) VALUE = temp
164  10 CONTINUE
165  20 CONTINUE
166  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
167 *
168 * Find norm1(A).
169 *
170  VALUE = zero
171  DO 40 j = 1, n
172  sum = zero
173  DO 30 i = 1, m
174  sum = sum + abs( a( i, j ) )
175  30 CONTINUE
176  IF( VALUE.LT.sum .OR. disnan( sum ) ) VALUE = sum
177  40 CONTINUE
178  ELSE IF( lsame( norm, 'I' ) ) THEN
179 *
180 * Find normI(A).
181 *
182  DO 50 i = 1, m
183  work( i ) = zero
184  50 CONTINUE
185  DO 70 j = 1, n
186  DO 60 i = 1, m
187  work( i ) = work( i ) + abs( a( i, j ) )
188  60 CONTINUE
189  70 CONTINUE
190  VALUE = zero
191  DO 80 i = 1, m
192  temp = work( i )
193  IF( VALUE.LT.temp .OR. disnan( temp ) ) VALUE = temp
194  80 CONTINUE
195  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
196 *
197 * Find normF(A).
198 * SSQ(1) is scale
199 * SSQ(2) is sum-of-squares
200 * For better accuracy, sum each column separately.
201 *
202  ssq( 1 ) = zero
203  ssq( 2 ) = one
204  DO 90 j = 1, n
205  colssq( 1 ) = zero
206  colssq( 2 ) = one
207  CALL dlassq( m, a( 1, j ), 1, colssq( 1 ), colssq( 2 ) )
208  CALL dcombssq( ssq, colssq )
209  90 CONTINUE
210  VALUE = ssq( 1 )*sqrt( ssq( 2 ) )
211  END IF
212 *
213  dlange = VALUE
214  RETURN
215 *
216 * End of DLANGE
217 *
218  END
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:59
subroutine dlassq(n, x, incx, scl, sumsq)
DLASSQ updates a sum of squares represented in scaled form.
Definition: dlassq.f90:126
subroutine dcombssq(V1, V2)
DCOMBSSQ adds two scaled sum of squares quantities.
Definition: dcombssq.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
double precision function dlange(NORM, M, N, A, LDA, WORK)
DLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: dlange.f:114