LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
ssytrf_rook.f
Go to the documentation of this file.
1*> \brief \b SSYTRF_ROOK
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download SSYTRF_ROOK + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/ssytrf_rook.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/ssytrf_rook.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/ssytrf_rook.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE SSYTRF_ROOK( UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO )
22*
23* .. Scalar Arguments ..
24* CHARACTER UPLO
25* INTEGER INFO, LDA, LWORK, N
26* ..
27* .. Array Arguments ..
28* INTEGER IPIV( * )
29* REAL A( LDA, * ), WORK( * )
30* ..
31*
32*
33*> \par Purpose:
34* =============
35*>
36*> \verbatim
37*>
38*> SSYTRF_ROOK computes the factorization of a real symmetric matrix A
39*> using the bounded Bunch-Kaufman ("rook") diagonal pivoting method.
40*> The form of the factorization is
41*>
42*> A = U*D*U**T or A = L*D*L**T
43*>
44*> where U (or L) is a product of permutation and unit upper (lower)
45*> triangular matrices, and D is symmetric and block diagonal with
46*> 1-by-1 and 2-by-2 diagonal blocks.
47*>
48*> This is the blocked version of the algorithm, calling Level 3 BLAS.
49*> \endverbatim
50*
51* Arguments:
52* ==========
53*
54*> \param[in] UPLO
55*> \verbatim
56*> UPLO is CHARACTER*1
57*> = 'U': Upper triangle of A is stored;
58*> = 'L': Lower triangle of A is stored.
59*> \endverbatim
60*>
61*> \param[in] N
62*> \verbatim
63*> N is INTEGER
64*> The order of the matrix A. N >= 0.
65*> \endverbatim
66*>
67*> \param[in,out] A
68*> \verbatim
69*> A is REAL array, dimension (LDA,N)
70*> On entry, the symmetric matrix A. If UPLO = 'U', the leading
71*> N-by-N upper triangular part of A contains the upper
72*> triangular part of the matrix A, and the strictly lower
73*> triangular part of A is not referenced. If UPLO = 'L', the
74*> leading N-by-N lower triangular part of A contains the lower
75*> triangular part of the matrix A, and the strictly upper
76*> triangular part of A is not referenced.
77*>
78*> On exit, the block diagonal matrix D and the multipliers used
79*> to obtain the factor U or L (see below for further details).
80*> \endverbatim
81*>
82*> \param[in] LDA
83*> \verbatim
84*> LDA is INTEGER
85*> The leading dimension of the array A. LDA >= max(1,N).
86*> \endverbatim
87*>
88*> \param[out] IPIV
89*> \verbatim
90*> IPIV is INTEGER array, dimension (N)
91*> Details of the interchanges and the block structure of D.
92*>
93*> If UPLO = 'U':
94*> If IPIV(k) > 0, then rows and columns k and IPIV(k)
95*> were interchanged and D(k,k) is a 1-by-1 diagonal block.
96*>
97*> If IPIV(k) < 0 and IPIV(k-1) < 0, then rows and
98*> columns k and -IPIV(k) were interchanged and rows and
99*> columns k-1 and -IPIV(k-1) were inerchaged,
100*> D(k-1:k,k-1:k) is a 2-by-2 diagonal block.
101*>
102*> If UPLO = 'L':
103*> If IPIV(k) > 0, then rows and columns k and IPIV(k)
104*> were interchanged and D(k,k) is a 1-by-1 diagonal block.
105*>
106*> If IPIV(k) < 0 and IPIV(k+1) < 0, then rows and
107*> columns k and -IPIV(k) were interchanged and rows and
108*> columns k+1 and -IPIV(k+1) were inerchaged,
109*> D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
110*> \endverbatim
111*>
112*> \param[out] WORK
113*> \verbatim
114*> WORK is REAL array, dimension (MAX(1,LWORK)).
115*> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
116*> \endverbatim
117*>
118*> \param[in] LWORK
119*> \verbatim
120*> LWORK is INTEGER
121*> The length of WORK. LWORK >=1. For best performance
122*> LWORK >= N*NB, where NB is the block size returned by ILAENV.
123*>
124*> If LWORK = -1, then a workspace query is assumed; the routine
125*> only calculates the optimal size of the WORK array, returns
126*> this value as the first entry of the WORK array, and no error
127*> message related to LWORK is issued by XERBLA.
128*> \endverbatim
129*>
130*> \param[out] INFO
131*> \verbatim
132*> INFO is INTEGER
133*> = 0: successful exit
134*> < 0: if INFO = -i, the i-th argument had an illegal value
135*> > 0: if INFO = i, D(i,i) is exactly zero. The factorization
136*> has been completed, but the block diagonal matrix D is
137*> exactly singular, and division by zero will occur if it
138*> is used to solve a system of equations.
139*> \endverbatim
140*
141* Authors:
142* ========
143*
144*> \author Univ. of Tennessee
145*> \author Univ. of California Berkeley
146*> \author Univ. of Colorado Denver
147*> \author NAG Ltd.
148*
149*> \ingroup hetrf_rook
150*
151*> \par Further Details:
152* =====================
153*>
154*> \verbatim
155*>
156*> If UPLO = 'U', then A = U*D*U**T, where
157*> U = P(n)*U(n)* ... *P(k)U(k)* ...,
158*> i.e., U is a product of terms P(k)*U(k), where k decreases from n to
159*> 1 in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
160*> and 2-by-2 diagonal blocks D(k). P(k) is a permutation matrix as
161*> defined by IPIV(k), and U(k) is a unit upper triangular matrix, such
162*> that if the diagonal block D(k) is of order s (s = 1 or 2), then
163*>
164*> ( I v 0 ) k-s
165*> U(k) = ( 0 I 0 ) s
166*> ( 0 0 I ) n-k
167*> k-s s n-k
168*>
169*> If s = 1, D(k) overwrites A(k,k), and v overwrites A(1:k-1,k).
170*> If s = 2, the upper triangle of D(k) overwrites A(k-1,k-1), A(k-1,k),
171*> and A(k,k), and v overwrites A(1:k-2,k-1:k).
172*>
173*> If UPLO = 'L', then A = L*D*L**T, where
174*> L = P(1)*L(1)* ... *P(k)*L(k)* ...,
175*> i.e., L is a product of terms P(k)*L(k), where k increases from 1 to
176*> n in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
177*> and 2-by-2 diagonal blocks D(k). P(k) is a permutation matrix as
178*> defined by IPIV(k), and L(k) is a unit lower triangular matrix, such
179*> that if the diagonal block D(k) is of order s (s = 1 or 2), then
180*>
181*> ( I 0 0 ) k-1
182*> L(k) = ( 0 I 0 ) s
183*> ( 0 v I ) n-k-s+1
184*> k-1 s n-k-s+1
185*>
186*> If s = 1, D(k) overwrites A(k,k), and v overwrites A(k+1:n,k).
187*> If s = 2, the lower triangle of D(k) overwrites A(k,k), A(k+1,k),
188*> and A(k+1,k+1), and v overwrites A(k+2:n,k:k+1).
189*> \endverbatim
190*
191*> \par Contributors:
192* ==================
193*>
194*> \verbatim
195*>
196*> June 2016, Igor Kozachenko,
197*> Computer Science Division,
198*> University of California, Berkeley
199*>
200*> September 2007, Sven Hammarling, Nicholas J. Higham, Craig Lucas,
201*> School of Mathematics,
202*> University of Manchester
203*>
204*> \endverbatim
205*
206* =====================================================================
207 SUBROUTINE ssytrf_rook( UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO )
208*
209* -- LAPACK computational routine --
210* -- LAPACK is a software package provided by Univ. of Tennessee, --
211* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
212*
213* .. Scalar Arguments ..
214 CHARACTER UPLO
215 INTEGER INFO, LDA, LWORK, N
216* ..
217* .. Array Arguments ..
218 INTEGER IPIV( * )
219 REAL A( LDA, * ), WORK( * )
220* ..
221*
222* =====================================================================
223*
224* .. Local Scalars ..
225 LOGICAL LQUERY, UPPER
226 INTEGER IINFO, IWS, J, K, KB, LDWORK, LWKOPT, NB, NBMIN
227* ..
228* .. External Functions ..
229 LOGICAL LSAME
230 INTEGER ILAENV
231 REAL SROUNDUP_LWORK
232 EXTERNAL lsame, ilaenv, sroundup_lwork
233* ..
234* .. External Subroutines ..
236* ..
237* .. Intrinsic Functions ..
238 INTRINSIC max
239* ..
240* .. Executable Statements ..
241*
242* Test the input parameters.
243*
244 info = 0
245 upper = lsame( uplo, 'U' )
246 lquery = ( lwork.EQ.-1 )
247 IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
248 info = -1
249 ELSE IF( n.LT.0 ) THEN
250 info = -2
251 ELSE IF( lda.LT.max( 1, n ) ) THEN
252 info = -4
253 ELSE IF( lwork.LT.1 .AND. .NOT.lquery ) THEN
254 info = -7
255 END IF
256*
257 IF( info.EQ.0 ) THEN
258*
259* Determine the block size
260*
261 nb = ilaenv( 1, 'SSYTRF_ROOK', uplo, n, -1, -1, -1 )
262 lwkopt = max( 1, n*nb )
263 work( 1 ) = sroundup_lwork(lwkopt)
264 END IF
265*
266 IF( info.NE.0 ) THEN
267 CALL xerbla( 'SSYTRF_ROOK', -info )
268 RETURN
269 ELSE IF( lquery ) THEN
270 RETURN
271 END IF
272*
273 nbmin = 2
274 ldwork = n
275 IF( nb.GT.1 .AND. nb.LT.n ) THEN
276 iws = ldwork*nb
277 IF( lwork.LT.iws ) THEN
278 nb = max( lwork / ldwork, 1 )
279 nbmin = max( 2, ilaenv( 2, 'SSYTRF_ROOK',
280 $ uplo, n, -1, -1, -1 ) )
281 END IF
282 ELSE
283 iws = 1
284 END IF
285 IF( nb.LT.nbmin )
286 $ nb = n
287*
288 IF( upper ) THEN
289*
290* Factorize A as U*D*U**T using the upper triangle of A
291*
292* K is the main loop index, decreasing from N to 1 in steps of
293* KB, where KB is the number of columns factorized by SLASYF_ROOK;
294* KB is either NB or NB-1, or K for the last block
295*
296 k = n
297 10 CONTINUE
298*
299* If K < 1, exit from loop
300*
301 IF( k.LT.1 )
302 $ GO TO 40
303*
304 IF( k.GT.nb ) THEN
305*
306* Factorize columns k-kb+1:k of A and use blocked code to
307* update columns 1:k-kb
308*
309 CALL slasyf_rook( uplo, k, nb, kb, a, lda,
310 $ ipiv, work, ldwork, iinfo )
311 ELSE
312*
313* Use unblocked code to factorize columns 1:k of A
314*
315 CALL ssytf2_rook( uplo, k, a, lda, ipiv, iinfo )
316 kb = k
317 END IF
318*
319* Set INFO on the first occurrence of a zero pivot
320*
321 IF( info.EQ.0 .AND. iinfo.GT.0 )
322 $ info = iinfo
323*
324* No need to adjust IPIV
325*
326* Decrease K and return to the start of the main loop
327*
328 k = k - kb
329 GO TO 10
330*
331 ELSE
332*
333* Factorize A as L*D*L**T using the lower triangle of A
334*
335* K is the main loop index, increasing from 1 to N in steps of
336* KB, where KB is the number of columns factorized by SLASYF_ROOK;
337* KB is either NB or NB-1, or N-K+1 for the last block
338*
339 k = 1
340 20 CONTINUE
341*
342* If K > N, exit from loop
343*
344 IF( k.GT.n )
345 $ GO TO 40
346*
347 IF( k.LE.n-nb ) THEN
348*
349* Factorize columns k:k+kb-1 of A and use blocked code to
350* update columns k+kb:n
351*
352 CALL slasyf_rook( uplo, n-k+1, nb, kb, a( k, k ), lda,
353 $ ipiv( k ), work, ldwork, iinfo )
354 ELSE
355*
356* Use unblocked code to factorize columns k:n of A
357*
358 CALL ssytf2_rook( uplo, n-k+1, a( k, k ), lda, ipiv( k ),
359 $ iinfo )
360 kb = n - k + 1
361 END IF
362*
363* Set INFO on the first occurrence of a zero pivot
364*
365 IF( info.EQ.0 .AND. iinfo.GT.0 )
366 $ info = iinfo + k - 1
367*
368* Adjust IPIV
369*
370 DO 30 j = k, k + kb - 1
371 IF( ipiv( j ).GT.0 ) THEN
372 ipiv( j ) = ipiv( j ) + k - 1
373 ELSE
374 ipiv( j ) = ipiv( j ) - k + 1
375 END IF
376 30 CONTINUE
377*
378* Increase K and return to the start of the main loop
379*
380 k = k + kb
381 GO TO 20
382*
383 END IF
384*
385 40 CONTINUE
386 work( 1 ) = sroundup_lwork(lwkopt)
387 RETURN
388*
389* End of SSYTRF_ROOK
390*
391 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine ssytf2_rook(uplo, n, a, lda, ipiv, info)
SSYTF2_ROOK computes the factorization of a real symmetric indefinite matrix using the bounded Bunch-...
subroutine ssytrf_rook(uplo, n, a, lda, ipiv, work, lwork, info)
SSYTRF_ROOK
subroutine slasyf_rook(uplo, n, nb, kb, a, lda, ipiv, w, ldw, info)
SLASYF_ROOK computes a partial factorization of a real symmetric matrix using the bounded Bunch-Kaufm...