pmpim2.f

Go to the documentation of this file.

***********************************************************************
*
*     Auxiliary subroutine for eigenpair assignments
*
***********************************************************************
      SUBROUTINE pmpim2( IL, IU, NPROCS, PMYILS, PMYIUS )
 
      IMPLICIT NONE
*
*  -- ScaLAPACK auxiliary routine (version 2.0.2) --
*     Univ. of Tennessee, Univ. of California Berkeley, Univ. of Colorado Denver
*     May 1 2012
*
*     .. Scalar Arguments ..
      INTEGER PMYILS( * ), PMYIUS( * )
*     ..
*     .. Array Arguments ..
      INTEGER IL, IU, M, NPROCS, PRCCTR
*     ..
*
*  Purpose
*  =======
*
*  PMPIM2 is the scheduling subroutine.
*  It computes for all processors the eigenpair range assignments.
*
*  Arguments
*  =========
*
*  IL, IU  (input) INTEGER
*          The range of eigenpairs to be computed
*
*  NPROCS  (input) INTEGER
*          The total number of processors available
*
*  PMYILS  (output) INTEGER array
*          For each processor p,  PMYILS(p) is the index 
*          of the first eigenvalue in W to be computed
*          PMYILS(p) equals zero if p stays idle
*
*  PMYIUS  (output) INTEGER array
*          For each processor p,  PMYIUS(p) is the index
*          of the last eigenvalue in W to be computed
*          PMYIUS(p) equals zero if p stays idle
*
 
*     .. Executable Statements ..
      m = iu - il + 1
 
      IF ( nprocs.GT.m ) THEN
         DO 10 prcctr = 0, nprocs-1
            IF ( prcctr.LT.m ) THEN
               pmyils(prcctr+1) = prcctr + il
               pmyius(prcctr+1) = prcctr + il
            ELSE
               pmyils(prcctr+1) = 0
               pmyius(prcctr+1) = 0
            END IF
 10      CONTINUE
      ELSE
         DO 20 prcctr = 0, nprocs-1
            pmyils(prcctr+1) = (prcctr * (m / nprocs)) + il
            IF (prcctr.LT.mod(m, nprocs)) THEN
               pmyils(prcctr+1) = pmyils(prcctr+1) + prcctr
               pmyius(prcctr+1) = pmyils(prcctr+1) + m / nprocs
            ELSE
               pmyils(prcctr+1) = pmyils(prcctr+1) + mod(m, nprocs)
               pmyius(prcctr+1) = pmyils(prcctr+1) + m / nprocs - 1
            END IF
 20      CONTINUE
      END IF
 
      RETURN
      END