schksy_rook.f

Go to the documentation of this file.

*> \brief \b SCHKSY_ROOK
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE SCHKSY_ROOK( DOTYPE, NN, NVAL, NNB, NBVAL, NNS, NSVAL,
*                          THRESH, TSTERR, NMAX, A, AFAC, AINV, B, X,
*                          XACT, WORK, RWORK, IWORK, NOUT )
*
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NMAX, NN, NNB, NNS, NOUT
*       REAL               THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            IWORK( * ), NBVAL( * ), NSVAL( * ), NVAL( * )
*       REAL               A( * ), AFAC( * ), AINV( * ), B( * ),
*      $                   RWORK( * ), WORK( * ), X( * ), XACT( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SCHKSY_ROOK tests SSYTRF_ROOK, -TRI_ROOK, -TRS_ROOK,
*> and -CON_ROOK.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix dimension N.
*> \endverbatim
*>
*> \param[in] NNB
*> \verbatim
*>          NNB is INTEGER
*>          The number of values of NB contained in the vector NBVAL.
*> \endverbatim
*>
*> \param[in] NBVAL
*> \verbatim
*>          NBVAL is INTEGER array, dimension (NNB)
*>          The values of the blocksize NB.
*> \endverbatim
*>
*> \param[in] NNS
*> \verbatim
*>          NNS is INTEGER
*>          The number of values of NRHS contained in the vector NSVAL.
*> \endverbatim
*>
*> \param[in] NSVAL
*> \verbatim
*>          NSVAL is INTEGER array, dimension (NNS)
*>          The values of the number of right hand sides NRHS.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is REAL
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[in] NMAX
*> \verbatim
*>          NMAX is INTEGER
*>          The maximum value permitted for N, used in dimensioning the
*>          work arrays.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is REAL array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] AFAC
*> \verbatim
*>          AFAC is REAL array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] AINV
*> \verbatim
*>          AINV is REAL array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] B
*> \verbatim
*>          B is REAL array, dimension (NMAX*NSMAX)
*>          where NSMAX is the largest entry in NSVAL.
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*>          X is REAL array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] XACT
*> \verbatim
*>          XACT is REAL array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (NMAX*max(3,NSMAX))
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension (max(NMAX,2*NSMAX))
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (2*NMAX)
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup single_lin
*
*  =====================================================================
      SUBROUTINE schksy_rook( DOTYPE, NN, NVAL, NNB, NBVAL, NNS, NSVAL,
     $                   THRESH, TSTERR, NMAX, A, AFAC, AINV, B, X,
     $                   XACT, WORK, RWORK, IWORK, NOUT )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NMAX, NN, NNB, NNS, NOUT
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            IWORK( * ), NBVAL( * ), NSVAL( * ), NVAL( * )
      REAL               A( * ), AFAC( * ), AINV( * ), B( * ),
     $                   rwork( * ), work( * ), x( * ), xact( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      PARAMETER          ( ZERO = 0.0d+0, one = 1.0d+0 )
      REAL               EIGHT, SEVTEN
      parameter( eight = 8.0d+0, sevten = 17.0d+0 )
      INTEGER            NTYPES
      parameter( ntypes = 10 )
      INTEGER            NTESTS
      parameter( ntests = 7 )
*     ..
*     .. Local Scalars ..
      LOGICAL            TRFCON, ZEROT
      CHARACTER          DIST, TYPE, UPLO, XTYPE
      CHARACTER*3        PATH, MATPATH
      INTEGER            I, I1, I2, IMAT, IN, INB, INFO, IOFF, IRHS,
     $                   iuplo, izero, j, k, kl, ku, lda, lwork, mode,
     $                   n, nb, nerrs, nfail, nimat, nrhs, nrun, nt
      REAL               ALPHA, ANORM, CNDNUM, CONST, SING_MAX,
     $                   SING_MIN, RCOND, RCONDC, STEMP
*     ..
*     .. Local Arrays ..
      CHARACTER          UPLOS( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      REAL               BLOCK( 2, 2 ), RESULT( NTESTS ), SDUMMY( 1 )
*     ..
*     .. External Functions ..
      REAL               SGET06, SLANGE, SLANSY
      EXTERNAL           SGET06, SLANGE, SLANSY
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, serrsy, sget04, slacpy,
     $                   slarhs, slatb4, slatms, spot02, spot03, sgesvd,
     $                   ssycon_rook, ssyt01_rook, ssytrf_rook,
     $                   ssytri_rook, ssytrs_rook, xlaenv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, sqrt
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      alpha = ( one+sqrt( sevten ) ) / eight
*
*     Test path
*
      path( 1: 1 ) = 'Single precision'
      path( 2: 3 ) = 'SR'
*
*     Path to generate matrices
*
      matpath( 1: 1 ) = 'Single precision'
      matpath( 2: 3 ) = 'SY'
*
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL serrsy( path, nout )
      infot = 0
*
*     Set the minimum block size for which the block routine should
*     be used, which will be later returned by ILAENV
*
      CALL xlaenv( 2, 2 )
*
*     Do for each value of N in NVAL
*
      DO 270 in = 1, nn
         n = nval( in )
         lda = max( n, 1 )
         xtype = 'N'
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         izero = 0
*
*        Do for each value of matrix type IMAT
*
         DO 260 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 260
*
*           Skip types 3, 4, 5, or 6 if the matrix size is too small.
*
            zerot = imat.GE.3 .AND. imat.LE.6
            IF( zerot .AND. n.LT.imat-2 )
     $         GO TO 260
*
*           Do first for UPLO = 'U', then for UPLO = 'L'
*
            DO 250 iuplo = 1, 2
               uplo = uplos( iuplo )
*
*              Begin generate the test matrix A.
*
*              Set up parameters with SLATB4 for the matrix generator
*              based on the type of matrix to be generated.
*
               CALL slatb4( matpath, imat, n, n, TYPE, kl, ku, anorm,
     $                      mode, cndnum, dist )
*
*              Generate a matrix with SLATMS.
*
               srnamt = 'SLATMS'
               CALL slatms( n, n, dist, iseed, TYPE, rwork, mode,
     $                      cndnum, anorm, kl, ku, uplo, a, lda, work,
     $                      info )
*
*              Check error code from SLATMS and handle error.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'SLATMS', info, 0, uplo, n, n, -1,
     $                         -1, -1, imat, nfail, nerrs, nout )
*
*                 Skip all tests for this generated matrix
*
                  GO TO 250
               END IF
*
*              For matrix types 3-6, zero one or more rows and
*              columns of the matrix to test that INFO is returned
*              correctly.
*
               IF( zerot ) THEN
                  IF( imat.EQ.3 ) THEN
                     izero = 1
                  ELSE IF( imat.EQ.4 ) THEN
                     izero = n
                  ELSE
                     izero = n / 2 + 1
                  END IF
*
                  IF( imat.LT.6 ) THEN
*
*                    Set row and column IZERO to zero.
*
                     IF( iuplo.EQ.1 ) THEN
                        ioff = ( izero-1 )*lda
                        DO 20 i = 1, izero - 1
                           a( ioff+i ) = zero
   20                   CONTINUE
                        ioff = ioff + izero
                        DO 30 i = izero, n
                           a( ioff ) = zero
                           ioff = ioff + lda
   30                   CONTINUE
                     ELSE
                        ioff = izero
                        DO 40 i = 1, izero - 1
                           a( ioff ) = zero
                           ioff = ioff + lda
   40                   CONTINUE
                        ioff = ioff - izero
                        DO 50 i = izero, n
                           a( ioff+i ) = zero
   50                   CONTINUE
                     END IF
                  ELSE
                     IF( iuplo.EQ.1 ) THEN
*
*                       Set the first IZERO rows and columns to zero.
*
                        ioff = 0
                        DO 70 j = 1, n
                           i2 = min( j, izero )
                           DO 60 i = 1, i2
                              a( ioff+i ) = zero
   60                      CONTINUE
                           ioff = ioff + lda
   70                   CONTINUE
                     ELSE
*
*                       Set the last IZERO rows and columns to zero.
*
                        ioff = 0
                        DO 90 j = 1, n
                           i1 = max( j, izero )
                           DO 80 i = i1, n
                              a( ioff+i ) = zero
   80                      CONTINUE
                           ioff = ioff + lda
   90                   CONTINUE
                     END IF
                  END IF
               ELSE
                  izero = 0
               END IF
*
*              End generate the test matrix A.
*
*
*              Do for each value of NB in NBVAL
*
               DO 240 inb = 1, nnb
*
*                 Set the optimal blocksize, which will be later
*                 returned by ILAENV.
*
                  nb = nbval( inb )
                  CALL xlaenv( 1, nb )
*
*                 Copy the test matrix A into matrix AFAC which
*                 will be factorized in place. This is needed to
*                 preserve the test matrix A for subsequent tests.
*
                  CALL slacpy( uplo, n, n, a, lda, afac, lda )
*
*                 Compute the L*D*L**T or U*D*U**T factorization of the
*                 matrix. IWORK stores details of the interchanges and
*                 the block structure of D. AINV is a work array for
*                 block factorization, LWORK is the length of AINV.
*
                  lwork = max( 2, nb )*lda
                  srnamt = 'SSYTRF_ROOK'
                  CALL ssytrf_rook( uplo, n, afac, lda, iwork, ainv,
     $                              lwork, info )
*
*                 Adjust the expected value of INFO to account for
*                 pivoting.
*
                  k = izero
                  IF( k.GT.0 ) THEN
  100                CONTINUE
                     IF( iwork( k ).LT.0 ) THEN
                        IF( iwork( k ).NE.-k ) THEN
                           k = -iwork( k )
                           GO TO 100
                        END IF
                     ELSE IF( iwork( k ).NE.k ) THEN
                        k = iwork( k )
                        GO TO 100
                     END IF
                  END IF
*
*                 Check error code from SSYTRF_ROOK and handle error.
*
                  IF( info.NE.k)
     $               CALL alaerh( path, 'SSYTRF_ROOK', info, k,
     $                            uplo, n, n, -1, -1, nb, imat,
     $                            nfail, nerrs, nout )
*
*                 Set the condition estimate flag if the INFO is not 0.
*
                  IF( info.NE.0 ) THEN
                     trfcon = .true.
                  ELSE
                     trfcon = .false.
                  END IF
*
*+    TEST 1
*                 Reconstruct matrix from factors and compute residual.
*
                  CALL ssyt01_rook( uplo, n, a, lda, afac, lda, iwork,
     $                              ainv, lda, rwork, result( 1 ) )
                  nt = 1
*
*+    TEST 2
*                 Form the inverse and compute the residual,
*                 if the factorization was competed without INFO > 0
*                 (i.e. there is no zero rows and columns).
*                 Do it only for the first block size.
*
                  IF( inb.EQ.1 .AND. .NOT.trfcon ) THEN
                     CALL slacpy( uplo, n, n, afac, lda, ainv, lda )
                     srnamt = 'SSYTRI_ROOK'
                     CALL ssytri_rook( uplo, n, ainv, lda, iwork, work,
     $                                 info )
*
*                    Check error code from SSYTRI_ROOK and handle error.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'SSYTRI_ROOK', info, -1,
     $                               uplo, n, n, -1, -1, -1, imat,
     $                               nfail, nerrs, nout )
*
*                    Compute the residual for a symmetric matrix times
*                    its inverse.
*
                     CALL spot03( uplo, n, a, lda, ainv, lda, work, lda,
     $                            rwork, rcondc, result( 2 ) )
                     nt = 2
                  END IF
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  DO 110 k = 1, nt
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9999 )uplo, n, nb, imat, k,
     $                     result( k )
                        nfail = nfail + 1
                     END IF
  110             CONTINUE
                  nrun = nrun + nt
*
*+    TEST 3
*                 Compute largest element in U or L
*
                  result( 3 ) = zero
                  stemp = zero
*
                  const = one / ( one-alpha )
*
                  IF( iuplo.EQ.1 ) THEN
*
*                 Compute largest element in U
*
                     k = n
  120                CONTINUE
                     IF( k.LE.1 )
     $                  GO TO 130
*
                     IF( iwork( k ).GT.zero ) THEN
*
*                       Get max absolute value from elements
*                       in column k in in U
*
                        stemp = slange( 'M', k-1, 1,
     $                          afac( ( k-1 )*lda+1 ), lda, rwork )
                     ELSE
*
*                       Get max absolute value from elements
*                       in columns k and k-1 in U
*
                        stemp = slange( 'M', k-2, 2,
     $                          afac( ( k-2 )*lda+1 ), lda, rwork )
                        k = k - 1
*
                     END IF
*
*                    STEMP should be bounded by CONST
*
                     stemp = stemp - const + thresh
                     IF( stemp.GT.result( 3 ) )
     $                  result( 3 ) = stemp
*
                     k = k - 1
*
                     GO TO 120
  130                CONTINUE
*
                  ELSE
*
*                 Compute largest element in L
*
                     k = 1
  140                CONTINUE
                     IF( k.GE.n )
     $                  GO TO 150
*
                     IF( iwork( k ).GT.zero ) THEN
*
*                       Get max absolute value from elements
*                       in column k in in L
*
                        stemp = slange( 'M', n-k, 1,
     $                          afac( ( k-1 )*lda+k+1 ), lda, rwork )
                     ELSE
*
*                       Get max absolute value from elements
*                       in columns k and k+1 in L
*
                        stemp = slange( 'M', n-k-1, 2,
     $                          afac( ( k-1 )*lda+k+2 ), lda, rwork )
                        k = k + 1
*
                     END IF
*
*                    STEMP should be bounded by CONST
*
                     stemp = stemp - const + thresh
                     IF( stemp.GT.result( 3 ) )
     $                  result( 3 ) = stemp
*
                     k = k + 1
*
                     GO TO 140
  150                CONTINUE
                  END IF
*
*
*+    TEST 4
*                 Compute largest 2-Norm (condition number)
*                 of 2-by-2 diag blocks
*
                  result( 4 ) = zero
                  stemp = zero
*
                  const = ( one+alpha ) / ( one-alpha )
                  CALL slacpy( uplo, n, n, afac, lda, ainv, lda )
*
                  IF( iuplo.EQ.1 ) THEN
*
*                    Loop backward for UPLO = 'U'
*
                     k = n
  160                CONTINUE
                     IF( k.LE.1 )
     $                  GO TO 170
*
                     IF( iwork( k ).LT.zero ) THEN
*
*                       Get the two singular values
*                       (real and non-negative) of a 2-by-2 block,
*                       store them in RWORK array
*
                        block( 1, 1 ) = afac( ( k-2 )*lda+k-1 )
                        block( 1, 2 ) = afac( (k-1)*lda+k-1 )
                        block( 2, 1 ) = block( 1, 2 )
                        block( 2, 2 ) = afac( (k-1)*lda+k )
*
                        CALL sgesvd( 'N', 'N', 2, 2, block, 2, rwork,
     $                               sdummy, 1, sdummy, 1,
     $                               work, 10, info )
*
*
                        sing_max = rwork( 1 )
                        sing_min = rwork( 2 )
*
                        stemp = sing_max / sing_min
*
*                       STEMP should be bounded by CONST
*
                        stemp = stemp - const + thresh
                        IF( stemp.GT.result( 4 ) )
     $                     result( 4 ) = stemp
                        k = k - 1
*
                     END IF
*
                     k = k - 1
*
                     GO TO 160
  170                CONTINUE
*
                  ELSE
*
*                    Loop forward for UPLO = 'L'
*
                     k = 1
  180                CONTINUE
                     IF( k.GE.n )
     $                  GO TO 190
*
                     IF( iwork( k ).LT.zero ) THEN
*
*                       Get the two singular values
*                       (real and non-negative) of a 2-by-2 block,
*                       store them in RWORK array
*
                        block( 1, 1 ) = afac( ( k-1 )*lda+k )
                        block( 2, 1 ) = afac( ( k-1 )*lda+k+1 )
                        block( 1, 2 ) = block( 2, 1 )
                        block( 2, 2 ) = afac( k*lda+k+1 )
*
                        CALL sgesvd( 'N', 'N', 2, 2, block, 2, rwork,
     $                               sdummy, 1, sdummy, 1,
     $                               work, 10, info )
*
*
                        sing_max = rwork( 1 )
                        sing_min = rwork( 2 )
*
                        stemp = sing_max / sing_min
*
*                       STEMP should be bounded by CONST
*
                        stemp = stemp - const + thresh
                        IF( stemp.GT.result( 4 ) )
     $                     result( 4 ) = stemp
                        k = k + 1
*
                     END IF
*
                     k = k + 1
*
                     GO TO 180
  190                CONTINUE
                  END IF
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  DO 200 k = 3, 4
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9999 )uplo, n, nb, imat, k,
     $                     result( k )
                        nfail = nfail + 1
                     END IF
  200             CONTINUE
                  nrun = nrun + 2
*
*                 Skip the other tests if this is not the first block
*                 size.
*
                  IF( inb.GT.1 )
     $               GO TO 240
*
*                 Do only the condition estimate if INFO is not 0.
*
                  IF( trfcon ) THEN
                     rcondc = zero
                     GO TO 230
                  END IF
*
*                 Do for each value of NRHS in NSVAL.
*
                  DO 220 irhs = 1, nns
                     nrhs = nsval( irhs )
*
*+    TEST 5 ( Using TRS_ROOK)
*                 Solve and compute residual for  A * X = B.
*
*                    Choose a set of NRHS random solution vectors
*                    stored in XACT and set up the right hand side B
*
                     srnamt = 'SLARHS'
                     CALL slarhs( matpath, xtype, uplo, ' ', n, n,
     $                            kl, ku, nrhs, a, lda, xact, lda,
     $                            b, lda, iseed, info )
                     CALL slacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                     srnamt = 'SSYTRS_ROOK'
                     CALL ssytrs_rook( uplo, n, nrhs, afac, lda, iwork,
     $                                 x, lda, info )
*
*                    Check error code from SSYTRS_ROOK and handle error.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'SSYTRS_ROOK', info, 0,
     $                               uplo, n, n, -1, -1, nrhs, imat,
     $                               nfail, nerrs, nout )
*
                     CALL slacpy( 'Full', n, nrhs, b, lda, work, lda )
*
*                    Compute the residual for the solution
*
                     CALL spot02( uplo, n, nrhs, a, lda, x, lda, work,
     $                            lda, rwork, result( 5 ) )
*
*+    TEST 6
*                 Check solution from generated exact solution.
*
                     CALL sget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                            result( 6 ) )
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     DO 210 k = 5, 6
                        IF( result( k ).GE.thresh ) THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL alahd( nout, path )
                           WRITE( nout, fmt = 9998 )uplo, n, nrhs,
     $                        imat, k, result( k )
                           nfail = nfail + 1
                        END IF
  210                CONTINUE
                     nrun = nrun + 2
*
*                 End do for each value of NRHS in NSVAL.
*
  220             CONTINUE
*
*+    TEST 7
*                 Get an estimate of RCOND = 1/CNDNUM.
*
  230             CONTINUE
                  anorm = slansy( '1', uplo, n, a, lda, rwork )
                  srnamt = 'SSYCON_ROOK'
                  CALL ssycon_rook( uplo, n, afac, lda, iwork, anorm,
     $                              rcond, work, iwork( n+1 ), info )
*
*                 Check error code from SSYCON_ROOK and handle error.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'SSYCON_ROOK', info, 0,
     $                             uplo, n, n, -1, -1, -1, imat,
     $                             nfail, nerrs, nout )
*
*                 Compute the test ratio to compare values of RCOND
*
                  result( 7 ) = sget06( rcond, rcondc )
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  IF( result( 7 ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9997 )uplo, n, imat, 7,
     $                  result( 7 )
                     nfail = nfail + 1
                  END IF
                  nrun = nrun + 1
  240          CONTINUE
*
  250       CONTINUE
  260    CONTINUE
  270 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', NB =', i4, ', type ',
     $      i2, ', test ', i2, ', ratio =', g12.5 )
 9998 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', NRHS=', i3, ', type ',
     $      i2, ', test(', i2, ') =', g12.5 )
 9997 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ',', 10x, ' type ', i2,
     $      ', test(', i2, ') =', g12.5 )
      RETURN
*
*     End of SCHKSY_ROOK
*
      END