cungqr()

subroutine cungqr	(	integer	m,
		integer	n,
		integer	k,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( * )	tau,
		complex, dimension( * )	work,
		integer	lwork,
		integer	info
	)

CUNGQR

Download CUNGQR + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CUNGQR generates an M-by-N complex matrix Q with orthonormal columns,
 which is defined as the first N columns of a product of K elementary
 reflectors of order M

       Q  =  H(1) H(2) . . . H(k)

 as returned by CGEQRF.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix Q. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix Q. M >= N >= 0.
[in]	K	K is INTEGER The number of elementary reflectors whose product defines the matrix Q. N >= K >= 0.
[in,out]	A	A is COMPLEX array, dimension (LDA,N) On entry, the i-th column must contain the vector which defines the elementary reflector H(i), for i = 1,2,...,k, as returned by CGEQRF in the first k columns of its array argument A. On exit, the M-by-N matrix Q.
[in]	LDA	LDA is INTEGER The first dimension of the array A. LDA >= max(1,M).
[in]	TAU	TAU is COMPLEX array, dimension (K) TAU(i) must contain the scalar factor of the elementary reflector H(i), as returned by CGEQRF.
[out]	WORK	WORK is COMPLEX array, dimension (MAX(1,LWORK)) On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK. LWORK >= max(1,N). For optimum performance LWORK >= N*NB, where NB is the optimal blocksize. If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument has an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 127 of file cungqr.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, K, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            ZERO
      parameter( zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            I, IB, IINFO, IWS, J, KI, KK, L, LDWORK,
     $                   LWKOPT, NB, NBMIN, NX
*     ..
*     .. External Subroutines ..
      EXTERNAL           clarfb, clarft, cung2r, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. External Functions ..
      INTEGER            ILAENV
      REAL               SROUNDUP_LWORK
      EXTERNAL           ilaenv, sroundup_lwork
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      nb = ilaenv( 1, 'CUNGQR', ' ', m, n, k, -1 )
      lwkopt = max( 1, n )*nb
      work( 1 ) = sroundup_lwork(lwkopt)
      lquery = ( lwork.EQ.-1 )
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 .OR. n.GT.m ) THEN
         info = -2
      ELSE IF( k.LT.0 .OR. k.GT.n ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      ELSE IF( lwork.LT.max( 1, n ) .AND. .NOT.lquery ) THEN
         info = -8
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CUNGQR', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.LE.0 ) THEN
         work( 1 ) = 1
         RETURN
      END IF
*
      nbmin = 2
      nx = 0
      iws = n
      IF( nb.GT.1 .AND. nb.LT.k ) THEN
*
*        Determine when to cross over from blocked to unblocked code.
*
         nx = max( 0, ilaenv( 3, 'CUNGQR', ' ', m, n, k, -1 ) )
         IF( nx.LT.k ) THEN
*
*           Determine if workspace is large enough for blocked code.
*
            ldwork = n
            iws = ldwork*nb
            IF( lwork.LT.iws ) THEN
*
*              Not enough workspace to use optimal NB:  reduce NB and
*              determine the minimum value of NB.
*
               nb = lwork / ldwork
               nbmin = max( 2, ilaenv( 2, 'CUNGQR', ' ', m, n, k, -1 ) )
            END IF
         END IF
      END IF
*
      IF( nb.GE.nbmin .AND. nb.LT.k .AND. nx.LT.k ) THEN
*
*        Use blocked code after the last block.
*        The first kk columns are handled by the block method.
*
         ki = ( ( k-nx-1 ) / nb )*nb
         kk = min( k, ki+nb )
*
*        Set A(1:kk,kk+1:n) to zero.
*
         DO 20 j = kk + 1, n
            DO 10 i = 1, kk
               a( i, j ) = zero
   10       CONTINUE
   20    CONTINUE
      ELSE
         kk = 0
      END IF
*
*     Use unblocked code for the last or only block.
*
      IF( kk.LT.n )
     $   CALL cung2r( m-kk, n-kk, k-kk, a( kk+1, kk+1 ), lda,
     $                tau( kk+1 ), work, iinfo )
*
      IF( kk.GT.0 ) THEN
*
*        Use blocked code
*
         DO 50 i = ki + 1, 1, -nb
            ib = min( nb, k-i+1 )
            IF( i+ib.LE.n ) THEN
*
*              Form the triangular factor of the block reflector
*              H = H(i) H(i+1) . . . H(i+ib-1)
*
               CALL clarft( 'Forward', 'Columnwise', m-i+1, ib,
     $                      a( i, i ), lda, tau( i ), work, ldwork )
*
*              Apply H to A(i:m,i+ib:n) from the left
*
               CALL clarfb( 'Left', 'No transpose', 'Forward',
     $                      'Columnwise', m-i+1, n-i-ib+1, ib,
     $                      a( i, i ), lda, work, ldwork, a( i, i+ib ),
     $                      lda, work( ib+1 ), ldwork )
            END IF
*
*           Apply H to rows i:m of current block
*
            CALL cung2r( m-i+1, ib, ib, a( i, i ), lda, tau( i ), work,
     $                   iinfo )
*
*           Set rows 1:i-1 of current block to zero
*
            DO 40 j = i, i + ib - 1
               DO 30 l = 1, i - 1
                  a( l, j ) = zero
   30          CONTINUE
   40       CONTINUE
   50    CONTINUE
      END IF
*
      work( 1 ) = sroundup_lwork(iws)
      RETURN
*
*     End of CUNGQR
*

Here is the call graph for this function:

Here is the caller graph for this function: