dpptrf()

subroutine dpptrf	(	character	uplo,
		integer	n,
		double precision, dimension( * )	ap,
		integer	info
	)

DPPTRF

Download DPPTRF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DPPTRF computes the Cholesky factorization of a real symmetric
 positive definite matrix A stored in packed format.

 The factorization has the form
    A = U**T * U,  if UPLO = 'U', or
    A = L  * L**T,  if UPLO = 'L',
 where U is an upper triangular matrix and L is lower triangular.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	AP	AP is DOUBLE PRECISION array, dimension (N*(N+1)/2) On entry, the upper or lower triangle of the symmetric matrix A, packed columnwise in a linear array. The j-th column of A is stored in the array AP as follows: if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j; if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n. See below for further details. On exit, if INFO = 0, the triangular factor U or L from the Cholesky factorization A = U**T*U or A = L*L**T, in the same storage format as A.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, the leading principal minor of order i is not positive, and the factorization could not be completed.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

  The packed storage scheme is illustrated by the following example
  when N = 4, UPLO = 'U':

  Two-dimensional storage of the symmetric matrix A:

     a11 a12 a13 a14
         a22 a23 a24
             a33 a34     (aij = aji)
                 a44

  Packed storage of the upper triangle of A:

  AP = [ a11, a12, a22, a13, a23, a33, a14, a24, a34, a44 ]

Definition at line 118 of file dpptrf.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   AP( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            J, JC, JJ
      DOUBLE PRECISION   AJJ
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DDOT
      EXTERNAL           lsame, ddot
*     ..
*     .. External Subroutines ..
      EXTERNAL           dscal, dspr, dtpsv, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DPPTRF', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Compute the Cholesky factorization A = U**T*U.
*
         jj = 0
         DO 10 j = 1, n
            jc = jj + 1
            jj = jj + j
*
*           Compute elements 1:J-1 of column J.
*
            IF( j.GT.1 )
     $         CALL dtpsv( 'Upper', 'Transpose', 'Non-unit', j-1, ap,
     $                     ap( jc ), 1 )
*
*           Compute U(J,J) and test for non-positive-definiteness.
*
            ajj = ap( jj ) - ddot( j-1, ap( jc ), 1, ap( jc ), 1 )
            IF( ajj.LE.zero ) THEN
               ap( jj ) = ajj
               GO TO 30
            END IF
            ap( jj ) = sqrt( ajj )
   10    CONTINUE
      ELSE
*
*        Compute the Cholesky factorization A = L*L**T.
*
         jj = 1
         DO 20 j = 1, n
*
*           Compute L(J,J) and test for non-positive-definiteness.
*
            ajj = ap( jj )
            IF( ajj.LE.zero ) THEN
               ap( jj ) = ajj
               GO TO 30
            END IF
            ajj = sqrt( ajj )
            ap( jj ) = ajj
*
*           Compute elements J+1:N of column J and update the trailing
*           submatrix.
*
            IF( j.LT.n ) THEN
               CALL dscal( n-j, one / ajj, ap( jj+1 ), 1 )
               CALL dspr( 'Lower', n-j, -one, ap( jj+1 ), 1,
     $                    ap( jj+n-j+1 ) )
               jj = jj + n - j + 1
            END IF
   20    CONTINUE
      END IF
      GO TO 40
*
   30 CONTINUE
      info = j
*
   40 CONTINUE
      RETURN
*
*     End of DPPTRF
*

Here is the call graph for this function:

Here is the caller graph for this function: