001:       SUBROUTINE ZLACN2( N, V, X, EST, KASE, ISAVE )
002: *
003: *  -- LAPACK auxiliary routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       INTEGER            KASE, N
010:       DOUBLE PRECISION   EST
011: *     ..
012: *     .. Array Arguments ..
013:       INTEGER            ISAVE( 3 )
014:       COMPLEX*16         V( * ), X( * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  ZLACN2 estimates the 1-norm of a square, complex matrix A.
021: *  Reverse communication is used for evaluating matrix-vector products.
022: *
023: *  Arguments
024: *  =========
025: *
026: *  N      (input) INTEGER
027: *         The order of the matrix.  N >= 1.
028: *
029: *  V      (workspace) COMPLEX*16 array, dimension (N)
030: *         On the final return, V = A*W,  where  EST = norm(V)/norm(W)
031: *         (W is not returned).
032: *
033: *  X      (input/output) COMPLEX*16 array, dimension (N)
034: *         On an intermediate return, X should be overwritten by
035: *               A * X,   if KASE=1,
036: *               A' * X,  if KASE=2,
037: *         where A' is the conjugate transpose of A, and ZLACN2 must be
038: *         re-called with all the other parameters unchanged.
039: *
040: *  EST    (input/output) DOUBLE PRECISION
041: *         On entry with KASE = 1 or 2 and ISAVE(1) = 3, EST should be
042: *         unchanged from the previous call to ZLACN2.
043: *         On exit, EST is an estimate (a lower bound) for norm(A). 
044: *
045: *  KASE   (input/output) INTEGER
046: *         On the initial call to ZLACN2, KASE should be 0.
047: *         On an intermediate return, KASE will be 1 or 2, indicating
048: *         whether X should be overwritten by A * X  or A' * X.
049: *         On the final return from ZLACN2, KASE will again be 0.
050: *
051: *  ISAVE  (input/output) INTEGER array, dimension (3)
052: *         ISAVE is used to save variables between calls to ZLACN2
053: *
054: *  Further Details
055: *  ======= =======
056: *
057: *  Contributed by Nick Higham, University of Manchester.
058: *  Originally named CONEST, dated March 16, 1988.
059: *
060: *  Reference: N.J. Higham, "FORTRAN codes for estimating the one-norm of
061: *  a real or complex matrix, with applications to condition estimation",
062: *  ACM Trans. Math. Soft., vol. 14, no. 4, pp. 381-396, December 1988.
063: *
064: *  Last modified:  April, 1999
065: *
066: *  This is a thread safe version of ZLACON, which uses the array ISAVE
067: *  in place of a SAVE statement, as follows:
068: *
069: *     ZLACON     ZLACN2
070: *      JUMP     ISAVE(1)
071: *      J        ISAVE(2)
072: *      ITER     ISAVE(3)
073: *
074: *  =====================================================================
075: *
076: *     .. Parameters ..
077:       INTEGER              ITMAX
078:       PARAMETER          ( ITMAX = 5 )
079:       DOUBLE PRECISION     ONE,         TWO
080:       PARAMETER          ( ONE = 1.0D0, TWO = 2.0D0 )
081:       COMPLEX*16           CZERO, CONE
082:       PARAMETER          ( CZERO = ( 0.0D0, 0.0D0 ),
083:      $                            CONE = ( 1.0D0, 0.0D0 ) )
084: *     ..
085: *     .. Local Scalars ..
086:       INTEGER            I, JLAST
087:       DOUBLE PRECISION   ABSXI, ALTSGN, ESTOLD, SAFMIN, TEMP
088: *     ..
089: *     .. External Functions ..
090:       INTEGER            IZMAX1
091:       DOUBLE PRECISION   DLAMCH, DZSUM1
092:       EXTERNAL           IZMAX1, DLAMCH, DZSUM1
093: *     ..
094: *     .. External Subroutines ..
095:       EXTERNAL           ZCOPY
096: *     ..
097: *     .. Intrinsic Functions ..
098:       INTRINSIC          ABS, DBLE, DCMPLX, DIMAG
099: *     ..
100: *     .. Executable Statements ..
101: *
102:       SAFMIN = DLAMCH( 'Safe minimum' )
103:       IF( KASE.EQ.0 ) THEN
104:          DO 10 I = 1, N
105:             X( I ) = DCMPLX( ONE / DBLE( N ) )
106:    10    CONTINUE
107:          KASE = 1
108:          ISAVE( 1 ) = 1
109:          RETURN
110:       END IF
111: *
112:       GO TO ( 20, 40, 70, 90, 120 )ISAVE( 1 )
113: *
114: *     ................ ENTRY   (ISAVE( 1 ) = 1)
115: *     FIRST ITERATION.  X HAS BEEN OVERWRITTEN BY A*X.
116: *
117:    20 CONTINUE
118:       IF( N.EQ.1 ) THEN
119:          V( 1 ) = X( 1 )
120:          EST = ABS( V( 1 ) )
121: *        ... QUIT
122:          GO TO 130
123:       END IF
124:       EST = DZSUM1( N, X, 1 )
125: *
126:       DO 30 I = 1, N
127:          ABSXI = ABS( X( I ) )
128:          IF( ABSXI.GT.SAFMIN ) THEN
129:             X( I ) = DCMPLX( DBLE( X( I ) ) / ABSXI,
130:      $               DIMAG( X( I ) ) / ABSXI )
131:          ELSE
132:             X( I ) = CONE
133:          END IF
134:    30 CONTINUE
135:       KASE = 2
136:       ISAVE( 1 ) = 2
137:       RETURN
138: *
139: *     ................ ENTRY   (ISAVE( 1 ) = 2)
140: *     FIRST ITERATION.  X HAS BEEN OVERWRITTEN BY CTRANS(A)*X.
141: *
142:    40 CONTINUE
143:       ISAVE( 2 ) = IZMAX1( N, X, 1 )
144:       ISAVE( 3 ) = 2
145: *
146: *     MAIN LOOP - ITERATIONS 2,3,...,ITMAX.
147: *
148:    50 CONTINUE
149:       DO 60 I = 1, N
150:          X( I ) = CZERO
151:    60 CONTINUE
152:       X( ISAVE( 2 ) ) = CONE
153:       KASE = 1
154:       ISAVE( 1 ) = 3
155:       RETURN
156: *
157: *     ................ ENTRY   (ISAVE( 1 ) = 3)
158: *     X HAS BEEN OVERWRITTEN BY A*X.
159: *
160:    70 CONTINUE
161:       CALL ZCOPY( N, X, 1, V, 1 )
162:       ESTOLD = EST
163:       EST = DZSUM1( N, V, 1 )
164: *
165: *     TEST FOR CYCLING.
166:       IF( EST.LE.ESTOLD )
167:      $   GO TO 100
168: *
169:       DO 80 I = 1, N
170:          ABSXI = ABS( X( I ) )
171:          IF( ABSXI.GT.SAFMIN ) THEN
172:             X( I ) = DCMPLX( DBLE( X( I ) ) / ABSXI,
173:      $               DIMAG( X( I ) ) / ABSXI )
174:          ELSE
175:             X( I ) = CONE
176:          END IF
177:    80 CONTINUE
178:       KASE = 2
179:       ISAVE( 1 ) = 4
180:       RETURN
181: *
182: *     ................ ENTRY   (ISAVE( 1 ) = 4)
183: *     X HAS BEEN OVERWRITTEN BY CTRANS(A)*X.
184: *
185:    90 CONTINUE
186:       JLAST = ISAVE( 2 )
187:       ISAVE( 2 ) = IZMAX1( N, X, 1 )
188:       IF( ( ABS( X( JLAST ) ).NE.ABS( X( ISAVE( 2 ) ) ) ) .AND.
189:      $    ( ISAVE( 3 ).LT.ITMAX ) ) THEN
190:          ISAVE( 3 ) = ISAVE( 3 ) + 1
191:          GO TO 50
192:       END IF
193: *
194: *     ITERATION COMPLETE.  FINAL STAGE.
195: *
196:   100 CONTINUE
197:       ALTSGN = ONE
198:       DO 110 I = 1, N
199:          X( I ) = DCMPLX( ALTSGN*( ONE+DBLE( I-1 ) / DBLE( N-1 ) ) )
200:          ALTSGN = -ALTSGN
201:   110 CONTINUE
202:       KASE = 1
203:       ISAVE( 1 ) = 5
204:       RETURN
205: *
206: *     ................ ENTRY   (ISAVE( 1 ) = 5)
207: *     X HAS BEEN OVERWRITTEN BY A*X.
208: *
209:   120 CONTINUE
210:       TEMP = TWO*( DZSUM1( N, X, 1 ) / DBLE( 3*N ) )
211:       IF( TEMP.GT.EST ) THEN
212:          CALL ZCOPY( N, X, 1, V, 1 )
213:          EST = TEMP
214:       END IF
215: *
216:   130 CONTINUE
217:       KASE = 0
218:       RETURN
219: *
220: *     End of ZLACN2
221: *
222:       END
223: