cchkhe_aa_2stage()

subroutine cchkhe_aa_2stage	(	logical, dimension( * )	dotype,
		integer	nn,
		integer, dimension( * )	nval,
		integer	nnb,
		integer, dimension( * )	nbval,
		integer	nns,
		integer, dimension( * )	nsval,
		real	thresh,
		logical	tsterr,
		integer	nmax,
		complex, dimension( * )	a,
		complex, dimension( * )	afac,
		complex, dimension( * )	ainv,
		complex, dimension( * )	b,
		complex, dimension( * )	x,
		complex, dimension( * )	xact,
		complex, dimension( * )	work,
		real, dimension( * )	rwork,
		integer, dimension( * )	iwork,
		integer	nout
	)

CCHKHE_AA_2STAGE

Purpose:

 CCHKSY_AA_2STAGE tests CHETRF_AA_2STAGE, -TRS_AA_2STAGE.

Parameters

[in]	DOTYPE	DOTYPE is LOGICAL array, dimension (NTYPES) The matrix types to be used for testing. Matrices of type j (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) = .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
[in]	NN	NN is INTEGER The number of values of N contained in the vector NVAL.
[in]	NVAL	NVAL is INTEGER array, dimension (NN) The values of the matrix dimension N.
[in]	NNB	NNB is INTEGER The number of values of NB contained in the vector NBVAL.
[in]	NBVAL	NBVAL is INTEGER array, dimension (NNB) The values of the blocksize NB.
[in]	NNS	NNS is INTEGER The number of values of NRHS contained in the vector NSVAL.
[in]	NSVAL	NSVAL is INTEGER array, dimension (NNS) The values of the number of right hand sides NRHS.
[in]	THRESH	THRESH is REAL The threshold value for the test ratios. A result is included in the output file if RESULT >= THRESH. To have every test ratio printed, use THRESH = 0.
[in]	TSTERR	TSTERR is LOGICAL Flag that indicates whether error exits are to be tested.
[in]	NMAX	NMAX is INTEGER The maximum value permitted for N, used in dimensioning the work arrays.
[out]	A	A is COMPLEX array, dimension (NMAX*NMAX)
[out]	AFAC	AFAC is COMPLEX array, dimension (NMAX*NMAX)
[out]	AINV	AINV is COMPLEX array, dimension (NMAX*NMAX)
[out]	B	B is COMPLEX array, dimension (NMAX*NSMAX) where NSMAX is the largest entry in NSVAL.
[out]	X	X is COMPLEX array, dimension (NMAX*NSMAX)
[out]	XACT	XACT is COMPLEX array, dimension (NMAX*NSMAX)
[out]	WORK	WORK is COMPLEX array, dimension (NMAX*max(3,NSMAX))
[out]	RWORK	RWORK is REAL array, dimension (max(NMAX,2*NSMAX))
[out]	IWORK	IWORK is INTEGER array, dimension (2*NMAX)
[in]	NOUT	NOUT is INTEGER The unit number for output.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 169 of file cchkhe_aa_2stage.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
      IMPLICIT NONE
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NN, NNB, NNS, NMAX, NOUT
      REAL               THRESH
*     ..
*     .. Array Arguments ..
*
      LOGICAL      DOTYPE( * )
      INTEGER      IWORK( * ), NBVAL( * ), NSVAL( * ), NVAL( * )
      REAL         RWORK( * )
      COMPLEX      A( * ), AFAC( * ), AINV( * ), B( * ),
     $             WORK( * ), X( * ), XACT( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL         ZERO
      parameter( zero = 0.0e+0 )
      COMPLEX      CZERO
      parameter( czero = ( 0.0e+0, 0.0e+0 ) )
      INTEGER      NTYPES
      parameter( ntypes = 10 )
      INTEGER      NTESTS
      parameter( ntests = 9 )
*     ..
*     .. Local Scalars ..
      LOGICAL            ZEROT
      CHARACTER          DIST, TYPE, UPLO, XTYPE
      CHARACTER*3        PATH, MATPATH
      INTEGER            I, I1, I2, IMAT, IN, INB, INFO, IOFF, IRHS,
     $                   IUPLO, IZERO, J, K, KL, KU, LDA, LWORK, MODE,
     $                   N, NB, NERRS, NFAIL, NIMAT, NRHS, NRUN, NT
      REAL               ANORM, CNDNUM
*     ..
*     .. Local Arrays ..
      CHARACTER          UPLOS( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      REAL               RESULT( NTESTS )
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, cerrhe, clacpy, 
     $                   clarhs, clatb4, clatms, cpot02, 
     $                   chetrf_aa_2stage, 
     $                   chetrs_aa_2stage, xlaenv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
*
*     Test path
*
      path( 1: 1 ) = 'Complex precision'
      path( 2: 3 ) = 'H2'
*
*     Path to generate matrices
*
      matpath( 1: 1 ) = 'Complex precision'
      matpath( 2: 3 ) = 'HE'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL cerrhe( path, nout )
      infot = 0
*
*     Set the minimum block size for which the block routine should
*     be used, which will be later returned by ILAENV
*
      CALL xlaenv( 2, 2 )
*
*     Do for each value of N in NVAL
*
      DO 180 in = 1, nn
         n = nval( in )
         IF( n .GT. nmax ) THEN
            nfail = nfail + 1
            WRITE(nout, 9995) 'M ', n, nmax
            GO TO 180
         END IF
         lda = max( n, 1 )
         xtype = 'N'
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         izero = 0
*
*        Do for each value of matrix type IMAT
*
         DO 170 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 170
*
*           Skip types 3, 4, 5, or 6 if the matrix size is too small.
*
            zerot = imat.GE.3 .AND. imat.LE.6
            IF( zerot .AND. n.LT.imat-2 )
     $         GO TO 170
*
*           Do first for UPLO = 'U', then for UPLO = 'L'
*
            DO 160 iuplo = 1, 2
               uplo = uplos( iuplo )
*
*              Begin generate the test matrix A.
*
*
*              Set up parameters with CLATB4 for the matrix generator
*              based on the type of matrix to be generated.
*
               CALL clatb4( matpath, imat, n, n, TYPE, KL, KU,
     $                      ANORM, MODE, CNDNUM, DIST )
*
*              Generate a matrix with CLATMS.
*
               srnamt = 'CLATMS'
               CALL clatms( n, n, dist, iseed, TYPE, RWORK, MODE,
     $                      CNDNUM, ANORM, KL, KU, UPLO, A, LDA, WORK,
     $                      INFO )
*
*              Check error code from CLATMS and handle error.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'CLATMS', info, 0, uplo, n, n, -1,
     $                         -1, -1, imat, nfail, nerrs, nout )
*
*                    Skip all tests for this generated matrix
*
                  GO TO 160
               END IF
*
*              For matrix types 3-6, zero one or more rows and
*              columns of the matrix to test that INFO is returned
*              correctly.
*
               IF( zerot ) THEN
                  IF( imat.EQ.3 ) THEN
                     izero = 1
                  ELSE IF( imat.EQ.4 ) THEN
                     izero = n
                  ELSE
                     izero = n / 2 + 1
                  END IF
*
                  IF( imat.LT.6 ) THEN
*
*                    Set row and column IZERO to zero.
*
                     IF( iuplo.EQ.1 ) THEN
                        ioff = ( izero-1 )*lda
                        DO 20 i = 1, izero - 1
                           a( ioff+i ) = czero
   20                   CONTINUE
                        ioff = ioff + izero
                        DO 30 i = izero, n
                           a( ioff ) = czero
                           ioff = ioff + lda
   30                   CONTINUE
                     ELSE
                        ioff = izero
                        DO 40 i = 1, izero - 1
                           a( ioff ) = czero
                           ioff = ioff + lda
   40                   CONTINUE
                        ioff = ioff - izero
                        DO 50 i = izero, n
                           a( ioff+i ) = czero
   50                   CONTINUE
                     END IF
                  ELSE
                     IF( iuplo.EQ.1 ) THEN
*
*                       Set the first IZERO rows and columns to zero.
*
                        ioff = 0
                        DO 70 j = 1, n
                           i2 = min( j, izero )
                           DO 60 i = 1, i2
                              a( ioff+i ) = czero
   60                      CONTINUE
                           ioff = ioff + lda
   70                   CONTINUE
                        izero = 1
                     ELSE
*
*                       Set the last IZERO rows and columns to zero.
*
                        ioff = 0
                        DO 90 j = 1, n
                           i1 = max( j, izero )
                           DO 80 i = i1, n
                              a( ioff+i ) = czero
   80                      CONTINUE
                           ioff = ioff + lda
   90                   CONTINUE
                     END IF
                  END IF
               ELSE
                  izero = 0
               END IF
*
*              End generate test matrix A.
*
*
*              Set the imaginary part of the diagonals.
*
               CALL claipd( n, a, lda+1, 0 )
*
*              Do for each value of NB in NBVAL
*
               DO 150 inb = 1, nnb
*
*                 Set the optimal blocksize, which will be later
*                 returned by ILAENV.
*
                  nb = nbval( inb )
                  CALL xlaenv( 1, nb )
*
*                 Copy the test matrix A into matrix AFAC which
*                 will be factorized in place. This is needed to
*                 preserve the test matrix A for subsequent tests.
*
                  CALL clacpy( uplo, n, n, a, lda, afac, lda )
*
*                 Compute the L*D*L**T or U*D*U**T factorization of the
*                 matrix. IWORK stores details of the interchanges and
*                 the block structure of D. AINV is a work array for
*                 block factorization, LWORK is the length of AINV.
*
                  srnamt = 'CHETRF_AA_2STAGE'
                  lwork = min(n*nb, 3*nmax*nmax)
                  CALL chetrf_aa_2stage( uplo, n, afac, lda, 
     $                                   ainv, (3*nb+1)*n, 
     $                                   iwork, iwork( 1+n ),
     $                                   work, lwork,
     $                                   info )
*
*                 Adjust the expected value of INFO to account for
*                 pivoting.
*
                  IF( izero.GT.0 ) THEN
                     j = 1
                     k = izero
  100                CONTINUE
                     IF( j.EQ.k ) THEN
                        k = iwork( j )
                     ELSE IF( iwork( j ).EQ.k ) THEN
                        k = j
                     END IF
                     IF( j.LT.k ) THEN
                        j = j + 1
                        GO TO 100
                     END IF
                  ELSE
                     k = 0
                  END IF
*
*                 Check error code from CHETRF and handle error.
*
                  IF( info.NE.k ) THEN
                     CALL alaerh( path, 'CHETRF_AA_2STAGE', info, k,
     $                            uplo, n, n, -1, -1, nb, imat, nfail,
     $                            nerrs, nout )
                  END IF
*
*+    TEST 1
*                 Reconstruct matrix from factors and compute residual.
*
*                   
c                 NEED TO WRITE CHET01_AA_2STAGE
c                  CALL CHET01_AA( UPLO, N, A, LDA, AFAC, LDA, IWORK,
c     $                            AINV, LDA, RWORK, RESULT( 1 ) )
c                  NT = 1
                   nt = 0
*
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  DO 110 k = 1, nt
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9999 )uplo, n, nb, imat, k,
     $                     result( k )
                        nfail = nfail + 1
                     END IF
  110             CONTINUE
                  nrun = nrun + nt
*
*                 Skip solver test if INFO is not 0.
*
                  IF( info.NE.0 ) THEN
                     GO TO 140
                  END IF
*
*                 Do for each value of NRHS in NSVAL.
*
                  DO 130 irhs = 1, nns
                     nrhs = nsval( irhs )
*
*+    TEST 2 (Using TRS)
*                 Solve and compute residual for  A * X = B.
*
*                    Choose a set of NRHS random solution vectors
*                    stored in XACT and set up the right hand side B
*
                     srnamt = 'CLARHS'
                     CALL clarhs( matpath, xtype, uplo, ' ', n, n,
     $                            kl, ku, nrhs, a, lda, xact, lda,
     $                            b, lda, iseed, info )
                     CALL clacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                     srnamt = 'CHETRS_AA_2STAGE'
                     lwork = max( 1, 3*n-2 )
                     CALL chetrs_aa_2stage( uplo, n, nrhs, afac, lda,
     $                            ainv, (3*nb+1)*n, iwork, iwork( 1+n ),
     $                            x, lda, info )
*
*                    Check error code from CHETRS and handle error.
*
                     IF( info.NE.0 ) THEN
                        IF( izero.EQ.0 ) THEN
                           CALL alaerh( path, 'CHETRS_AA_2STAGE',
     $                                  info, 0, uplo, n, n, -1, -1,
     $                                  nrhs, imat, nfail, nerrs, nout )
                        END IF
                     ELSE
                        CALL clacpy( 'Full', n, nrhs, b, lda, work, lda
     $                               )
*
*                       Compute the residual for the solution
*
                        CALL cpot02( uplo, n, nrhs, a, lda, x, lda,
     $                               work, lda, rwork, result( 2 ) )
*
*                       Print information about the tests that did not pass
*                       the threshold.
*
                        DO 120 k = 2, 2
                           IF( result( k ).GE.thresh ) THEN
                              IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                           CALL alahd( nout, path )
                              WRITE( nout, fmt = 9998 )uplo, n, nrhs,
     $                           imat, k, result( k )
                              nfail = nfail + 1
                           END IF
  120                   CONTINUE
                     END IF
                     nrun = nrun + 1
*
*                 End do for each value of NRHS in NSVAL.
*
  130             CONTINUE
  140             CONTINUE
  150          CONTINUE
  160       CONTINUE
  170    CONTINUE
  180 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', NB =', i4, ', type ',
     $      i2, ', test ', i2, ', ratio =', g12.5 )
 9998 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', NRHS=', i3, ', type ',
     $      i2, ', test(', i2, ') =', g12.5 )
 9995 FORMAT( ' Invalid input value: ', a4, '=', i6, '; must be <=',
     $      i6 )
      RETURN
*
*     End of CCHKHE_AA_2STAGE
*

Here is the call graph for this function:

Here is the caller graph for this function: