pzlarzt()

subroutine pzlarzt	(	character	direct,
		character	storev,
		integer	n,
		integer	k,
		complex*16, dimension( * )	v,
		integer	iv,
		integer	jv,
		integer, dimension( * )	descv,
		complex*16, dimension( * )	tau,
		complex*16, dimension( * )	t,
		complex*16, dimension( * )	work
	)

Definition at line 1 of file pzlarzt.f.

*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          DIRECT, STOREV
      INTEGER            IV, JV, K, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCV( * )
      COMPLEX*16         TAU( * ), T( * ), V( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PZLARZT forms the triangular factor T of a complex block reflector
*  H of order > n, which is defined as a product of k elementary
*  reflectors as returned by PZTZRZF.
*
*  If DIRECT = 'F', H = H(1) H(2) . . . H(k) and T is upper triangular;
*
*  If DIRECT = 'B', H = H(k) . . . H(2) H(1) and T is lower triangular.
*
*  If STOREV = 'C', the vector which defines the elementary reflector
*  H(i) is stored in the i-th column of the array V, and
*
*     H  =  I - V * T * V'
*
*  If STOREV = 'R', the vector which defines the elementary reflector
*  H(i) is stored in the i-th row of the array V, and
*
*     H  =  I - V' * T * V
*
*  Currently, only STOREV = 'R' and DIRECT = 'B' are supported.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  DIRECT  (global input) CHARACTER
*          Specifies the order in which the elementary reflectors are
*          multiplied to form the block reflector:
*          = 'F': H = H(1) H(2) . . . H(k) (Forward, not supported yet)
*          = 'B': H = H(k) . . . H(2) H(1) (Backward)
*
*  STOREV  (global input) CHARACTER
*          Specifies how the vectors which define the elementary
*          reflectors are stored (see also Further Details):
*          = 'C': columnwise                        (not supported yet)
*          = 'R': rowwise
*
*  N       (global input) INTEGER
*          The number of meaningful entries of the block reflector H.
*          N >= 0.
*
*  K       (global input) INTEGER
*          The order of the triangular factor T (= the number of
*          elementary reflectors). 1 <= K <= MB_V (= NB_V).
*
*  V       (input/output) COMPLEX*16 pointer into the local memory
*          to an array of local dimension (LOCr(IV+K-1),LOCc(JV+N-1)).
*          The distributed matrix V contains the Householder vectors.
*          See further details.
*
*  IV      (global input) INTEGER
*          The row index in the global array V indicating the first
*          row of sub( V ).
*
*  JV      (global input) INTEGER
*          The column index in the global array V indicating the
*          first column of sub( V ).
*
*  DESCV   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix V.
*
*  TAU     (local input) COMPLEX*16, array, dimension LOCr(IV+K-1)
*          if INCV = M_V, and LOCc(JV+K-1) otherwise. This array
*          contains the Householder scalars related to the Householder
*          vectors.  TAU is tied to the distributed matrix V.
*
*  T       (local output) COMPLEX*16 array, dimension (MB_V,MB_V)
*          It contains the k-by-k triangular factor of the block
*          reflector associated with V. T is lower triangular.
*
*  WORK    (local workspace) COMPLEX*16 array,
*                                           dimension (K*(K-1)/2)
*
*  Further Details
*  ===============
*
*  The shape of the matrix V and the storage of the vectors which define
*  the H(i) is best illustrated by the following example with n = 5 and
*  k = 3. The elements equal to 1 are not stored; the corresponding
*  array elements are modified but restored on exit. The rest of the
*  array is not used.
*
*  DIRECT = 'F' and STOREV = 'C':         DIRECT = 'F' and STOREV = 'R':
*
*                                              ______V_____
*         ( v1 v2 v3 )                        /            \
*         ( v1 v2 v3 )                      ( v1 v1 v1 v1 v1 . . . . 1 )
*     V = ( v1 v2 v3 )                      ( v2 v2 v2 v2 v2 . . . 1   )
*         ( v1 v2 v3 )                      ( v3 v3 v3 v3 v3 . . 1     )
*         ( v1 v2 v3 )
*            .  .  .
*            .  .  .
*            1  .  .
*               1  .
*                  1
*
*  DIRECT = 'B' and STOREV = 'C':         DIRECT = 'B' and STOREV = 'R':
*
*                                                        ______V_____
*            1                                          /            \
*            .  1                           ( 1 . . . . v1 v1 v1 v1 v1 )
*            .  .  1                        ( . 1 . . . v2 v2 v2 v2 v2 )
*            .  .  .                        ( . . 1 . . v3 v3 v3 v3 v3 )
*            .  .  .
*         ( v1 v2 v3 )
*         ( v1 v2 v3 )
*     V = ( v1 v2 v3 )
*         ( v1 v2 v3 )
*         ( v1 v2 v3 )
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      COMPLEX*16         ZERO
      parameter( zero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            ICOFF, ICTXT, II, IIV, INFO, IVCOL, IVROW,
     $                   ITMP0, ITMP1, IW, JJV, LDV, MYCOL, MYROW,
     $                   NPCOL, NPROW, NQ
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_abort, blacs_gridinfo, infog2l, pxerbla,
     $                   zcopy, zgemv, zgsum2d, zlacgv,
     $                   zlaset, ztrmv
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            NUMROC
      EXTERNAL           lsame, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          mod
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = descv( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Check for currently supported options
*
      info = 0
      IF( .NOT.lsame( direct, 'B' ) ) THEN
         info = -1
      ELSE IF( .NOT.lsame( storev, 'R' ) ) THEN
         info = -2
      END IF
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PZLARZT', -info )
         CALL blacs_abort( ictxt, 1 )
         RETURN
      END IF
*
      CALL infog2l( iv, jv, descv, nprow, npcol, myrow, mycol,
     $              iiv, jjv, ivrow, ivcol )
*
      IF( myrow.EQ.ivrow ) THEN
         iw = 1
         itmp0 = 0
         ldv = descv( lld_ )
         icoff = mod( jv-1, descv( nb_ ) )
         nq = numroc( n+icoff, descv( nb_ ), mycol, ivcol, npcol )
         IF( mycol.EQ.ivcol )
     $      nq = nq - icoff
*
         DO 10 ii = iiv+k-2, iiv, -1
*
*           T(i+1:k,i) = -tau( iv+i-1 ) *
*                     V(iv+i:iv+k-1,jv:jv+n-1) * V(iv+i-1,jv:jv+n-1)'
*
            itmp0 = itmp0 + 1
            IF( nq.GT.0 ) THEN
               CALL zlacgv( nq, v( ii+(jjv-1)*ldv ), ldv )
               CALL zgemv( 'No transpose', itmp0, nq, -tau( ii ),
     $                     v( ii+1+(jjv-1)*ldv ), ldv,
     $                     v( ii+(jjv-1)*ldv ), ldv, zero, work( iw ),
     $                     1 )
               CALL zlacgv( nq, v( ii+(jjv-1)*ldv ), ldv )
            ELSE
               CALL zlaset( 'All', itmp0, 1, zero, zero, work( iw ),
     $                      itmp0 )
            END IF
            iw = iw + itmp0
*
   10    CONTINUE
*
         CALL zgsum2d( ictxt, 'Rowwise', ' ', iw-1, 1, work, iw-1,
     $                 myrow, ivcol )
*
         IF( mycol.EQ.ivcol ) THEN
*
            iw = 1
            itmp0 = 0
            itmp1 = k + 1 + (k-1) * descv( mb_ )
*
            t( itmp1-1 ) = tau( iiv+k-1 )
*
            DO 20 ii = iiv+k-2, iiv, -1
*
*              T(i+1:k,i) = T(i+1:k,i+1:k) * T(i+1:k,i)
*
               itmp0 = itmp0 + 1
               itmp1 = itmp1 - descv( mb_ ) - 1
               CALL zcopy( itmp0, work( iw ), 1, t( itmp1 ), 1 )
               iw = iw + itmp0
*
               CALL ztrmv( 'Lower', 'No transpose', 'Non-unit', itmp0,
     $                     t( itmp1+descv( mb_ ) ), descv( mb_ ),
     $                     t( itmp1 ), 1 )
               t( itmp1-1 ) = tau( ii )
*
   20       CONTINUE
*
         END IF
*
      END IF
*
      RETURN
*
*     End of PZLARZT
*

Here is the call graph for this function:

Here is the caller graph for this function: