sget04()

subroutine sget04	(	integer	n,
		integer	nrhs,
		real, dimension( ldx, * )	x,
		integer	ldx,
		real, dimension( ldxact, * )	xact,
		integer	ldxact,
		real	rcond,
		real	resid )

SGET04

Purpose:

!>
!> SGET04 computes the difference between a computed solution and the
!> true solution to a system of linear equations.
!>
!> RESID =  ( norm(X-XACT) * RCOND ) / ( norm(XACT) * EPS ),
!> where RCOND is the reciprocal of the condition number and EPS is the
!> machine epsilon.
!> 

Parameters

[in]	N	!> N is INTEGER !> The number of rows of the matrices X and XACT. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of columns of the matrices X and XACT. NRHS >= 0. !>
[in]	X	!> X is REAL array, dimension (LDX,NRHS) !> The computed solution vectors. Each vector is stored as a !> column of the matrix X. !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the array X. LDX >= max(1,N). !>
[in]	XACT	!> XACT is REAL array, dimension( LDX, NRHS ) !> The exact solution vectors. Each vector is stored as a !> column of the matrix XACT. !>
[in]	LDXACT	!> LDXACT is INTEGER !> The leading dimension of the array XACT. LDXACT >= max(1,N). !>
[in]	RCOND	!> RCOND is REAL !> The reciprocal of the condition number of the coefficient !> matrix in the system of equations. !>
[out]	RESID	!> RESID is REAL !> The maximum over the NRHS solution vectors of !> ( norm(X-XACT) * RCOND ) / ( norm(XACT) * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 101 of file sget04.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDX, LDXACT, N, NRHS
      REAL               RCOND, RESID
*     ..
*     .. Array Arguments ..
      REAL               X( LDX, * ), XACT( LDXACT, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO
      parameter( zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IX, J
      REAL               DIFFNM, EPS, XNORM
*     ..
*     .. External Functions ..
      INTEGER            ISAMAX
      REAL               SLAMCH
      EXTERNAL           isamax, slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0 or NRHS = 0.
*
      IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if RCOND is invalid.
*
      eps = slamch( 'Epsilon' )
      IF( rcond.LT.zero ) THEN
         resid = 1.0 / eps
         RETURN
      END IF
*
*     Compute the maximum of
*        norm(X - XACT) / ( norm(XACT) * EPS )
*     over all the vectors X and XACT .
*
      resid = zero
      DO 20 j = 1, nrhs
         ix = isamax( n, xact( 1, j ), 1 )
         xnorm = abs( xact( ix, j ) )
         diffnm = zero
         DO 10 i = 1, n
            diffnm = max( diffnm, abs( x( i, j )-xact( i, j ) ) )
   10    CONTINUE
         IF( xnorm.LE.zero ) THEN
            IF( diffnm.GT.zero )
     $         resid = 1.0 / eps
         ELSE
            resid = max( resid, ( diffnm / xnorm )*rcond )
         END IF
   20 CONTINUE
      IF( resid*eps.LT.1.0 )
     $   resid = resid / eps
*
      RETURN
*
*     End of SGET04
*

Here is the caller graph for this function: