LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
cungqr.f
Go to the documentation of this file.
1*> \brief \b CUNGQR
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cungqr.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cungqr.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cungqr.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE CUNGQR( M, N, K, A, LDA, TAU, WORK, LWORK, INFO )
22*
23* .. Scalar Arguments ..
24* INTEGER INFO, K, LDA, LWORK, M, N
25* ..
26* .. Array Arguments ..
27* COMPLEX A( LDA, * ), TAU( * ), WORK( * )
28* ..
29*
30*
31*> \par Purpose:
32* =============
33*>
34*> \verbatim
35*>
36*> CUNGQR generates an M-by-N complex matrix Q with orthonormal columns,
37*> which is defined as the first N columns of a product of K elementary
38*> reflectors of order M
39*>
40*> Q = H(1) H(2) . . . H(k)
41*>
42*> as returned by CGEQRF.
43*> \endverbatim
44*
45* Arguments:
46* ==========
47*
48*> \param[in] M
49*> \verbatim
50*> M is INTEGER
51*> The number of rows of the matrix Q. M >= 0.
52*> \endverbatim
53*>
54*> \param[in] N
55*> \verbatim
56*> N is INTEGER
57*> The number of columns of the matrix Q. M >= N >= 0.
58*> \endverbatim
59*>
60*> \param[in] K
61*> \verbatim
62*> K is INTEGER
63*> The number of elementary reflectors whose product defines the
64*> matrix Q. N >= K >= 0.
65*> \endverbatim
66*>
67*> \param[in,out] A
68*> \verbatim
69*> A is COMPLEX array, dimension (LDA,N)
70*> On entry, the i-th column must contain the vector which
71*> defines the elementary reflector H(i), for i = 1,2,...,k, as
72*> returned by CGEQRF in the first k columns of its array
73*> argument A.
74*> On exit, the M-by-N matrix Q.
75*> \endverbatim
76*>
77*> \param[in] LDA
78*> \verbatim
79*> LDA is INTEGER
80*> The first dimension of the array A. LDA >= max(1,M).
81*> \endverbatim
82*>
83*> \param[in] TAU
84*> \verbatim
85*> TAU is COMPLEX array, dimension (K)
86*> TAU(i) must contain the scalar factor of the elementary
87*> reflector H(i), as returned by CGEQRF.
88*> \endverbatim
89*>
90*> \param[out] WORK
91*> \verbatim
92*> WORK is COMPLEX array, dimension (MAX(1,LWORK))
93*> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
94*> \endverbatim
95*>
96*> \param[in] LWORK
97*> \verbatim
98*> LWORK is INTEGER
99*> The dimension of the array WORK. LWORK >= max(1,N).
100*> For optimum performance LWORK >= N*NB, where NB is the
101*> optimal blocksize.
102*>
103*> If LWORK = -1, then a workspace query is assumed; the routine
104*> only calculates the optimal size of the WORK array, returns
105*> this value as the first entry of the WORK array, and no error
106*> message related to LWORK is issued by XERBLA.
107*> \endverbatim
108*>
109*> \param[out] INFO
110*> \verbatim
111*> INFO is INTEGER
112*> = 0: successful exit
113*> < 0: if INFO = -i, the i-th argument has an illegal value
114*> \endverbatim
115*
116* Authors:
117* ========
118*
119*> \author Univ. of Tennessee
120*> \author Univ. of California Berkeley
121*> \author Univ. of Colorado Denver
122*> \author NAG Ltd.
123*
124*> \ingroup ungqr
125*
126* =====================================================================
127 SUBROUTINE cungqr( M, N, K, A, LDA, TAU, WORK, LWORK, INFO )
128*
129* -- LAPACK computational routine --
130* -- LAPACK is a software package provided by Univ. of Tennessee, --
131* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
132*
133* .. Scalar Arguments ..
134 INTEGER INFO, K, LDA, LWORK, M, N
135* ..
136* .. Array Arguments ..
137 COMPLEX A( LDA, * ), TAU( * ), WORK( * )
138* ..
139*
140* =====================================================================
141*
142* .. Parameters ..
143 COMPLEX ZERO
144 parameter( zero = ( 0.0e+0, 0.0e+0 ) )
145* ..
146* .. Local Scalars ..
147 LOGICAL LQUERY
148 INTEGER I, IB, IINFO, IWS, J, KI, KK, L, LDWORK,
149 \$ LWKOPT, NB, NBMIN, NX
150* ..
151* .. External Subroutines ..
152 EXTERNAL clarfb, clarft, cung2r, xerbla
153* ..
154* .. Intrinsic Functions ..
155 INTRINSIC max, min
156* ..
157* .. External Functions ..
158 INTEGER ILAENV
159 REAL SROUNDUP_LWORK
160 EXTERNAL ilaenv, sroundup_lwork
161* ..
162* .. Executable Statements ..
163*
164* Test the input arguments
165*
166 info = 0
167 nb = ilaenv( 1, 'CUNGQR', ' ', m, n, k, -1 )
168 lwkopt = max( 1, n )*nb
169 work( 1 ) = sroundup_lwork(lwkopt)
170 lquery = ( lwork.EQ.-1 )
171 IF( m.LT.0 ) THEN
172 info = -1
173 ELSE IF( n.LT.0 .OR. n.GT.m ) THEN
174 info = -2
175 ELSE IF( k.LT.0 .OR. k.GT.n ) THEN
176 info = -3
177 ELSE IF( lda.LT.max( 1, m ) ) THEN
178 info = -5
179 ELSE IF( lwork.LT.max( 1, n ) .AND. .NOT.lquery ) THEN
180 info = -8
181 END IF
182 IF( info.NE.0 ) THEN
183 CALL xerbla( 'CUNGQR', -info )
184 RETURN
185 ELSE IF( lquery ) THEN
186 RETURN
187 END IF
188*
189* Quick return if possible
190*
191 IF( n.LE.0 ) THEN
192 work( 1 ) = 1
193 RETURN
194 END IF
195*
196 nbmin = 2
197 nx = 0
198 iws = n
199 IF( nb.GT.1 .AND. nb.LT.k ) THEN
200*
201* Determine when to cross over from blocked to unblocked code.
202*
203 nx = max( 0, ilaenv( 3, 'CUNGQR', ' ', m, n, k, -1 ) )
204 IF( nx.LT.k ) THEN
205*
206* Determine if workspace is large enough for blocked code.
207*
208 ldwork = n
209 iws = ldwork*nb
210 IF( lwork.LT.iws ) THEN
211*
212* Not enough workspace to use optimal NB: reduce NB and
213* determine the minimum value of NB.
214*
215 nb = lwork / ldwork
216 nbmin = max( 2, ilaenv( 2, 'CUNGQR', ' ', m, n, k, -1 ) )
217 END IF
218 END IF
219 END IF
220*
221 IF( nb.GE.nbmin .AND. nb.LT.k .AND. nx.LT.k ) THEN
222*
223* Use blocked code after the last block.
224* The first kk columns are handled by the block method.
225*
226 ki = ( ( k-nx-1 ) / nb )*nb
227 kk = min( k, ki+nb )
228*
229* Set A(1:kk,kk+1:n) to zero.
230*
231 DO 20 j = kk + 1, n
232 DO 10 i = 1, kk
233 a( i, j ) = zero
234 10 CONTINUE
235 20 CONTINUE
236 ELSE
237 kk = 0
238 END IF
239*
240* Use unblocked code for the last or only block.
241*
242 IF( kk.LT.n )
243 \$ CALL cung2r( m-kk, n-kk, k-kk, a( kk+1, kk+1 ), lda,
244 \$ tau( kk+1 ), work, iinfo )
245*
246 IF( kk.GT.0 ) THEN
247*
248* Use blocked code
249*
250 DO 50 i = ki + 1, 1, -nb
251 ib = min( nb, k-i+1 )
252 IF( i+ib.LE.n ) THEN
253*
254* Form the triangular factor of the block reflector
255* H = H(i) H(i+1) . . . H(i+ib-1)
256*
257 CALL clarft( 'Forward', 'Columnwise', m-i+1, ib,
258 \$ a( i, i ), lda, tau( i ), work, ldwork )
259*
260* Apply H to A(i:m,i+ib:n) from the left
261*
262 CALL clarfb( 'Left', 'No transpose', 'Forward',
263 \$ 'Columnwise', m-i+1, n-i-ib+1, ib,
264 \$ a( i, i ), lda, work, ldwork, a( i, i+ib ),
265 \$ lda, work( ib+1 ), ldwork )
266 END IF
267*
268* Apply H to rows i:m of current block
269*
270 CALL cung2r( m-i+1, ib, ib, a( i, i ), lda, tau( i ), work,
271 \$ iinfo )
272*
273* Set rows 1:i-1 of current block to zero
274*
275 DO 40 j = i, i + ib - 1
276 DO 30 l = 1, i - 1
277 a( l, j ) = zero
278 30 CONTINUE
279 40 CONTINUE
280 50 CONTINUE
281 END IF
282*
283 work( 1 ) = sroundup_lwork(iws)
284 RETURN
285*
286* End of CUNGQR
287*
288 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine clarfb(side, trans, direct, storev, m, n, k, v, ldv, t, ldt, c, ldc, work, ldwork)
CLARFB applies a block reflector or its conjugate-transpose to a general rectangular matrix.
Definition clarfb.f:197
subroutine clarft(direct, storev, n, k, v, ldv, tau, t, ldt)
CLARFT forms the triangular factor T of a block reflector H = I - vtvH
Definition clarft.f:163
subroutine cung2r(m, n, k, a, lda, tau, work, info)
CUNG2R
Definition cung2r.f:114
subroutine cungqr(m, n, k, a, lda, tau, work, lwork, info)
CUNGQR
Definition cungqr.f:128