zchktr()

subroutine zchktr	(	logical, dimension( * )	dotype,
		integer	nn,
		integer, dimension( * )	nval,
		integer	nnb,
		integer, dimension( * )	nbval,
		integer	nns,
		integer, dimension( * )	nsval,
		double precision	thresh,
		logical	tsterr,
		integer	nmax,
		complex*16, dimension( * )	a,
		complex*16, dimension( * )	ainv,
		complex*16, dimension( * )	b,
		complex*16, dimension( * )	x,
		complex*16, dimension( * )	xact,
		complex*16, dimension( * )	work,
		double precision, dimension( * )	rwork,
		integer	nout )

ZCHKTR

Purpose:

!>
!> ZCHKTR tests ZTRTRI, -TRS, -RFS, and -CON, and ZLATRS(3)
!> 

Parameters

[in]	DOTYPE	!> DOTYPE is LOGICAL array, dimension (NTYPES) !> The matrix types to be used for testing. Matrices of type j !> (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) = !> .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used. !>
[in]	NN	!> NN is INTEGER !> The number of values of N contained in the vector NVAL. !>
[in]	NVAL	!> NVAL is INTEGER array, dimension (NN) !> The values of the matrix column dimension N. !>
[in]	NNB	!> NNB is INTEGER !> The number of values of NB contained in the vector NBVAL. !>
[in]	NBVAL	!> NBVAL is INTEGER array, dimension (NNB) !> The values of the blocksize NB. !>
[in]	NNS	!> NNS is INTEGER !> The number of values of NRHS contained in the vector NSVAL. !>
[in]	NSVAL	!> NSVAL is INTEGER array, dimension (NNS) !> The values of the number of right hand sides NRHS. !>
[in]	THRESH	!> THRESH is DOUBLE PRECISION !> The threshold value for the test ratios. A result is !> included in the output file if RESULT >= THRESH. To have !> every test ratio printed, use THRESH = 0. !>
[in]	TSTERR	!> TSTERR is LOGICAL !> Flag that indicates whether error exits are to be tested. !>
[in]	NMAX	!> NMAX is INTEGER !> The leading dimension of the work arrays. !> NMAX >= the maximum value of N in NVAL. !>
[out]	A	!> A is COMPLEX*16 array, dimension (NMAX*NMAX) !>
[out]	AINV	!> AINV is COMPLEX*16 array, dimension (NMAX*NMAX) !>
[out]	B	!> B is COMPLEX*16 array, dimension (NMAX*NSMAX) !> where NSMAX is the largest entry in NSVAL. !>
[out]	X	!> X is COMPLEX*16 array, dimension (NMAX*NSMAX) !>
[out]	XACT	!> XACT is COMPLEX*16 array, dimension (NMAX*NSMAX) !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension !> (NMAX*max(3,NSMAX)) !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension !> (max(NMAX,2*NSMAX)) !>
[in]	NOUT	!> NOUT is INTEGER !> The unit number for output. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 160 of file zchktr.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NMAX, NN, NNB, NNS, NOUT
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            NBVAL( * ), NSVAL( * ), NVAL( * )
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         A( * ), AINV( * ), B( * ), WORK( * ), X( * ),
     $                   XACT( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            NTYPE1, NTYPES
      parameter( ntype1 = 10, ntypes = 18 )
      INTEGER            NTESTS
      parameter( ntests = 10 )
      INTEGER            NTRAN
      parameter( ntran = 3 )
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d0, zero = 0.0d0 )
*     ..
*     .. Local Scalars ..
      CHARACTER          DIAG, NORM, TRANS, UPLO, XTYPE
      CHARACTER*3        PATH
      INTEGER            I, IDIAG, IMAT, IN, INB, INFO, IRHS, ITRAN,
     $                   IUPLO, K, LDA, N, NB, NERRS, NFAIL, NRHS, NRUN
      DOUBLE PRECISION   AINVNM, ANORM, BIGNUM, DUMMY, RCOND, RCONDC,
     $                   RCONDI, RCONDO, RES, SCALE, DLAMCH
*     ..
*     .. Local Arrays ..
      CHARACTER          TRANSS( NTRAN ), UPLOS( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      DOUBLE PRECISION   RESULT( NTESTS ), RWORK2( 2*NMAX ),
     $                   SCALE3( 2 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   ZLANTR
      EXTERNAL           lsame, zlantr
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, dlamch, xlaenv, zcopy,
     $                   zdscal, zerrtr, zget04, zlacpy, zlarhs, zlatrs,
     $                   zlatrs3, zlattr, ztrcon, ztrrfs, ztrt01,
     $                   ztrt02, ztrt03, ztrt05, ztrt06, ztrtri, ztrtrs
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, IOUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, iounit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' / , transs / 'N', 'T', 'C' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Zomplex precision'
      path( 2: 3 ) = 'TR'
      bignum = dlamch('Overflow') / dlamch('Precision')
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL zerrtr( path, nout )
      infot = 0
*
      DO 120 in = 1, nn
*
*        Do for each value of N in NVAL
*
         n = nval( in )
         lda = max( 1, n )
         xtype = 'N'
*
         DO 80 imat = 1, ntype1
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 80
*
            DO 70 iuplo = 1, 2
*
*              Do first for UPLO = 'U', then for UPLO = 'L'
*
               uplo = uplos( iuplo )
*
*              Call ZLATTR to generate a triangular test matrix.
*
               srnamt = 'ZLATTR'
               CALL zlattr( imat, uplo, 'No transpose', diag, iseed, n,
     $                      a, lda, x, work, rwork, info )
*
*              Set IDIAG = 1 for non-unit matrices, 2 for unit.
*
               IF( lsame( diag, 'N' ) ) THEN
                  idiag = 1
               ELSE
                  idiag = 2
               END IF
*
               DO 60 inb = 1, nnb
*
*                 Do for each blocksize in NBVAL
*
                  nb = nbval( inb )
                  CALL xlaenv( 1, nb )
*
*+    TEST 1
*                 Form the inverse of A.
*
                  CALL zlacpy( uplo, n, n, a, lda, ainv, lda )
                  srnamt = 'ZTRTRI'
                  CALL ztrtri( uplo, diag, n, ainv, lda, info )
*
*                 Check error code from ZTRTRI.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'ZTRTRI', info, 0, uplo // diag,
     $                            n, n, -1, -1, nb, imat, nfail, nerrs,
     $                            nout )
*
*                 Compute the infinity-norm condition number of A.
*
                  anorm = zlantr( 'I', uplo, diag, n, n, a, lda, rwork )
                  ainvnm = zlantr( 'I', uplo, diag, n, n, ainv, lda,
     $                     rwork )
                  IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
                     rcondi = one
                  ELSE
                     rcondi = ( one / anorm ) / ainvnm
                  END IF
*
*                 Compute the residual for the triangular matrix times
*                 its inverse.  Also compute the 1-norm condition number
*                 of A.
*
                  CALL ztrt01( uplo, diag, n, a, lda, ainv, lda, rcondo,
     $                         rwork, result( 1 ) )
*                 Print the test ratio if it is .GE. THRESH.
*
                  IF( result( 1 ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9999 )uplo, diag, n, nb, imat,
     $                  1, result( 1 )
                     nfail = nfail + 1
                  END IF
                  nrun = nrun + 1
*
*                 Skip remaining tests if not the first block size.
*
                  IF( inb.NE.1 )
     $               GO TO 60
*
                  DO 40 irhs = 1, nns
                     nrhs = nsval( irhs )
                     xtype = 'N'
*
                     DO 30 itran = 1, ntran
*
*                    Do for op(A) = A, A**T, or A**H.
*
                        trans = transs( itran )
                        IF( itran.EQ.1 ) THEN
                           norm = 'O'
                           rcondc = rcondo
                        ELSE
                           norm = 'I'
                           rcondc = rcondi
                        END IF
*
*+    TEST 2
*                       Solve and compute residual for op(A)*x = b.
*
                        srnamt = 'ZLARHS'
                        CALL zlarhs( path, xtype, uplo, trans, n, n, 0,
     $                               idiag, nrhs, a, lda, xact, lda, b,
     $                               lda, iseed, info )
                        xtype = 'C'
                        CALL zlacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                        srnamt = 'ZTRTRS'
                        CALL ztrtrs( uplo, trans, diag, n, nrhs, a, lda,
     $                               x, lda, info )
*
*                       Check error code from ZTRTRS.
*
                        IF( info.NE.0 )
     $                     CALL alaerh( path, 'ZTRTRS', info, 0,
     $                                  uplo // trans // diag, n, n, -1,
     $                                  -1, nrhs, imat, nfail, nerrs,
     $                                  nout )
*
*                       This line is needed on a Sun SPARCstation.
*
                        IF( n.GT.0 )
     $                     dummy = dble( a( 1 ) )
*
                        CALL ztrt02( uplo, trans, diag, n, nrhs, a, lda,
     $                               x, lda, b, lda, work, rwork,
     $                               result( 2 ) )
*
*+    TEST 3
*                       Check solution from generated exact solution.
*
                        CALL zget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                               result( 3 ) )
*
*+    TESTS 4, 5, and 6
*                       Use iterative refinement to improve the solution
*                       and compute error bounds.
*
                        srnamt = 'ZTRRFS'
                        CALL ztrrfs( uplo, trans, diag, n, nrhs, a, lda,
     $                               b, lda, x, lda, rwork,
     $                               rwork( nrhs+1 ), work,
     $                               rwork( 2*nrhs+1 ), info )
*
*                       Check error code from ZTRRFS.
*
                        IF( info.NE.0 )
     $                     CALL alaerh( path, 'ZTRRFS', info, 0,
     $                                  uplo // trans // diag, n, n, -1,
     $                                  -1, nrhs, imat, nfail, nerrs,
     $                                  nout )
*
                        CALL zget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                               result( 4 ) )
                        CALL ztrt05( uplo, trans, diag, n, nrhs, a, lda,
     $                               b, lda, x, lda, xact, lda, rwork,
     $                               rwork( nrhs+1 ), result( 5 ) )
*
*                       Print information about the tests that did not
*                       pass the threshold.
*
                        DO 20 k = 2, 6
                           IF( result( k ).GE.thresh ) THEN
                              IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                           CALL alahd( nout, path )
                              WRITE( nout, fmt = 9998 )uplo, trans,
     $                           diag, n, nrhs, imat, k, result( k )
                              nfail = nfail + 1
                           END IF
   20                   CONTINUE
                        nrun = nrun + 5
   30                CONTINUE
   40             CONTINUE
*
*+    TEST 7
*                       Get an estimate of RCOND = 1/CNDNUM.
*
                  DO 50 itran = 1, 2
                     IF( itran.EQ.1 ) THEN
                        norm = 'O'
                        rcondc = rcondo
                     ELSE
                        norm = 'I'
                        rcondc = rcondi
                     END IF
                     srnamt = 'ZTRCON'
                     CALL ztrcon( norm, uplo, diag, n, a, lda, rcond,
     $                            work, rwork, info )
*
*                       Check error code from ZTRCON.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'ZTRCON', info, 0,
     $                               norm // uplo // diag, n, n, -1, -1,
     $                               -1, imat, nfail, nerrs, nout )
*
                     CALL ztrt06( rcond, rcondc, uplo, diag, n, a, lda,
     $                            rwork, result( 7 ) )
*
*                    Print the test ratio if it is .GE. THRESH.
*
                     IF( result( 7 ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9997 )norm, uplo, n, imat,
     $                     7, result( 7 )
                        nfail = nfail + 1
                     END IF
                     nrun = nrun + 1
   50             CONTINUE
   60          CONTINUE
   70       CONTINUE
   80    CONTINUE
*
*        Use pathological test matrices to test ZLATRS.
*
         DO 110 imat = ntype1 + 1, ntypes
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 110
*
            DO 100 iuplo = 1, 2
*
*              Do first for UPLO = 'U', then for UPLO = 'L'
*
               uplo = uplos( iuplo )
               DO 90 itran = 1, ntran
*
*                 Do for op(A) = A, A**T, and A**H.
*
                  trans = transs( itran )
*
*                 Call ZLATTR to generate a triangular test matrix.
*
                  srnamt = 'ZLATTR'
                  CALL zlattr( imat, uplo, trans, diag, iseed, n, a,
     $                         lda, x, work, rwork, info )
*
*+    TEST 8
*                 Solve the system op(A)*x = b.
*
                  srnamt = 'ZLATRS'
                  CALL zcopy( n, x, 1, b, 1 )
                  CALL zlatrs( uplo, trans, diag, 'N', n, a, lda, b,
     $                         scale, rwork, info )
*
*                 Check error code from ZLATRS.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'ZLATRS', info, 0,
     $                            uplo // trans // diag // 'N', n, n,
     $                            -1, -1, -1, imat, nfail, nerrs, nout )
*
                  CALL ztrt03( uplo, trans, diag, n, 1, a, lda, scale,
     $                         rwork, one, b, lda, x, lda, work,
     $                         result( 8 ) )
*
*+    TEST 9
*                 Solve op(A)*X = b again with NORMIN = 'Y'.
*
                  CALL zcopy( n, x, 1, b( n+1 ), 1 )
                  CALL zlatrs( uplo, trans, diag, 'Y', n, a, lda,
     $                         b( n+1 ), scale, rwork, info )
*
*                 Check error code from ZLATRS.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'ZLATRS', info, 0,
     $                            uplo // trans // diag // 'Y', n, n,
     $                            -1, -1, -1, imat, nfail, nerrs, nout )
*
                  CALL ztrt03( uplo, trans, diag, n, 1, a, lda, scale,
     $                         rwork, one, b( n+1 ), lda, x, lda, work,
     $                         result( 9 ) )
*
*+    TEST 10
*                 Solve op(A)*X = B
*
                  srnamt = 'ZLATRS3'
                  CALL zcopy( n, x, 1, b, 1 )
                  CALL zcopy( n, x, 1, b( n+1 ), 1 )
                  CALL zdscal( n, bignum, b( n+1 ), 1 )
                  CALL zlatrs3( uplo, trans, diag, 'N', n, 2, a, lda,
     $                          b, max(1, n), scale3, rwork, rwork2,
     $                          2*nmax, info )
*
*                 Check error code from ZLATRS3.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'ZLATRS3', info, 0,
     $                            uplo // trans // diag // 'N', n, n,
     $                            -1, -1, -1, imat, nfail, nerrs, nout )
                  CALL ztrt03( uplo, trans, diag, n, 1, a, lda,
     $                         scale3( 1 ), rwork, one, b( 1 ), lda,
     $                         x, lda, work, result( 10 ) )
                  CALL zdscal( n, bignum, x, 1 )
                  CALL ztrt03( uplo, trans, diag, n, 1, a, lda,
     $                         scale3( 2 ), rwork, one, b( n+1 ), lda,
     $                         x, lda, work, res )
                  result( 10 ) = max( result( 10 ), res )
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  IF( result( 8 ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9996 )'ZLATRS', uplo, trans,
     $                  diag, 'N', n, imat, 8, result( 8 )
                     nfail = nfail + 1
                  END IF
                  IF( result( 9 ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9996 )'ZLATRS', uplo, trans,
     $                  diag, 'Y', n, imat, 9, result( 9 )
                     nfail = nfail + 1
                  END IF
                  IF( result( 10 ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9996 )'ZLATRS3', uplo, trans,
     $                  diag, 'N', n, imat, 10, result( 10 )
                     nfail = nfail + 1
                  END IF
                  nrun = nrun + 3
   90          CONTINUE
  100       CONTINUE
  110    CONTINUE
  120 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' UPLO=''', a1, ''', DIAG=''', a1, ''', N=', i5, ', NB=',
     $      i4, ', type ', i2, ', test(', i2, ')= ', g12.5 )
 9998 FORMAT( ' UPLO=''', a1, ''', TRANS=''', a1, ''', DIAG=''', a1,
     $      ''', N=', i5, ', NB=', i4, ', type ', i2, ', test(',
     $      i2, ')= ', g12.5 )
 9997 FORMAT( ' NORM=''', a1, ''', UPLO =''', a1, ''', N=', i5, ',',
     $      11x, ' type ', i2, ', test(', i2, ')=', g12.5 )
 9996 FORMAT( 1x, a, '( ''', a1, ''', ''', a1, ''', ''', a1, ''', ''',
     $      a1, ''',', i5, ', ... ), type ', i2, ', test(', i2, ')=',
     $      g12.5 )
      RETURN
*
*     End of ZCHKTR
*

Here is the call graph for this function:

Here is the caller graph for this function: