cgelsd()

subroutine cgelsd	(	integer	m,
		integer	n,
		integer	nrhs,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( ldb, * )	b,
		integer	ldb,
		real, dimension( * )	s,
		real	rcond,
		integer	rank,
		complex, dimension( * )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		integer, dimension( * )	iwork,
		integer	info )

CGELSD computes the minimum-norm solution to a linear least squares problem for GE matrices

Download CGELSD + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CGELSD computes the minimum-norm solution to a real linear least
!> squares problem:
!>     minimize 2-norm(| b - A*x |)
!> using the singular value decomposition (SVD) of A. A is an M-by-N
!> matrix which may be rank-deficient.
!>
!> Several right hand side vectors b and solution vectors x can be
!> handled in a single call; they are stored as the columns of the
!> M-by-NRHS right hand side matrix B and the N-by-NRHS solution
!> matrix X.
!>
!> The problem is solved in three steps:
!> (1) Reduce the coefficient matrix A to bidiagonal form with
!>     Householder transformations, reducing the original problem
!>     into a  (BLS)
!> (2) Solve the BLS using a divide and conquer approach.
!> (3) Apply back all the Householder transformations to solve
!>     the original least squares problem.
!>
!> The effective rank of A is determined by treating as zero those
!> singular values which are less than RCOND times the largest singular
!> value.
!>
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrices B and X. NRHS >= 0. !>
[in,out]	A	!> A is COMPLEX array, dimension (LDA,N) !> On entry, the M-by-N matrix A. !> On exit, A has been destroyed. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,M). !>
[in,out]	B	!> B is COMPLEX array, dimension (LDB,NRHS) !> On entry, the M-by-NRHS right hand side matrix B. !> On exit, B is overwritten by the N-by-NRHS solution matrix X. !> If m >= n and RANK = n, the residual sum-of-squares for !> the solution in the i-th column is given by the sum of !> squares of the modulus of elements n+1:m in that column. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,M,N). !>
[out]	S	!> S is REAL array, dimension (min(M,N)) !> The singular values of A in decreasing order. !> The condition number of A in the 2-norm = S(1)/S(min(m,n)). !>
[in]	RCOND	!> RCOND is REAL !> RCOND is used to determine the effective rank of A. !> Singular values S(i) <= RCOND*S(1) are treated as zero. !> If RCOND < 0, machine precision is used instead. !>
[out]	RANK	!> RANK is INTEGER !> The effective rank of A, i.e., the number of singular values !> which are greater than RCOND*S(1). !>
[out]	WORK	!> WORK is COMPLEX array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. LWORK must be at least 1. !> The exact minimum amount of workspace needed depends on M, !> N and NRHS. As long as LWORK is at least !> 2 * N + N * NRHS !> if M is greater than or equal to N or !> 2 * M + M * NRHS !> if M is less than N, the code will execute correctly. !> For good performance, LWORK should generally be larger. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the array WORK and the !> minimum sizes of the arrays RWORK and IWORK, and returns !> these values as the first entries of the WORK, RWORK and !> IWORK arrays, and no error message related to LWORK is issued !> by XERBLA. !>
[out]	RWORK	!> RWORK is REAL array, dimension (MAX(1,LRWORK)) !> LRWORK >= !> 10*N + 2*N*SMLSIZ + 8*N*NLVL + 3*SMLSIZ*NRHS + !> MAX( (SMLSIZ+1)**2, N*(1+NRHS) + 2*NRHS ) !> if M is greater than or equal to N or !> 10*M + 2*M*SMLSIZ + 8*M*NLVL + 3*SMLSIZ*NRHS + !> MAX( (SMLSIZ+1)**2, N*(1+NRHS) + 2*NRHS ) !> if M is less than N, the code will execute correctly. !> SMLSIZ is returned by ILAENV and is equal to the maximum !> size of the subproblems at the bottom of the computation !> tree (usually about 25), and !> NLVL = MAX( 0, INT( LOG_2( MIN( M,N )/(SMLSIZ+1) ) ) + 1 ) !> On exit, if INFO = 0, RWORK(1) returns the minimum LRWORK. !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (MAX(1,LIWORK)) !> LIWORK >= max(1, 3*MINMN*NLVL + 11*MINMN), !> where MINMN = MIN( M,N ). !> On exit, if INFO = 0, IWORK(1) returns the minimum LIWORK. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value. !> > 0: the algorithm for computing the SVD failed to converge; !> if INFO = i, i off-diagonal elements of an intermediate !> bidiagonal form did not converge to zero. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

Ming Gu and Ren-Cang Li, Computer Science Division, University of California at Berkeley, USA
Osni Marques, LBNL/NERSC, USA

Definition at line 215 of file cgelsd.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS, RANK
      REAL               RCOND
*     ..
*     .. Array Arguments ..
      INTEGER            IWORK( * )
      REAL               RWORK( * ), S( * )
      COMPLEX            A( LDA, * ), B( LDB, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE, TWO
      parameter( zero = 0.0e+0, one = 1.0e+0, two = 2.0e+0 )
      COMPLEX            CZERO
      parameter( czero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            IASCL, IBSCL, IE, IL, ITAU, ITAUP, ITAUQ,
     $                   LDWORK, LIWORK, LRWORK, MAXMN, MAXWRK, MINMN,
     $                   MINWRK, MM, MNTHR, NLVL, NRWORK, NWORK, SMLSIZ
      REAL               ANRM, BIGNUM, BNRM, EPS, SFMIN, SMLNUM
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgebrd, cgelqf, cgeqrf, clacpy,
     $                   clalsd, clascl, claset, cunmbr,
     $                   cunmlq, cunmqr, slascl,
     $                   slaset, xerbla
*     ..
*     .. External Functions ..
      INTEGER            ILAENV
      REAL               CLANGE, SLAMCH, SROUNDUP_LWORK
      EXTERNAL           clange, slamch, ilaenv,
     $                   sroundup_lwork
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          int, log, max, min, real
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments.
*
      info = 0
      minmn = min( m, n )
      maxmn = max( m, n )
      lquery = ( lwork.EQ.-1 )
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, maxmn ) ) THEN
         info = -7
      END IF
*
*     Compute workspace.
*     (Note: Comments in the code beginning "Workspace:" describe the
*     minimal amount of workspace needed at that point in the code,
*     as well as the preferred amount for good performance.
*     NB refers to the optimal block size for the immediately
*     following subroutine, as returned by ILAENV.)
*
      IF( info.EQ.0 ) THEN
         minwrk = 1
         maxwrk = 1
         liwork = 1
         lrwork = 1
         IF( minmn.GT.0 ) THEN
            smlsiz = ilaenv( 9, 'CGELSD', ' ', 0, 0, 0, 0 )
            mnthr = ilaenv( 6, 'CGELSD', ' ', m, n, nrhs, -1 )
            nlvl = max( int( log( real( minmn ) / real( smlsiz + 1 ) ) /
     $                  log( two ) ) + 1, 0 )
            liwork = 3*minmn*nlvl + 11*minmn
            mm = m
            IF( m.GE.n .AND. m.GE.mnthr ) THEN
*
*              Path 1a - overdetermined, with many more rows than
*                        columns.
*
               mm = n
               maxwrk = max( maxwrk, n*ilaenv( 1, 'CGEQRF', ' ', m,
     $                       n,
     $                       -1, -1 ) )
               maxwrk = max( maxwrk, nrhs*ilaenv( 1, 'CUNMQR', 'LC',
     $                       m,
     $                       nrhs, n, -1 ) )
            END IF
            IF( m.GE.n ) THEN
*
*              Path 1 - overdetermined or exactly determined.
*
               lrwork = 10*n + 2*n*smlsiz + 8*n*nlvl + 3*smlsiz*nrhs +
     $                  max( (smlsiz+1)**2, n*(1+nrhs) + 2*nrhs )
               maxwrk = max( maxwrk, 2*n + ( mm + n )*ilaenv( 1,
     $                       'CGEBRD', ' ', mm, n, -1, -1 ) )
               maxwrk = max( maxwrk, 2*n + nrhs*ilaenv( 1, 'CUNMBR',
     $                       'QLC', mm, nrhs, n, -1 ) )
               maxwrk = max( maxwrk, 2*n + ( n - 1 )*ilaenv( 1,
     $                       'CUNMBR', 'PLN', n, nrhs, n, -1 ) )
               maxwrk = max( maxwrk, 2*n + n*nrhs )
               minwrk = max( 2*n + mm, 2*n + n*nrhs )
            END IF
            IF( n.GT.m ) THEN
               lrwork = 10*m + 2*m*smlsiz + 8*m*nlvl + 3*smlsiz*nrhs +
     $                  max( (smlsiz+1)**2, n*(1+nrhs) + 2*nrhs )
               IF( n.GE.mnthr ) THEN
*
*                 Path 2a - underdetermined, with many more columns
*                           than rows.
*
                  maxwrk = m + m*ilaenv( 1, 'CGELQF', ' ', m, n, -1,
     $                     -1 )
                  maxwrk = max( maxwrk, m*m + 4*m + 2*m*ilaenv( 1,
     $                          'CGEBRD', ' ', m, m, -1, -1 ) )
                  maxwrk = max( maxwrk, m*m + 4*m + nrhs*ilaenv( 1,
     $                          'CUNMBR', 'QLC', m, nrhs, m, -1 ) )
                  maxwrk = max( maxwrk,
     $                          m*m + 4*m + ( m - 1 )*ilaenv( 1,
     $                          'CUNMLQ', 'LC', n, nrhs, m, -1 ) )
                  IF( nrhs.GT.1 ) THEN
                     maxwrk = max( maxwrk, m*m + m + m*nrhs )
                  ELSE
                     maxwrk = max( maxwrk, m*m + 2*m )
                  END IF
                  maxwrk = max( maxwrk, m*m + 4*m + m*nrhs )
!     XXX: Ensure the Path 2a case below is triggered.  The workspace
!     calculation should use queries for all routines eventually.
                  maxwrk = max( maxwrk,
     $                 4*m+m*m+max( m, 2*m-4, nrhs, n-3*m ) )
               ELSE
*
*                 Path 2 - underdetermined.
*
                  maxwrk = 2*m + ( n + m )*ilaenv( 1, 'CGEBRD', ' ',
     $                             m,
     $                     n, -1, -1 )
                  maxwrk = max( maxwrk, 2*m + nrhs*ilaenv( 1,
     $                          'CUNMBR',
     $                          'QLC', m, nrhs, m, -1 ) )
                  maxwrk = max( maxwrk, 2*m + m*ilaenv( 1, 'CUNMBR',
     $                          'PLN', n, nrhs, m, -1 ) )
                  maxwrk = max( maxwrk, 2*m + m*nrhs )
               END IF
               minwrk = max( 2*m + n, 2*m + m*nrhs )
            END IF
         END IF
         minwrk = min( minwrk, maxwrk )
         work( 1 ) = sroundup_lwork(maxwrk)
         iwork( 1 ) = liwork
         rwork( 1 ) = real( lrwork )
*
         IF( lwork.LT.minwrk .AND. .NOT.lquery ) THEN
            info = -12
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CGELSD', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible.
*
      IF( m.EQ.0 .OR. n.EQ.0 ) THEN
         rank = 0
         RETURN
      END IF
*
*     Get machine parameters.
*
      eps = slamch( 'P' )
      sfmin = slamch( 'S' )
      smlnum = sfmin / eps
      bignum = one / smlnum
*
*     Scale A if max entry outside range [SMLNUM,BIGNUM].
*
      anrm = clange( 'M', m, n, a, lda, rwork )
      iascl = 0
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL clascl( 'G', 0, 0, anrm, smlnum, m, n, a, lda, info )
         iascl = 1
      ELSE IF( anrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM.
*
         CALL clascl( 'G', 0, 0, anrm, bignum, m, n, a, lda, info )
         iascl = 2
      ELSE IF( anrm.EQ.zero ) THEN
*
*        Matrix all zero. Return zero solution.
*
         CALL claset( 'F', max( m, n ), nrhs, czero, czero, b, ldb )
         CALL slaset( 'F', minmn, 1, zero, zero, s, 1 )
         rank = 0
         GO TO 10
      END IF
*
*     Scale B if max entry outside range [SMLNUM,BIGNUM].
*
      bnrm = clange( 'M', m, nrhs, b, ldb, rwork )
      ibscl = 0
      IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM.
*
         CALL clascl( 'G', 0, 0, bnrm, smlnum, m, nrhs, b, ldb,
     $                info )
         ibscl = 1
      ELSE IF( bnrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM.
*
         CALL clascl( 'G', 0, 0, bnrm, bignum, m, nrhs, b, ldb,
     $                info )
         ibscl = 2
      END IF
*
*     If M < N make sure B(M+1:N,:) = 0
*
      IF( m.LT.n )
     $   CALL claset( 'F', n-m, nrhs, czero, czero, b( m+1, 1 ),
     $                ldb )
*
*     Overdetermined case.
*
      IF( m.GE.n ) THEN
*
*        Path 1 - overdetermined or exactly determined.
*
         mm = m
         IF( m.GE.mnthr ) THEN
*
*           Path 1a - overdetermined, with many more rows than columns
*
            mm = n
            itau = 1
            nwork = itau + n
*
*           Compute A=Q*R.
*           (RWorkspace: need N)
*           (CWorkspace: need N, prefer N*NB)
*
            CALL cgeqrf( m, n, a, lda, work( itau ), work( nwork ),
     $                   lwork-nwork+1, info )
*
*           Multiply B by transpose(Q).
*           (RWorkspace: need N)
*           (CWorkspace: need NRHS, prefer NRHS*NB)
*
            CALL cunmqr( 'L', 'C', m, nrhs, n, a, lda, work( itau ),
     $                   b,
     $                   ldb, work( nwork ), lwork-nwork+1, info )
*
*           Zero out below R.
*
            IF( n.GT.1 ) THEN
               CALL claset( 'L', n-1, n-1, czero, czero, a( 2, 1 ),
     $                      lda )
            END IF
         END IF
*
         itauq = 1
         itaup = itauq + n
         nwork = itaup + n
         ie = 1
         nrwork = ie + n
*
*        Bidiagonalize R in A.
*        (RWorkspace: need N)
*        (CWorkspace: need 2*N+MM, prefer 2*N+(MM+N)*NB)
*
         CALL cgebrd( mm, n, a, lda, s, rwork( ie ), work( itauq ),
     $                work( itaup ), work( nwork ), lwork-nwork+1,
     $                info )
*
*        Multiply B by transpose of left bidiagonalizing vectors of R.
*        (CWorkspace: need 2*N+NRHS, prefer 2*N+NRHS*NB)
*
         CALL cunmbr( 'Q', 'L', 'C', mm, nrhs, n, a, lda,
     $                work( itauq ),
     $                b, ldb, work( nwork ), lwork-nwork+1, info )
*
*        Solve the bidiagonal least squares problem.
*
         CALL clalsd( 'U', smlsiz, n, nrhs, s, rwork( ie ), b, ldb,
     $                rcond, rank, work( nwork ), rwork( nrwork ),
     $                iwork, info )
         IF( info.NE.0 ) THEN
            GO TO 10
         END IF
*
*        Multiply B by right bidiagonalizing vectors of R.
*
         CALL cunmbr( 'P', 'L', 'N', n, nrhs, n, a, lda,
     $                work( itaup ),
     $                b, ldb, work( nwork ), lwork-nwork+1, info )
*
      ELSE IF( n.GE.mnthr .AND. lwork.GE.4*m+m*m+
     $         max( m, 2*m-4, nrhs, n-3*m ) ) THEN
*
*        Path 2a - underdetermined, with many more columns than rows
*        and sufficient workspace for an efficient algorithm.
*
         ldwork = m
         IF( lwork.GE.max( 4*m+m*lda+max( m, 2*m-4, nrhs, n-3*m ),
     $       m*lda+m+m*nrhs ) )ldwork = lda
         itau = 1
         nwork = m + 1
*
*        Compute A=L*Q.
*        (CWorkspace: need 2*M, prefer M+M*NB)
*
         CALL cgelqf( m, n, a, lda, work( itau ), work( nwork ),
     $                lwork-nwork+1, info )
         il = nwork
*
*        Copy L to WORK(IL), zeroing out above its diagonal.
*
         CALL clacpy( 'L', m, m, a, lda, work( il ), ldwork )
         CALL claset( 'U', m-1, m-1, czero, czero, work( il+ldwork ),
     $                ldwork )
         itauq = il + ldwork*m
         itaup = itauq + m
         nwork = itaup + m
         ie = 1
         nrwork = ie + m
*
*        Bidiagonalize L in WORK(IL).
*        (RWorkspace: need M)
*        (CWorkspace: need M*M+4*M, prefer M*M+4*M+2*M*NB)
*
         CALL cgebrd( m, m, work( il ), ldwork, s, rwork( ie ),
     $                work( itauq ), work( itaup ), work( nwork ),
     $                lwork-nwork+1, info )
*
*        Multiply B by transpose of left bidiagonalizing vectors of L.
*        (CWorkspace: need M*M+4*M+NRHS, prefer M*M+4*M+NRHS*NB)
*
         CALL cunmbr( 'Q', 'L', 'C', m, nrhs, m, work( il ), ldwork,
     $                work( itauq ), b, ldb, work( nwork ),
     $                lwork-nwork+1, info )
*
*        Solve the bidiagonal least squares problem.
*
         CALL clalsd( 'U', smlsiz, m, nrhs, s, rwork( ie ), b, ldb,
     $                rcond, rank, work( nwork ), rwork( nrwork ),
     $                iwork, info )
         IF( info.NE.0 ) THEN
            GO TO 10
         END IF
*
*        Multiply B by right bidiagonalizing vectors of L.
*
         CALL cunmbr( 'P', 'L', 'N', m, nrhs, m, work( il ), ldwork,
     $                work( itaup ), b, ldb, work( nwork ),
     $                lwork-nwork+1, info )
*
*        Zero out below first M rows of B.
*
         CALL claset( 'F', n-m, nrhs, czero, czero, b( m+1, 1 ),
     $                ldb )
         nwork = itau + m
*
*        Multiply transpose(Q) by B.
*        (CWorkspace: need NRHS, prefer NRHS*NB)
*
         CALL cunmlq( 'L', 'C', n, nrhs, m, a, lda, work( itau ), b,
     $                ldb, work( nwork ), lwork-nwork+1, info )
*
      ELSE
*
*        Path 2 - remaining underdetermined cases.
*
         itauq = 1
         itaup = itauq + m
         nwork = itaup + m
         ie = 1
         nrwork = ie + m
*
*        Bidiagonalize A.
*        (RWorkspace: need M)
*        (CWorkspace: need 2*M+N, prefer 2*M+(M+N)*NB)
*
         CALL cgebrd( m, n, a, lda, s, rwork( ie ), work( itauq ),
     $                work( itaup ), work( nwork ), lwork-nwork+1,
     $                info )
*
*        Multiply B by transpose of left bidiagonalizing vectors.
*        (CWorkspace: need 2*M+NRHS, prefer 2*M+NRHS*NB)
*
         CALL cunmbr( 'Q', 'L', 'C', m, nrhs, n, a, lda,
     $                work( itauq ),
     $                b, ldb, work( nwork ), lwork-nwork+1, info )
*
*        Solve the bidiagonal least squares problem.
*
         CALL clalsd( 'L', smlsiz, m, nrhs, s, rwork( ie ), b, ldb,
     $                rcond, rank, work( nwork ), rwork( nrwork ),
     $                iwork, info )
         IF( info.NE.0 ) THEN
            GO TO 10
         END IF
*
*        Multiply B by right bidiagonalizing vectors of A.
*
         CALL cunmbr( 'P', 'L', 'N', n, nrhs, m, a, lda,
     $                work( itaup ),
     $                b, ldb, work( nwork ), lwork-nwork+1, info )
*
      END IF
*
*     Undo scaling.
*
      IF( iascl.EQ.1 ) THEN
         CALL clascl( 'G', 0, 0, anrm, smlnum, n, nrhs, b, ldb,
     $                info )
         CALL slascl( 'G', 0, 0, smlnum, anrm, minmn, 1, s, minmn,
     $                info )
      ELSE IF( iascl.EQ.2 ) THEN
         CALL clascl( 'G', 0, 0, anrm, bignum, n, nrhs, b, ldb,
     $                info )
         CALL slascl( 'G', 0, 0, bignum, anrm, minmn, 1, s, minmn,
     $                info )
      END IF
      IF( ibscl.EQ.1 ) THEN
         CALL clascl( 'G', 0, 0, smlnum, bnrm, n, nrhs, b, ldb,
     $                info )
      ELSE IF( ibscl.EQ.2 ) THEN
         CALL clascl( 'G', 0, 0, bignum, bnrm, n, nrhs, b, ldb,
     $                info )
      END IF
*
   10 CONTINUE
      work( 1 ) = sroundup_lwork(maxwrk)
      iwork( 1 ) = liwork
      rwork( 1 ) = real( lrwork )
      RETURN
*
*     End of CGELSD
*

Here is the call graph for this function:

Here is the caller graph for this function: