slarnd()

real function slarnd	(	integer	idist,
		integer, dimension( 4 )	iseed
	)

Definition at line 1 of file slarnd.f.

*
*  -- LAPACK auxiliary routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      INTEGER            IDIST
*     ..
*     .. Array Arguments ..
      INTEGER            ISEED( 4 )
*     ..
*
*  Purpose
*  =======
*
*  SLARND returns a random real number from a uniform or normal
*  distribution.
*
*  Arguments
*  =========
*
*  IDIST   (input) INTEGER
*          Specifies the distribution of the random numbers:
*          = 1:  uniform (0,1)
*          = 2:  uniform (-1,1)
*          = 3:  normal (0,1)
*
*  ISEED   (input/output) INTEGER array, dimension (4)
*          On entry, the seed of the random number generator; the array
*          elements must be between 0 and 4095, and ISEED(4) must be
*          odd.
*          On exit, the seed is updated.
*
*  Further Details
*  ===============
*
*  This routine calls the auxiliary routine SLARAN to generate a random
*  real number from a uniform (0,1) distribution. The Box-Muller method
*  is used to transform numbers from a uniform to a normal distribution.
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, TWO
      parameter( one = 1.0e+0, two = 2.0e+0 )
      REAL               TWOPI
      parameter( twopi = 6.2831853071795864769252867663e+0 )
*     ..
*     .. Local Scalars ..
      REAL               T1, T2
*     ..
*     .. External Functions ..
      REAL               SLARAN
      EXTERNAL           slaran
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cos, log, sqrt
*     ..
*     .. Executable Statements ..
*
*     Generate a real random number from a uniform (0,1) distribution
*
      t1 = slaran( iseed )
*
      IF( idist.EQ.1 ) THEN
*
*        uniform (0,1)
*
         slarnd = t1
      ELSE IF( idist.EQ.2 ) THEN
*
*        uniform (-1,1)
*
         slarnd = two*t1 - one
      ELSE IF( idist.EQ.3 ) THEN
*
*        normal (0,1)
*
         t2 = slaran( iseed )
         slarnd = sqrt( -two*log( t1 ) )*cos( twopi*t2 )
      ELSE
         slarnd = one
      END IF
      RETURN
*
*     End of SLARND
*

Here is the call graph for this function:

Here is the caller graph for this function: