LAPACK  3.10.1
LAPACK: Linear Algebra PACKage
cgrqts.f
Go to the documentation of this file.
1 *> \brief \b CGRQTS
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 * Definition:
9 * ===========
10 *
11 * SUBROUTINE CGRQTS( M, P, N, A, AF, Q, R, LDA, TAUA, B, BF, Z, T,
12 * BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT )
13 *
14 * .. Scalar Arguments ..
15 * INTEGER LDA, LDB, LWORK, M, P, N
16 * ..
17 * .. Array Arguments ..
18 * REAL RESULT( 4 ), RWORK( * )
19 * COMPLEX A( LDA, * ), AF( LDA, * ), R( LDA, * ),
20 * $ Q( LDA, * ), B( LDB, * ), BF( LDB, * ),
21 * $ T( LDB, * ), Z( LDB, * ), BWK( LDB, * ),
22 * $ TAUA( * ), TAUB( * ), WORK( LWORK )
23 * ..
24 *
25 *
26 *> \par Purpose:
27 * =============
28 *>
29 *> \verbatim
30 *>
31 *> CGRQTS tests CGGRQF, which computes the GRQ factorization of an
32 *> M-by-N matrix A and a P-by-N matrix B: A = R*Q and B = Z*T*Q.
33 *> \endverbatim
34 *
35 * Arguments:
36 * ==========
37 *
38 *> \param[in] M
39 *> \verbatim
40 *> M is INTEGER
41 *> The number of rows of the matrix A. M >= 0.
42 *> \endverbatim
43 *>
44 *> \param[in] P
45 *> \verbatim
46 *> P is INTEGER
47 *> The number of rows of the matrix B. P >= 0.
48 *> \endverbatim
49 *>
50 *> \param[in] N
51 *> \verbatim
52 *> N is INTEGER
53 *> The number of columns of the matrices A and B. N >= 0.
54 *> \endverbatim
55 *>
56 *> \param[in] A
57 *> \verbatim
58 *> A is COMPLEX array, dimension (LDA,N)
59 *> The M-by-N matrix A.
60 *> \endverbatim
61 *>
62 *> \param[out] AF
63 *> \verbatim
64 *> AF is COMPLEX array, dimension (LDA,N)
65 *> Details of the GRQ factorization of A and B, as returned
66 *> by CGGRQF, see CGGRQF for further details.
67 *> \endverbatim
68 *>
69 *> \param[out] Q
70 *> \verbatim
71 *> Q is COMPLEX array, dimension (LDA,N)
72 *> The N-by-N unitary matrix Q.
73 *> \endverbatim
74 *>
75 *> \param[out] R
76 *> \verbatim
77 *> R is COMPLEX array, dimension (LDA,MAX(M,N))
78 *> \endverbatim
79 *>
80 *> \param[in] LDA
81 *> \verbatim
82 *> LDA is INTEGER
83 *> The leading dimension of the arrays A, AF, R and Q.
84 *> LDA >= max(M,N).
85 *> \endverbatim
86 *>
87 *> \param[out] TAUA
88 *> \verbatim
89 *> TAUA is COMPLEX array, dimension (min(M,N))
90 *> The scalar factors of the elementary reflectors, as returned
91 *> by SGGQRC.
92 *> \endverbatim
93 *>
94 *> \param[in] B
95 *> \verbatim
96 *> B is COMPLEX array, dimension (LDB,N)
97 *> On entry, the P-by-N matrix A.
98 *> \endverbatim
99 *>
100 *> \param[out] BF
101 *> \verbatim
102 *> BF is COMPLEX array, dimension (LDB,N)
103 *> Details of the GQR factorization of A and B, as returned
104 *> by CGGRQF, see CGGRQF for further details.
105 *> \endverbatim
106 *>
107 *> \param[out] Z
108 *> \verbatim
109 *> Z is REAL array, dimension (LDB,P)
110 *> The P-by-P unitary matrix Z.
111 *> \endverbatim
112 *>
113 *> \param[out] T
114 *> \verbatim
115 *> T is COMPLEX array, dimension (LDB,max(P,N))
116 *> \endverbatim
117 *>
118 *> \param[out] BWK
119 *> \verbatim
120 *> BWK is COMPLEX array, dimension (LDB,N)
121 *> \endverbatim
122 *>
123 *> \param[in] LDB
124 *> \verbatim
125 *> LDB is INTEGER
126 *> The leading dimension of the arrays B, BF, Z and T.
127 *> LDB >= max(P,N).
128 *> \endverbatim
129 *>
130 *> \param[out] TAUB
131 *> \verbatim
132 *> TAUB is COMPLEX array, dimension (min(P,N))
133 *> The scalar factors of the elementary reflectors, as returned
134 *> by SGGRQF.
135 *> \endverbatim
136 *>
137 *> \param[out] WORK
138 *> \verbatim
139 *> WORK is COMPLEX array, dimension (LWORK)
140 *> \endverbatim
141 *>
142 *> \param[in] LWORK
143 *> \verbatim
144 *> LWORK is INTEGER
145 *> The dimension of the array WORK, LWORK >= max(M,P,N)**2.
146 *> \endverbatim
147 *>
148 *> \param[out] RWORK
149 *> \verbatim
150 *> RWORK is REAL array, dimension (M)
151 *> \endverbatim
152 *>
153 *> \param[out] RESULT
154 *> \verbatim
155 *> RESULT is REAL array, dimension (4)
156 *> The test ratios:
157 *> RESULT(1) = norm( R - A*Q' ) / ( MAX(M,N)*norm(A)*ULP)
158 *> RESULT(2) = norm( T*Q - Z'*B ) / (MAX(P,N)*norm(B)*ULP)
159 *> RESULT(3) = norm( I - Q'*Q ) / ( N*ULP )
160 *> RESULT(4) = norm( I - Z'*Z ) / ( P*ULP )
161 *> \endverbatim
162 *
163 * Authors:
164 * ========
165 *
166 *> \author Univ. of Tennessee
167 *> \author Univ. of California Berkeley
168 *> \author Univ. of Colorado Denver
169 *> \author NAG Ltd.
170 *
171 *> \ingroup complex_eig
172 *
173 * =====================================================================
174  SUBROUTINE cgrqts( M, P, N, A, AF, Q, R, LDA, TAUA, B, BF, Z, T,
175  $ BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT )
176 *
177 * -- LAPACK test routine --
178 * -- LAPACK is a software package provided by Univ. of Tennessee, --
179 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
180 *
181 * .. Scalar Arguments ..
182  INTEGER LDA, LDB, LWORK, M, P, N
183 * ..
184 * .. Array Arguments ..
185  REAL RESULT( 4 ), RWORK( * )
186  COMPLEX A( LDA, * ), AF( LDA, * ), R( LDA, * ),
187  $ q( lda, * ), b( ldb, * ), bf( ldb, * ),
188  $ t( ldb, * ), z( ldb, * ), bwk( ldb, * ),
189  $ taua( * ), taub( * ), work( lwork )
190 * ..
191 *
192 * =====================================================================
193 *
194 * .. Parameters ..
195  REAL ZERO, ONE
196  parameter( zero = 0.0e+0, one = 1.0e+0 )
197  COMPLEX CZERO, CONE
198  parameter( czero = ( 0.0e+0, 0.0e+0 ),
199  $ cone = ( 1.0e+0, 0.0e+0 ) )
200  COMPLEX CROGUE
201  parameter( crogue = ( -1.0e+10, 0.0e+0 ) )
202 * ..
203 * .. Local Scalars ..
204  INTEGER INFO
205  REAL ANORM, BNORM, ULP, UNFL, RESID
206 * ..
207 * .. External Functions ..
208  REAL SLAMCH, CLANGE, CLANHE
209  EXTERNAL slamch, clange, clanhe
210 * ..
211 * .. External Subroutines ..
212  EXTERNAL cgemm, cggrqf, clacpy, claset, cungqr,
213  $ cungrq, cherk
214 * ..
215 * .. Intrinsic Functions ..
216  INTRINSIC max, min, real
217 * ..
218 * .. Executable Statements ..
219 *
220  ulp = slamch( 'Precision' )
221  unfl = slamch( 'Safe minimum' )
222 *
223 * Copy the matrix A to the array AF.
224 *
225  CALL clacpy( 'Full', m, n, a, lda, af, lda )
226  CALL clacpy( 'Full', p, n, b, ldb, bf, ldb )
227 *
228  anorm = max( clange( '1', m, n, a, lda, rwork ), unfl )
229  bnorm = max( clange( '1', p, n, b, ldb, rwork ), unfl )
230 *
231 * Factorize the matrices A and B in the arrays AF and BF.
232 *
233  CALL cggrqf( m, p, n, af, lda, taua, bf, ldb, taub, work,
234  $ lwork, info )
235 *
236 * Generate the N-by-N matrix Q
237 *
238  CALL claset( 'Full', n, n, crogue, crogue, q, lda )
239  IF( m.LE.n ) THEN
240  IF( m.GT.0 .AND. m.LT.n )
241  $ CALL clacpy( 'Full', m, n-m, af, lda, q( n-m+1, 1 ), lda )
242  IF( m.GT.1 )
243  $ CALL clacpy( 'Lower', m-1, m-1, af( 2, n-m+1 ), lda,
244  $ q( n-m+2, n-m+1 ), lda )
245  ELSE
246  IF( n.GT.1 )
247  $ CALL clacpy( 'Lower', n-1, n-1, af( m-n+2, 1 ), lda,
248  $ q( 2, 1 ), lda )
249  END IF
250  CALL cungrq( n, n, min( m, n ), q, lda, taua, work, lwork, info )
251 *
252 * Generate the P-by-P matrix Z
253 *
254  CALL claset( 'Full', p, p, crogue, crogue, z, ldb )
255  IF( p.GT.1 )
256  $ CALL clacpy( 'Lower', p-1, n, bf( 2,1 ), ldb, z( 2,1 ), ldb )
257  CALL cungqr( p, p, min( p,n ), z, ldb, taub, work, lwork, info )
258 *
259 * Copy R
260 *
261  CALL claset( 'Full', m, n, czero, czero, r, lda )
262  IF( m.LE.n )THEN
263  CALL clacpy( 'Upper', m, m, af( 1, n-m+1 ), lda, r( 1, n-m+1 ),
264  $ lda )
265  ELSE
266  CALL clacpy( 'Full', m-n, n, af, lda, r, lda )
267  CALL clacpy( 'Upper', n, n, af( m-n+1, 1 ), lda, r( m-n+1, 1 ),
268  $ lda )
269  END IF
270 *
271 * Copy T
272 *
273  CALL claset( 'Full', p, n, czero, czero, t, ldb )
274  CALL clacpy( 'Upper', p, n, bf, ldb, t, ldb )
275 *
276 * Compute R - A*Q'
277 *
278  CALL cgemm( 'No transpose', 'Conjugate transpose', m, n, n, -cone,
279  $ a, lda, q, lda, cone, r, lda )
280 *
281 * Compute norm( R - A*Q' ) / ( MAX(M,N)*norm(A)*ULP ) .
282 *
283  resid = clange( '1', m, n, r, lda, rwork )
284  IF( anorm.GT.zero ) THEN
285  result( 1 ) = ( ( resid / real(max(1,m,n) ) ) / anorm ) / ulp
286  ELSE
287  result( 1 ) = zero
288  END IF
289 *
290 * Compute T*Q - Z'*B
291 *
292  CALL cgemm( 'Conjugate transpose', 'No transpose', p, n, p, cone,
293  $ z, ldb, b, ldb, czero, bwk, ldb )
294  CALL cgemm( 'No transpose', 'No transpose', p, n, n, cone, t, ldb,
295  $ q, lda, -cone, bwk, ldb )
296 *
297 * Compute norm( T*Q - Z'*B ) / ( MAX(P,N)*norm(A)*ULP ) .
298 *
299  resid = clange( '1', p, n, bwk, ldb, rwork )
300  IF( bnorm.GT.zero ) THEN
301  result( 2 ) = ( ( resid / real( max( 1,p,m ) ) )/bnorm ) / ulp
302  ELSE
303  result( 2 ) = zero
304  END IF
305 *
306 * Compute I - Q*Q'
307 *
308  CALL claset( 'Full', n, n, czero, cone, r, lda )
309  CALL cherk( 'Upper', 'No Transpose', n, n, -one, q, lda, one, r,
310  $ lda )
311 *
312 * Compute norm( I - Q'*Q ) / ( N * ULP ) .
313 *
314  resid = clanhe( '1', 'Upper', n, r, lda, rwork )
315  result( 3 ) = ( resid / real( max( 1,n ) ) ) / ulp
316 *
317 * Compute I - Z'*Z
318 *
319  CALL claset( 'Full', p, p, czero, cone, t, ldb )
320  CALL cherk( 'Upper', 'Conjugate transpose', p, p, -one, z, ldb,
321  $ one, t, ldb )
322 *
323 * Compute norm( I - Z'*Z ) / ( P*ULP ) .
324 *
325  resid = clanhe( '1', 'Upper', p, t, ldb, rwork )
326  result( 4 ) = ( resid / real( max( 1,p ) ) ) / ulp
327 *
328  RETURN
329 *
330 * End of CGRQTS
331 *
332  END
subroutine cgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
CGEMM
Definition: cgemm.f:187
subroutine cherk(UPLO, TRANS, N, K, ALPHA, A, LDA, BETA, C, LDC)
CHERK
Definition: cherk.f:173
subroutine cgrqts(M, P, N, A, AF, Q, R, LDA, TAUA, B, BF, Z, T, BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT)
CGRQTS
Definition: cgrqts.f:176
subroutine claset(UPLO, M, N, ALPHA, BETA, A, LDA)
CLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition: claset.f:106
subroutine clacpy(UPLO, M, N, A, LDA, B, LDB)
CLACPY copies all or part of one two-dimensional array to another.
Definition: clacpy.f:103
subroutine cggrqf(M, P, N, A, LDA, TAUA, B, LDB, TAUB, WORK, LWORK, INFO)
CGGRQF
Definition: cggrqf.f:214
subroutine cungqr(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
CUNGQR
Definition: cungqr.f:128
subroutine cungrq(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
CUNGRQ
Definition: cungrq.f:128