dtpsv.f

Go to the documentation of this file.

*> \brief \b DTPSV
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE DTPSV(UPLO,TRANS,DIAG,N,AP,X,INCX)
*
*       .. Scalar Arguments ..
*       INTEGER INCX,N
*       CHARACTER DIAG,TRANS,UPLO
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION AP(*),X(*)
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DTPSV  solves one of the systems of equations
*>
*>    A*x = b,   or   A**T*x = b,
*>
*> where b and x are n element vectors and A is an n by n unit, or
*> non-unit, upper or lower triangular matrix, supplied in packed form.
*>
*> No test for singularity or near-singularity is included in this
*> routine. Such tests must be performed before calling this routine.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>           On entry, UPLO specifies whether the matrix is an upper or
*>           lower triangular matrix as follows:
*>
*>              UPLO = 'U' or 'u'   A is an upper triangular matrix.
*>
*>              UPLO = 'L' or 'l'   A is a lower triangular matrix.
*> \endverbatim
*>
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER*1
*>           On entry, TRANS specifies the equations to be solved as
*>           follows:
*>
*>              TRANS = 'N' or 'n'   A*x = b.
*>
*>              TRANS = 'T' or 't'   A**T*x = b.
*>
*>              TRANS = 'C' or 'c'   A**T*x = b.
*> \endverbatim
*>
*> \param[in] DIAG
*> \verbatim
*>          DIAG is CHARACTER*1
*>           On entry, DIAG specifies whether or not A is unit
*>           triangular as follows:
*>
*>              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
*>
*>              DIAG = 'N' or 'n'   A is not assumed to be unit
*>                                  triangular.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>           On entry, N specifies the order of the matrix A.
*>           N must be at least zero.
*> \endverbatim
*>
*> \param[in] AP
*> \verbatim
*>          AP is DOUBLE PRECISION array, dimension at least
*>           ( ( n*( n + 1 ) )/2 ).
*>           Before entry with  UPLO = 'U' or 'u', the array AP must
*>           contain the upper triangular matrix packed sequentially,
*>           column by column, so that AP( 1 ) contains a( 1, 1 ),
*>           AP( 2 ) and AP( 3 ) contain a( 1, 2 ) and a( 2, 2 )
*>           respectively, and so on.
*>           Before entry with UPLO = 'L' or 'l', the array AP must
*>           contain the lower triangular matrix packed sequentially,
*>           column by column, so that AP( 1 ) contains a( 1, 1 ),
*>           AP( 2 ) and AP( 3 ) contain a( 2, 1 ) and a( 3, 1 )
*>           respectively, and so on.
*>           Note that when  DIAG = 'U' or 'u', the diagonal elements of
*>           A are not referenced, but are assumed to be unity.
*> \endverbatim
*>
*> \param[in,out] X
*> \verbatim
*>          X is DOUBLE PRECISION array, dimension at least
*>           ( 1 + ( n - 1 )*abs( INCX ) ).
*>           Before entry, the incremented array X must contain the n
*>           element right-hand side vector b. On exit, X is overwritten
*>           with the solution vector x.
*> \endverbatim
*>
*> \param[in] INCX
*> \verbatim
*>          INCX is INTEGER
*>           On entry, INCX specifies the increment for the elements of
*>           X. INCX must not be zero.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup double_blas_level2
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  Level 2 Blas routine.
*>
*>  -- Written on 22-October-1986.
*>     Jack Dongarra, Argonne National Lab.
*>     Jeremy Du Croz, Nag Central Office.
*>     Sven Hammarling, Nag Central Office.
*>     Richard Hanson, Sandia National Labs.
*> \endverbatim
*>
*  =====================================================================
      SUBROUTINE dtpsv(UPLO,TRANS,DIAG,N,AP,X,INCX)
*
*  -- Reference BLAS level2 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER INCX,N
      CHARACTER DIAG,TRANS,UPLO
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION AP(*),X(*)
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION ZERO
      parameter(zero=0.0d+0)
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION TEMP
      INTEGER I,INFO,IX,J,JX,K,KK,KX
      LOGICAL NOUNIT
*     ..
*     .. External Functions ..
      LOGICAL LSAME
      EXTERNAL lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL xerbla
*     ..
*
*     Test the input parameters.
*
      info = 0
      IF (.NOT.lsame(uplo,'U') .AND. .NOT.lsame(uplo,'L')) THEN
          info = 1
      ELSE IF (.NOT.lsame(trans,'N') .AND. .NOT.lsame(trans,'T') .AND.
     +         .NOT.lsame(trans,'C')) THEN
          info = 2
      ELSE IF (.NOT.lsame(diag,'U') .AND. .NOT.lsame(diag,'N')) THEN
          info = 3
      ELSE IF (n.LT.0) THEN
          info = 4
      ELSE IF (incx.EQ.0) THEN
          info = 7
      END IF
      IF (info.NE.0) THEN
          CALL xerbla('DTPSV ',info)
          RETURN
      END IF
*
*     Quick return if possible.
*
      IF (n.EQ.0) RETURN
*
      nounit = lsame(diag,'N')
*
*     Set up the start point in X if the increment is not unity. This
*     will be  ( N - 1 )*INCX  too small for descending loops.
*
      IF (incx.LE.0) THEN
          kx = 1 - (n-1)*incx
      ELSE IF (incx.NE.1) THEN
          kx = 1
      END IF
*
*     Start the operations. In this version the elements of AP are
*     accessed sequentially with one pass through AP.
*
      IF (lsame(trans,'N')) THEN
*
*        Form  x := inv( A )*x.
*
          IF (lsame(uplo,'U')) THEN
              kk = (n* (n+1))/2
              IF (incx.EQ.1) THEN
                  DO 20 j = n,1,-1
                      IF (x(j).NE.zero) THEN
                          IF (nounit) x(j) = x(j)/ap(kk)
                          temp = x(j)
                          k = kk - 1
                          DO 10 i = j - 1,1,-1
                              x(i) = x(i) - temp*ap(k)
                              k = k - 1
   10                     CONTINUE
                      END IF
                      kk = kk - j
   20             CONTINUE
              ELSE
                  jx = kx + (n-1)*incx
                  DO 40 j = n,1,-1
                      IF (x(jx).NE.zero) THEN
                          IF (nounit) x(jx) = x(jx)/ap(kk)
                          temp = x(jx)
                          ix = jx
                          DO 30 k = kk - 1,kk - j + 1,-1
                              ix = ix - incx
                              x(ix) = x(ix) - temp*ap(k)
   30                     CONTINUE
                      END IF
                      jx = jx - incx
                      kk = kk - j
   40             CONTINUE
              END IF
          ELSE
              kk = 1
              IF (incx.EQ.1) THEN
                  DO 60 j = 1,n
                      IF (x(j).NE.zero) THEN
                          IF (nounit) x(j) = x(j)/ap(kk)
                          temp = x(j)
                          k = kk + 1
                          DO 50 i = j + 1,n
                              x(i) = x(i) - temp*ap(k)
                              k = k + 1
   50                     CONTINUE
                      END IF
                      kk = kk + (n-j+1)
   60             CONTINUE
              ELSE
                  jx = kx
                  DO 80 j = 1,n
                      IF (x(jx).NE.zero) THEN
                          IF (nounit) x(jx) = x(jx)/ap(kk)
                          temp = x(jx)
                          ix = jx
                          DO 70 k = kk + 1,kk + n - j
                              ix = ix + incx
                              x(ix) = x(ix) - temp*ap(k)
   70                     CONTINUE
                      END IF
                      jx = jx + incx
                      kk = kk + (n-j+1)
   80             CONTINUE
              END IF
          END IF
      ELSE
*
*        Form  x := inv( A**T )*x.
*
          IF (lsame(uplo,'U')) THEN
              kk = 1
              IF (incx.EQ.1) THEN
                  DO 100 j = 1,n
                      temp = x(j)
                      k = kk
                      DO 90 i = 1,j - 1
                          temp = temp - ap(k)*x(i)
                          k = k + 1
   90                 CONTINUE
                      IF (nounit) temp = temp/ap(kk+j-1)
                      x(j) = temp
                      kk = kk + j
  100             CONTINUE
              ELSE
                  jx = kx
                  DO 120 j = 1,n
                      temp = x(jx)
                      ix = kx
                      DO 110 k = kk,kk + j - 2
                          temp = temp - ap(k)*x(ix)
                          ix = ix + incx
  110                 CONTINUE
                      IF (nounit) temp = temp/ap(kk+j-1)
                      x(jx) = temp
                      jx = jx + incx
                      kk = kk + j
  120             CONTINUE
              END IF
          ELSE
              kk = (n* (n+1))/2
              IF (incx.EQ.1) THEN
                  DO 140 j = n,1,-1
                      temp = x(j)
                      k = kk
                      DO 130 i = n,j + 1,-1
                          temp = temp - ap(k)*x(i)
                          k = k - 1
  130                 CONTINUE
                      IF (nounit) temp = temp/ap(kk-n+j)
                      x(j) = temp
                      kk = kk - (n-j+1)
  140             CONTINUE
              ELSE
                  kx = kx + (n-1)*incx
                  jx = kx
                  DO 160 j = n,1,-1
                      temp = x(jx)
                      ix = kx
                      DO 150 k = kk,kk - (n- (j+1)),-1
                          temp = temp - ap(k)*x(ix)
                          ix = ix - incx
  150                 CONTINUE
                      IF (nounit) temp = temp/ap(kk-n+j)
                      x(jx) = temp
                      jx = jx - incx
                      kk = kk - (n-j+1)
  160             CONTINUE
              END IF
          END IF
      END IF
*
      RETURN
*
*     End of DTPSV
*
      END