001:       DOUBLE PRECISION FUNCTION ZLA_GERCOND_C( TRANS, N, A, LDA, AF, 
002:      $                                         LDAF, IPIV, C, CAPPLY,
003:      $                                         INFO, WORK, RWORK )
004: *
005: *     -- LAPACK routine (version 3.2.1)                                 --
006: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
007: *     -- Jason Riedy of Univ. of California Berkeley.                 --
008: *     -- April 2009                                                   --
009: *
010: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
011: *     -- Univ. of California Berkeley and NAG Ltd.                    --
012: *
013:       IMPLICIT NONE
014: *     ..
015: *     .. Scalar Aguments ..
016:       CHARACTER          TRANS
017:       LOGICAL            CAPPLY
018:       INTEGER            N, LDA, LDAF, INFO
019: *     ..
020: *     .. Array Arguments ..
021:       INTEGER            IPIV( * )
022:       COMPLEX*16         A( LDA, * ), AF( LDAF, * ), WORK( * )
023:       DOUBLE PRECISION   C( * ), RWORK( * )
024: *     ..
025: *
026: *  Purpose
027: *  =======
028: *
029: *     ZLA_GERCOND_C computes the infinity norm condition number of
030: *     op(A) * inv(diag(C)) where C is a DOUBLE PRECISION vector.
031: *
032: *  Arguments
033: *  =========
034: *
035: *     TRANS   (input) CHARACTER*1
036: *     Specifies the form of the system of equations:
037: *       = 'N':  A * X = B     (No transpose)
038: *       = 'T':  A**T * X = B  (Transpose)
039: *       = 'C':  A**H * X = B  (Conjugate Transpose = Transpose)
040: *
041: *     N       (input) INTEGER
042: *     The number of linear equations, i.e., the order of the
043: *     matrix A.  N >= 0.
044: *
045: *     A       (input) COMPLEX*16 array, dimension (LDA,N)
046: *     On entry, the N-by-N matrix A
047: *
048: *     LDA     (input) INTEGER
049: *     The leading dimension of the array A.  LDA >= max(1,N).
050: *
051: *     AF      (input) COMPLEX*16 array, dimension (LDAF,N)
052: *     The factors L and U from the factorization
053: *     A = P*L*U as computed by ZGETRF.
054: *
055: *     LDAF    (input) INTEGER
056: *     The leading dimension of the array AF.  LDAF >= max(1,N).
057: *
058: *     IPIV    (input) INTEGER array, dimension (N)
059: *     The pivot indices from the factorization A = P*L*U
060: *     as computed by ZGETRF; row i of the matrix was interchanged
061: *     with row IPIV(i).
062: *
063: *     C       (input) DOUBLE PRECISION array, dimension (N)
064: *     The vector C in the formula op(A) * inv(diag(C)).
065: *
066: *     CAPPLY  (input) LOGICAL
067: *     If .TRUE. then access the vector C in the formula above.
068: *
069: *     INFO    (output) INTEGER
070: *       = 0:  Successful exit.
071: *     i > 0:  The ith argument is invalid.
072: *
073: *     WORK    (input) COMPLEX*16 array, dimension (2*N).
074: *     Workspace.
075: *
076: *     RWORK   (input) DOUBLE PRECISION array, dimension (N).
077: *     Workspace.
078: *
079: *  =====================================================================
080: *
081: *     .. Local Scalars ..
082:       LOGICAL            NOTRANS
083:       INTEGER            KASE, I, J
084:       DOUBLE PRECISION   AINVNM, ANORM, TMP
085:       COMPLEX*16         ZDUM
086: *     ..
087: *     .. Local Arrays ..
088:       INTEGER            ISAVE( 3 )
089: *     ..
090: *     .. External Functions ..
091:       LOGICAL            LSAME
092:       EXTERNAL           LSAME
093: *     ..
094: *     .. External Subroutines ..
095:       EXTERNAL           ZLACN2, ZGETRS, XERBLA
096: *     ..
097: *     .. Intrinsic Functions ..
098:       INTRINSIC          ABS, MAX, REAL, DIMAG
099: *     ..
100: *     .. Statement Functions ..
101:       DOUBLE PRECISION   CABS1
102: *     ..
103: *     .. Statement Function Definitions ..
104:       CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
105: *     ..
106: *     .. Executable Statements ..
107:       ZLA_GERCOND_C = 0.0D+0
108: *
109:       INFO = 0
110:       NOTRANS = LSAME( TRANS, 'N' )
111:       IF ( .NOT. NOTRANS .AND. .NOT. LSAME( TRANS, 'T' ) .AND. .NOT.
112:      $     LSAME( TRANS, 'C' ) ) THEN
113:       ELSE IF( N.LT.0 ) THEN
114:          INFO = -2
115:       END IF
116:       IF( INFO.NE.0 ) THEN
117:          CALL XERBLA( 'ZLA_GERCOND_C', -INFO )
118:          RETURN
119:       END IF
120: *
121: *     Compute norm of op(A)*op2(C).
122: *
123:       ANORM = 0.0D+0
124:       IF ( NOTRANS ) THEN
125:          DO I = 1, N
126:             TMP = 0.0D+0
127:             IF ( CAPPLY ) THEN
128:                DO J = 1, N
129:                   TMP = TMP + CABS1( A( I, J ) ) / C( J )
130:                END DO
131:             ELSE
132:                DO J = 1, N
133:                   TMP = TMP + CABS1( A( I, J ) )
134:                END DO
135:             END IF
136:             RWORK( I ) = TMP
137:             ANORM = MAX( ANORM, TMP )
138:          END DO
139:       ELSE
140:          DO I = 1, N
141:             TMP = 0.0D+0
142:             IF ( CAPPLY ) THEN
143:                DO J = 1, N
144:                   TMP = TMP + CABS1( A( J, I ) ) / C( J )
145:                END DO
146:             ELSE
147:                DO J = 1, N
148:                   TMP = TMP + CABS1( A( J, I ) )
149:                END DO
150:             END IF
151:             RWORK( I ) = TMP
152:             ANORM = MAX( ANORM, TMP )
153:          END DO
154:       END IF
155: *
156: *     Quick return if possible.
157: *
158:       IF( N.EQ.0 ) THEN
159:          ZLA_GERCOND_C = 1.0D+0
160:          RETURN
161:       ELSE IF( ANORM .EQ. 0.0D+0 ) THEN
162:          RETURN
163:       END IF
164: *
165: *     Estimate the norm of inv(op(A)).
166: *
167:       AINVNM = 0.0D+0
168: *
169:       KASE = 0
170:    10 CONTINUE
171:       CALL ZLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
172:       IF( KASE.NE.0 ) THEN
173:          IF( KASE.EQ.2 ) THEN
174: *
175: *           Multiply by R.
176: *
177:             DO I = 1, N
178:                WORK( I ) = WORK( I ) * RWORK( I )
179:             END DO
180: *
181:             IF (NOTRANS) THEN
182:                CALL ZGETRS( 'No transpose', N, 1, AF, LDAF, IPIV,
183:      $            WORK, N, INFO )
184:             ELSE
185:                CALL ZGETRS( 'Conjugate transpose', N, 1, AF, LDAF, IPIV,
186:      $            WORK, N, INFO )
187:             ENDIF
188: *
189: *           Multiply by inv(C).
190: *
191:             IF ( CAPPLY ) THEN
192:                DO I = 1, N
193:                   WORK( I ) = WORK( I ) * C( I )
194:                END DO
195:             END IF
196:          ELSE
197: *
198: *           Multiply by inv(C').
199: *
200:             IF ( CAPPLY ) THEN
201:                DO I = 1, N
202:                   WORK( I ) = WORK( I ) * C( I )
203:                END DO
204:             END IF
205: *
206:             IF ( NOTRANS ) THEN
207:                CALL ZGETRS( 'Conjugate transpose', N, 1, AF, LDAF, IPIV,
208:      $            WORK, N, INFO )
209:             ELSE
210:                CALL ZGETRS( 'No transpose', N, 1, AF, LDAF, IPIV,
211:      $            WORK, N, INFO )
212:             END IF
213: *
214: *           Multiply by R.
215: *
216:             DO I = 1, N
217:                WORK( I ) = WORK( I ) * RWORK( I )
218:             END DO
219:          END IF
220:          GO TO 10
221:       END IF
222: *
223: *     Compute the estimate of the reciprocal condition number.
224: *
225:       IF( AINVNM .NE. 0.0D+0 )
226:      $   ZLA_GERCOND_C = 1.0D+0 / AINVNM
227: *
228:       RETURN
229: *
230:       END
231: