LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches

## ◆ dspgvx()

 subroutine dspgvx ( integer itype, character jobz, character range, character uplo, integer n, double precision, dimension( * ) ap, double precision, dimension( * ) bp, double precision vl, double precision vu, integer il, integer iu, double precision abstol, integer m, double precision, dimension( * ) w, double precision, dimension( ldz, * ) z, integer ldz, double precision, dimension( * ) work, integer, dimension( * ) iwork, integer, dimension( * ) ifail, integer info )

DSPGVX

Purpose:
``` DSPGVX computes selected eigenvalues, and optionally, eigenvectors
of a real generalized symmetric-definite eigenproblem, of the form
A*x=(lambda)*B*x,  A*Bx=(lambda)*x,  or B*A*x=(lambda)*x.  Here A
and B are assumed to be symmetric, stored in packed storage, and B
is also positive definite.  Eigenvalues and eigenvectors can be
selected by specifying either a range of values or a range of indices
for the desired eigenvalues.```
Parameters
 [in] ITYPE ``` ITYPE is INTEGER Specifies the problem type to be solved: = 1: A*x = (lambda)*B*x = 2: A*B*x = (lambda)*x = 3: B*A*x = (lambda)*x``` [in] JOBZ ``` JOBZ is CHARACTER*1 = 'N': Compute eigenvalues only; = 'V': Compute eigenvalues and eigenvectors.``` [in] RANGE ``` RANGE is CHARACTER*1 = 'A': all eigenvalues will be found. = 'V': all eigenvalues in the half-open interval (VL,VU] will be found. = 'I': the IL-th through IU-th eigenvalues will be found.``` [in] UPLO ``` UPLO is CHARACTER*1 = 'U': Upper triangle of A and B are stored; = 'L': Lower triangle of A and B are stored.``` [in] N ``` N is INTEGER The order of the matrix pencil (A,B). N >= 0.``` [in,out] AP ``` AP is DOUBLE PRECISION array, dimension (N*(N+1)/2) On entry, the upper or lower triangle of the symmetric matrix A, packed columnwise in a linear array. The j-th column of A is stored in the array AP as follows: if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j; if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n. On exit, the contents of AP are destroyed.``` [in,out] BP ``` BP is DOUBLE PRECISION array, dimension (N*(N+1)/2) On entry, the upper or lower triangle of the symmetric matrix B, packed columnwise in a linear array. The j-th column of B is stored in the array BP as follows: if UPLO = 'U', BP(i + (j-1)*j/2) = B(i,j) for 1<=i<=j; if UPLO = 'L', BP(i + (j-1)*(2*n-j)/2) = B(i,j) for j<=i<=n. On exit, the triangular factor U or L from the Cholesky factorization B = U**T*U or B = L*L**T, in the same storage format as B.``` [in] VL ``` VL is DOUBLE PRECISION If RANGE='V', the lower bound of the interval to be searched for eigenvalues. VL < VU. Not referenced if RANGE = 'A' or 'I'.``` [in] VU ``` VU is DOUBLE PRECISION If RANGE='V', the upper bound of the interval to be searched for eigenvalues. VL < VU. Not referenced if RANGE = 'A' or 'I'.``` [in] IL ``` IL is INTEGER If RANGE='I', the index of the smallest eigenvalue to be returned. 1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0. Not referenced if RANGE = 'A' or 'V'.``` [in] IU ``` IU is INTEGER If RANGE='I', the index of the largest eigenvalue to be returned. 1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0. Not referenced if RANGE = 'A' or 'V'.``` [in] ABSTOL ``` ABSTOL is DOUBLE PRECISION The absolute error tolerance for the eigenvalues. An approximate eigenvalue is accepted as converged when it is determined to lie in an interval [a,b] of width less than or equal to ABSTOL + EPS * max( |a|,|b| ) , where EPS is the machine precision. If ABSTOL is less than or equal to zero, then EPS*|T| will be used in its place, where |T| is the 1-norm of the tridiagonal matrix obtained by reducing A to tridiagonal form. Eigenvalues will be computed most accurately when ABSTOL is set to twice the underflow threshold 2*DLAMCH('S'), not zero. If this routine returns with INFO>0, indicating that some eigenvectors did not converge, try setting ABSTOL to 2*DLAMCH('S').``` [out] M ``` M is INTEGER The total number of eigenvalues found. 0 <= M <= N. If RANGE = 'A', M = N, and if RANGE = 'I', M = IU-IL+1.``` [out] W ``` W is DOUBLE PRECISION array, dimension (N) On normal exit, the first M elements contain the selected eigenvalues in ascending order.``` [out] Z ``` Z is DOUBLE PRECISION array, dimension (LDZ, max(1,M)) If JOBZ = 'N', then Z is not referenced. If JOBZ = 'V', then if INFO = 0, the first M columns of Z contain the orthonormal eigenvectors of the matrix A corresponding to the selected eigenvalues, with the i-th column of Z holding the eigenvector associated with W(i). The eigenvectors are normalized as follows: if ITYPE = 1 or 2, Z**T*B*Z = I; if ITYPE = 3, Z**T*inv(B)*Z = I. If an eigenvector fails to converge, then that column of Z contains the latest approximation to the eigenvector, and the index of the eigenvector is returned in IFAIL. Note: the user must ensure that at least max(1,M) columns are supplied in the array Z; if RANGE = 'V', the exact value of M is not known in advance and an upper bound must be used.``` [in] LDZ ``` LDZ is INTEGER The leading dimension of the array Z. LDZ >= 1, and if JOBZ = 'V', LDZ >= max(1,N).``` [out] WORK ` WORK is DOUBLE PRECISION array, dimension (8*N)` [out] IWORK ` IWORK is INTEGER array, dimension (5*N)` [out] IFAIL ``` IFAIL is INTEGER array, dimension (N) If JOBZ = 'V', then if INFO = 0, the first M elements of IFAIL are zero. If INFO > 0, then IFAIL contains the indices of the eigenvectors that failed to converge. If JOBZ = 'N', then IFAIL is not referenced.``` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: DPPTRF or DSPEVX returned an error code: <= N: if INFO = i, DSPEVX failed to converge; i eigenvectors failed to converge. Their indices are stored in array IFAIL. > N: if INFO = N + i, for 1 <= i <= N, then the leading principal minor of order i of B is not positive. The factorization of B could not be completed and no eigenvalues or eigenvectors were computed.```
Contributors:
Mark Fahey, Department of Mathematics, Univ. of Kentucky, USA

Definition at line 269 of file dspgvx.f.

272*
273* -- LAPACK driver routine --
274* -- LAPACK is a software package provided by Univ. of Tennessee, --
275* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
276*
277* .. Scalar Arguments ..
278 CHARACTER JOBZ, RANGE, UPLO
279 INTEGER IL, INFO, ITYPE, IU, LDZ, M, N
280 DOUBLE PRECISION ABSTOL, VL, VU
281* ..
282* .. Array Arguments ..
283 INTEGER IFAIL( * ), IWORK( * )
284 DOUBLE PRECISION AP( * ), BP( * ), W( * ), WORK( * ),
285 \$ Z( LDZ, * )
286* ..
287*
288* =====================================================================
289*
290* .. Local Scalars ..
291 LOGICAL ALLEIG, INDEIG, UPPER, VALEIG, WANTZ
292 CHARACTER TRANS
293 INTEGER J
294* ..
295* .. External Functions ..
296 LOGICAL LSAME
297 EXTERNAL lsame
298* ..
299* .. External Subroutines ..
300 EXTERNAL dpptrf, dspevx, dspgst, dtpmv, dtpsv, xerbla
301* ..
302* .. Intrinsic Functions ..
303 INTRINSIC min
304* ..
305* .. Executable Statements ..
306*
307* Test the input parameters.
308*
309 upper = lsame( uplo, 'U' )
310 wantz = lsame( jobz, 'V' )
311 alleig = lsame( range, 'A' )
312 valeig = lsame( range, 'V' )
313 indeig = lsame( range, 'I' )
314*
315 info = 0
316 IF( itype.LT.1 .OR. itype.GT.3 ) THEN
317 info = -1
318 ELSE IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
319 info = -2
320 ELSE IF( .NOT.( alleig .OR. valeig .OR. indeig ) ) THEN
321 info = -3
322 ELSE IF( .NOT.( upper .OR. lsame( uplo, 'L' ) ) ) THEN
323 info = -4
324 ELSE IF( n.LT.0 ) THEN
325 info = -5
326 ELSE
327 IF( valeig ) THEN
328 IF( n.GT.0 .AND. vu.LE.vl ) THEN
329 info = -9
330 END IF
331 ELSE IF( indeig ) THEN
332 IF( il.LT.1 ) THEN
333 info = -10
334 ELSE IF( iu.LT.min( n, il ) .OR. iu.GT.n ) THEN
335 info = -11
336 END IF
337 END IF
338 END IF
339 IF( info.EQ.0 ) THEN
340 IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
341 info = -16
342 END IF
343 END IF
344*
345 IF( info.NE.0 ) THEN
346 CALL xerbla( 'DSPGVX', -info )
347 RETURN
348 END IF
349*
350* Quick return if possible
351*
352 m = 0
353 IF( n.EQ.0 )
354 \$ RETURN
355*
356* Form a Cholesky factorization of B.
357*
358 CALL dpptrf( uplo, n, bp, info )
359 IF( info.NE.0 ) THEN
360 info = n + info
361 RETURN
362 END IF
363*
364* Transform problem to standard eigenvalue problem and solve.
365*
366 CALL dspgst( itype, uplo, n, ap, bp, info )
367 CALL dspevx( jobz, range, uplo, n, ap, vl, vu, il, iu, abstol, m,
368 \$ w, z, ldz, work, iwork, ifail, info )
369*
370 IF( wantz ) THEN
371*
372* Backtransform eigenvectors to the original problem.
373*
374 IF( info.GT.0 )
375 \$ m = info - 1
376 IF( itype.EQ.1 .OR. itype.EQ.2 ) THEN
377*
378* For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
379* backtransform eigenvectors: x = inv(L)**T*y or inv(U)*y
380*
381 IF( upper ) THEN
382 trans = 'N'
383 ELSE
384 trans = 'T'
385 END IF
386*
387 DO 10 j = 1, m
388 CALL dtpsv( uplo, trans, 'Non-unit', n, bp, z( 1, j ),
389 \$ 1 )
390 10 CONTINUE
391*
392 ELSE IF( itype.EQ.3 ) THEN
393*
394* For B*A*x=(lambda)*x;
395* backtransform eigenvectors: x = L*y or U**T*y
396*
397 IF( upper ) THEN
398 trans = 'T'
399 ELSE
400 trans = 'N'
401 END IF
402*
403 DO 20 j = 1, m
404 CALL dtpmv( uplo, trans, 'Non-unit', n, bp, z( 1, j ),
405 \$ 1 )
406 20 CONTINUE
407 END IF
408 END IF
409*
410 RETURN
411*
412* End of DSPGVX
413*
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine dspevx(jobz, range, uplo, n, ap, vl, vu, il, iu, abstol, m, w, z, ldz, work, iwork, ifail, info)
DSPEVX computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrice...
Definition dspevx.f:234
subroutine dspgst(itype, uplo, n, ap, bp, info)
DSPGST
Definition dspgst.f:113
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
subroutine dpptrf(uplo, n, ap, info)
DPPTRF
Definition dpptrf.f:119
subroutine dtpmv(uplo, trans, diag, n, ap, x, incx)
DTPMV
Definition dtpmv.f:142
subroutine dtpsv(uplo, trans, diag, n, ap, x, incx)
DTPSV
Definition dtpsv.f:144
Here is the call graph for this function:
Here is the caller graph for this function: