LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ clarft()

subroutine clarft ( character direct,
character storev,
integer n,
integer k,
complex, dimension( ldv, * ) v,
integer ldv,
complex, dimension( * ) tau,
complex, dimension( ldt, * ) t,
integer ldt )

CLARFT forms the triangular factor T of a block reflector H = I - vtvH

Download CLARFT + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> CLARFT forms the triangular factor T of a complex block reflector H
!> of order n, which is defined as a product of k elementary reflectors.
!>
!> If DIRECT = 'F', H = H(1) H(2) . . . H(k) and T is upper triangular;
!>
!> If DIRECT = 'B', H = H(k) . . . H(2) H(1) and T is lower triangular.
!>
!> If STOREV = 'C', the vector which defines the elementary reflector
!> H(i) is stored in the i-th column of the array V, and
!>
!>    H  =  I - V * T * V**H
!>
!> If STOREV = 'R', the vector which defines the elementary reflector
!> H(i) is stored in the i-th row of the array V, and
!>
!>    H  =  I - V**H * T * V
!>
Parameters
[in]DIRECT
!>          DIRECT is CHARACTER*1
!>          Specifies the order in which the elementary reflectors are
!>          multiplied to form the block reflector:
!>          = 'F': H = H(1) H(2) . . . H(k) (Forward)
!>          = 'B': H = H(k) . . . H(2) H(1) (Backward)
!>
[in]STOREV
!>          STOREV is CHARACTER*1
!>          Specifies how the vectors which define the elementary
!>          reflectors are stored (see also Further Details):
!>          = 'C': columnwise
!>          = 'R': rowwise
!>
[in]N
!>          N is INTEGER
!>          The order of the block reflector H. N >= 0.
!>
[in]K
!>          K is INTEGER
!>          The order of the triangular factor T (= the number of
!>          elementary reflectors). K >= 1.
!>
[in]V
!>          V is COMPLEX array, dimension
!>                               (LDV,K) if STOREV = 'C'
!>                               (LDV,N) if STOREV = 'R'
!>          The matrix V. See further details.
!>
[in]LDV
!>          LDV is INTEGER
!>          The leading dimension of the array V.
!>          If STOREV = 'C', LDV >= max(1,N); if STOREV = 'R', LDV >= K.
!>
[in]TAU
!>          TAU is COMPLEX array, dimension (K)
!>          TAU(i) must contain the scalar factor of the elementary
!>          reflector H(i).
!>
[out]T
!>          T is COMPLEX array, dimension (LDT,K)
!>          The k by k triangular factor T of the block reflector.
!>          If DIRECT = 'F', T is upper triangular; if DIRECT = 'B', T is
!>          lower triangular. The rest of the array is not used.
!>
[in]LDT
!>          LDT is INTEGER
!>          The leading dimension of the array T. LDT >= K.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
!>
!>  The shape of the matrix V and the storage of the vectors which define
!>  the H(i) is best illustrated by the following example with n = 5 and
!>  k = 3. The elements equal to 1 are not stored.
!>
!>  DIRECT = 'F' and STOREV = 'C':         DIRECT = 'F' and STOREV = 'R':
!>
!>               V = (  1       )                 V = (  1 v1 v1 v1 v1 )
!>                   ( v1  1    )                     (     1 v2 v2 v2 )
!>                   ( v1 v2  1 )                     (        1 v3 v3 )
!>                   ( v1 v2 v3 )
!>                   ( v1 v2 v3 )
!>
!>  DIRECT = 'B' and STOREV = 'C':         DIRECT = 'B' and STOREV = 'R':
!>
!>               V = ( v1 v2 v3 )                 V = ( v1 v1  1       )
!>                   ( v1 v2 v3 )                     ( v2 v2 v2  1    )
!>                   (  1 v2 v3 )                     ( v3 v3 v3 v3  1 )
!>                   (     1 v3 )
!>                   (        1 )
!>

Definition at line 160 of file clarft.f.

161*
162* -- LAPACK auxiliary routine --
163* -- LAPACK is a software package provided by Univ. of Tennessee, --
164* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
165*
166* .. Scalar Arguments ..
167 CHARACTER DIRECT, STOREV
168 INTEGER K, LDT, LDV, N
169* ..
170* .. Array Arguments ..
171 COMPLEX T( LDT, * ), TAU( * ), V( LDV, * )
172* ..
173*
174* =====================================================================
175*
176* .. Parameters ..
177 COMPLEX ONE, ZERO
178 parameter( one = ( 1.0e+0, 0.0e+0 ),
179 $ zero = ( 0.0e+0, 0.0e+0 ) )
180* ..
181* .. Local Scalars ..
182 INTEGER I, J, PREVLASTV, LASTV
183* ..
184* .. External Subroutines ..
185 EXTERNAL cgemm, cgemv, ctrmv
186* ..
187* .. External Functions ..
188 LOGICAL LSAME
189 EXTERNAL lsame
190* ..
191* .. Executable Statements ..
192*
193* Quick return if possible
194*
195 IF( n.EQ.0 )
196 $ RETURN
197*
198 IF( lsame( direct, 'F' ) ) THEN
199 prevlastv = n
200 DO i = 1, k
201 prevlastv = max( prevlastv, i )
202 IF( tau( i ).EQ.zero ) THEN
203*
204* H(i) = I
205*
206 DO j = 1, i
207 t( j, i ) = zero
208 END DO
209 ELSE
210*
211* general case
212*
213 IF( lsame( storev, 'C' ) ) THEN
214* Skip any trailing zeros.
215 DO lastv = n, i+1, -1
216 IF( v( lastv, i ).NE.zero ) EXIT
217 END DO
218 DO j = 1, i-1
219 t( j, i ) = -tau( i ) * conjg( v( i , j ) )
220 END DO
221 j = min( lastv, prevlastv )
222*
223* T(1:i-1,i) := - tau(i) * V(i:j,1:i-1)**H * V(i:j,i)
224*
225 CALL cgemv( 'Conjugate transpose', j-i, i-1,
226 $ -tau( i ), v( i+1, 1 ), ldv,
227 $ v( i+1, i ), 1,
228 $ one, t( 1, i ), 1 )
229 ELSE
230* Skip any trailing zeros.
231 DO lastv = n, i+1, -1
232 IF( v( i, lastv ).NE.zero ) EXIT
233 END DO
234 DO j = 1, i-1
235 t( j, i ) = -tau( i ) * v( j , i )
236 END DO
237 j = min( lastv, prevlastv )
238*
239* T(1:i-1,i) := - tau(i) * V(1:i-1,i:j) * V(i,i:j)**H
240*
241 CALL cgemm( 'N', 'C', i-1, 1, j-i, -tau( i ),
242 $ v( 1, i+1 ), ldv, v( i, i+1 ), ldv,
243 $ one, t( 1, i ), ldt )
244 END IF
245*
246* T(1:i-1,i) := T(1:i-1,1:i-1) * T(1:i-1,i)
247*
248 CALL ctrmv( 'Upper', 'No transpose', 'Non-unit', i-1, t,
249 $ ldt, t( 1, i ), 1 )
250 t( i, i ) = tau( i )
251 IF( i.GT.1 ) THEN
252 prevlastv = max( prevlastv, lastv )
253 ELSE
254 prevlastv = lastv
255 END IF
256 END IF
257 END DO
258 ELSE
259 prevlastv = 1
260 DO i = k, 1, -1
261 IF( tau( i ).EQ.zero ) THEN
262*
263* H(i) = I
264*
265 DO j = i, k
266 t( j, i ) = zero
267 END DO
268 ELSE
269*
270* general case
271*
272 IF( i.LT.k ) THEN
273 IF( lsame( storev, 'C' ) ) THEN
274* Skip any leading zeros.
275 DO lastv = 1, i-1
276 IF( v( lastv, i ).NE.zero ) EXIT
277 END DO
278 DO j = i+1, k
279 t( j, i ) = -tau( i ) * conjg( v( n-k+i , j ) )
280 END DO
281 j = max( lastv, prevlastv )
282*
283* T(i+1:k,i) = -tau(i) * V(j:n-k+i,i+1:k)**H * V(j:n-k+i,i)
284*
285 CALL cgemv( 'Conjugate transpose', n-k+i-j, k-i,
286 $ -tau( i ), v( j, i+1 ), ldv, v( j, i ),
287 $ 1, one, t( i+1, i ), 1 )
288 ELSE
289* Skip any leading zeros.
290 DO lastv = 1, i-1
291 IF( v( i, lastv ).NE.zero ) EXIT
292 END DO
293 DO j = i+1, k
294 t( j, i ) = -tau( i ) * v( j, n-k+i )
295 END DO
296 j = max( lastv, prevlastv )
297*
298* T(i+1:k,i) = -tau(i) * V(i+1:k,j:n-k+i) * V(i,j:n-k+i)**H
299*
300 CALL cgemm( 'N', 'C', k-i, 1, n-k+i-j, -tau( i ),
301 $ v( i+1, j ), ldv, v( i, j ), ldv,
302 $ one, t( i+1, i ), ldt )
303 END IF
304*
305* T(i+1:k,i) := T(i+1:k,i+1:k) * T(i+1:k,i)
306*
307 CALL ctrmv( 'Lower', 'No transpose', 'Non-unit', k-i,
308 $ t( i+1, i+1 ), ldt, t( i+1, i ), 1 )
309 IF( i.GT.1 ) THEN
310 prevlastv = min( prevlastv, lastv )
311 ELSE
312 prevlastv = lastv
313 END IF
314 END IF
315 t( i, i ) = tau( i )
316 END IF
317 END DO
318 END IF
319 RETURN
320*
321* End of CLARFT
322*
cgemm
subroutine cgemm(transa, transb, m, n, k, alpha, a, lda, b, ldb, beta, c, ldc)
CGEMM
Definition cgemm.f:188
cgemv
subroutine cgemv(trans, m, n, alpha, a, lda, x, incx, beta, y, incy)
CGEMV
Definition cgemv.f:160
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
ctrmv
subroutine ctrmv(uplo, trans, diag, n, a, lda, x, incx)
CTRMV
Definition ctrmv.f:147
Here is the call graph for this function:
Here is the caller graph for this function: