pstzrzrv()

subroutine pstzrzrv	(	integer	m,
		integer	n,
		real, dimension( * )	a,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		real, dimension( * )	tau,
		real, dimension( * )	work
	)

Definition at line 1 of file pstzrzrv.f.

*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 28, 2001
*
*     .. Scalar Arguments ..
      INTEGER            IA, JA, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      REAL               A( * ),  TAU( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PSTZRZRV computes sub( A ) = A(IA:IA+M-1,JA:JA+N-1) from T, Z
*  computed by PSTZRZF.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  M       (global input) INTEGER
*          The number of rows to be operated on, i.e. the number of rows
*          of the distributed submatrix sub( A ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on, i.e. the number of
*          columns of the distributed submatrix sub( A ). N >= M >= 0.
*
*  A       (local input/local output) REAL pointer into the
*          local memory to an array of dimension (LLD_A, LOCc(JA+N-1)).
*          On entry, sub( A ) contains the the factors T and Z computed
*          by PSTZRZF. On exit, the original matrix is restored.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  TAU     (local input) REAL, array, dimension LOCr(M_A).
*          This array contains the scalar factors TAU of the elementary
*          reflectors computed by PSTZRZF. TAU is tied to the dis-
*          tributed matrix A.
*
*  WORK    (local workspace) REAL array, dimension (LWORK)
*          LWORK = MB_A * ( Mp0 + 2*Nq0 + MB_A ), where
*          Mp0   = NUMROC( M+IROFF, MB_A, MYROW, IAROW, NPROW ) * NB_A,
*          Nq0   = NUMROC( N+ICOFF, NB_A, MYCOL, IACOL, NPCOL ) * MB_A,
*          IROFF = MOD( IA-1, MB_A ), ICOFF = MOD( JA-1, NB_A ),
*          IAROW = INDXG2P( IA, DESCA( MB_ ), MYROW, DESCA( RSRC_ ),
*                           NPROW ),
*          IACOL = INDXG2P( JA, DESCA( NB_ ), MYCOL, DESCA( CSRC_ ),
*                           NPCOL ),
*          and NUMROC, INDXG2P are ScaLAPACK tool functions.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               ZERO
      parameter( zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      CHARACTER          COLBTOP, ROWBTOP
      INTEGER            I, IACOL, IAROW, IB, ICOFF, ICTXT, IIA, IN,
     $                   IPT, IPV, IPW, JJA, JM1, JV, L, MYCOL, MYROW,
     $                   NPCOL, NPROW, NQ
*     ..
*     .. Local Arrays ..
      INTEGER            DESCV( DLEN_ )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, descset, infog2l, pslacpy,
     $                   pslarzb, pslarzt, pslaset, pb_topget,
     $                   pb_topset
*     ..
*     .. External Functions ..
      INTEGER            ICEIL, NUMROC
      EXTERNAL           iceil, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, mod
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Quick return if possible
*
      IF( n.LT.m )
     $   RETURN
*
      l = n - m
      jm1 = ja + min( m+1, n ) - 1
      in = min( iceil( ia, desca( mb_ ) ) * desca( mb_ ), ia+m-1 )
      icoff = mod( ja-1, desca( nb_ ) )
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, iia, jja,
     $              iarow, iacol )
      nq = numroc( n+icoff, desca( nb_ ), mycol, iacol, npcol )
      ipv = 1
      ipt = ipv + nq * desca( mb_ )
      ipw = ipt + desca( mb_ ) * desca( mb_ )
      CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
      CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', ' ' )
      CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', 'I-ring' )
*
      CALL descset( descv, desca( mb_ ), n + icoff, desca( mb_ ),
     $              desca( nb_ ), iarow, iacol, ictxt, desca( mb_ ) )
*
*     Handle first block separately
*
      ib = in - ia + 1
      jv = icoff + jm1 - ja + 1
*
*     Compute upper triangular matrix T
*
      CALL pslarzt( 'Backward', 'Rowwise', l, ib, a, ia, jm1, desca,
     $              tau, work( ipt ), work( ipw ) )
*
*     Copy Householder vectors into workspace
*
      CALL pslacpy( 'All', ib, l, a, ia, jm1, desca, work( ipv ), 1,
     $              jv, descv )
*
*     Save temporarily strict lower part of A(IA:IA+IB-1,JA:JA+IB-1)
*
      CALL pslacpy( 'Lower', ib-1, ib-1, a, ia+1, ja, desca,
     $              work( ipv ), 1, icoff+1, descv )
*
*     Zeroes the row panel of sub( A ) to get T(IA:IN,JA:JA+N-1)
*
      CALL pslaset( 'All', ib, l, zero, zero, a, ia, jm1, desca )
      CALL pslaset( 'Lower', ib-1, ib-1, zero, zero, a, ia+1, ja,
     $              desca )
*
*     Apply block Householder transformation
*
      CALL pslarzb( 'Right', 'Transpose', 'Backward', 'Rowwise',
     $              in-ia+1, n, ib, l, work( ipv ), 1, jv, descv,
     $              work( ipt ), a, ia, ja, desca, work( ipw ) )
*
*     Restore strict lower part of A( IA:IA+IB-1, JA:JA+N-1 )
*
      CALL pslacpy( 'Lower', ib-1, ib-1, work( ipv ), 1, icoff+1, descv,
     $              a, ia+1, ja, desca )
*
      descv( rsrc_ ) = mod( descv( rsrc_ ) + 1, nprow )
*
*     Loop over the remaining row blocks
*
      DO 10 i = in+1, ia+m-1, desca( mb_ )
         ib = min( ia+m-i, desca( mb_ ) )
*
*        Compute upper triangular matrix T
*
         CALL pslarzt( 'Backward', 'Rowwise', l, ib, a, i, jm1, desca,
     $                 tau, work( ipt ), work( ipw ) )
*
*        Copy Householder vectors into workspace
*
         CALL pslacpy( 'All', ib, l, a, i, jm1, desca, work( ipv ), 1,
     $                 jv, descv )
*
*        Save temporarily strict lower part of A(I:I+IB-1,J:J+IB-1 )
*
         CALL pslacpy( 'Lower', ib-1, ib-1, a, i+1, ja+i-ia, desca,
     $                 work( ipv ), 1, icoff+1+i-ia, descv )
*
*        Zeoes the row panel of sub( A ) to get T(IA:I-1,JA+I-IA:JA+N-1)
*
         CALL pslaset( 'All', ib, l, zero, zero, a, i, jm1, desca )
         CALL pslaset( 'Lower', ib-1, ib-1, zero, zero, a, i+1, ja+i-ia,
     $                 desca )
*
*        Apply block Householder transformation
*
         CALL pslarzb( 'Right', 'Transpose', 'Backward', 'Rowwise',
     $                 i+ib-ia, n-i+ia, ib, l, work( ipv ), 1, jv,
     $                 descv, work( ipt ), a, ia, ja+i-ia, desca,
     $                 work( ipw ) )
*
         CALL pslacpy( 'Lower', ib-1, ib-1, work( ipv ), 1,
     $                 icoff+1+i-ia, descv, a, i+1, ja+i-ia, desca )
*
         descv( rsrc_ ) = mod( descv( rsrc_ ) + 1, nprow )
*
   10 CONTINUE
*
      CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      RETURN
*
*     End of PSTZRZRV
*

Here is the call graph for this function:

Here is the caller graph for this function: