pdlatra.f

Go to the documentation of this file.

      DOUBLE PRECISION   FUNCTION pdlatra( N, A, IA, JA, DESCA )
*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            ia, ja, n
*     ..
*     .. Array Arguments ..
      INTEGER            desca( * )
      DOUBLE PRECISION   a( * )
*     ..
*
*  Purpose
*  =======
*
*  PDLATRA computes the trace of an N-by-N distributed matrix sub( A )
*  denoting A( IA:IA+N-1, JA:JA+N-1 ). The result is left on every
*  process of the grid.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on i.e the
*          order of the distributed submatrix sub( A ).  N >= 0.
*
*  A       (local input) DOUBLE PRECISION pointer into the local memory
*          to an array of dimension ( LLD_A, LOCc(JA+N-1) ). This array
*          contains the local pieces of the distributed matrix the trace
*          is to be computed.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  ====================================================================
*
*     .. Parameters ..
      INTEGER            block_cyclic_2d, csrc_, ctxt_, dlen_, dtype_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      DOUBLE PRECISION   zero
      parameter( zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            icurcol, icurrow, ii, ioffa, j, jb, jj, jn,
     $                   lda, ll, mycol, myrow, npcol, nprow
      DOUBLE PRECISION   trace
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, dgsum2d, infog2l
*     ..
*     .. External Functions ..
      INTEGER            iceil
      EXTERNAL           iceil
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min, mod
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      CALL blacs_gridinfo( desca( ctxt_ ), nprow, npcol, myrow, mycol )
*
      trace = zero
      IF( n.EQ.0 ) THEN
         pdlatra = trace
         RETURN
      END IF
*
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, ii, jj,
     $              icurrow, icurcol )
*
      jn = min( iceil( ja, desca( nb_ ) ) * desca( nb_ ), ja+n-1 )
      jb = jn-ja+1
      lda = desca( lld_ )
      ioffa = ii + ( jj - 1 ) * lda
*
*     Handle first diagonal block separately
*
      IF( myrow.EQ.icurrow .AND. mycol.EQ.icurcol ) THEN
         DO 10 ll = ioffa, ioffa + (jb-1)*(lda+1), lda+1
            trace = trace + a( ll )
   10    CONTINUE
      END IF
      IF( myrow.EQ.icurrow )
     $   ioffa = ioffa + jb
      IF( mycol.EQ.icurcol )
     $   ioffa = ioffa + jb*lda
      icurrow = mod( icurrow+1, nprow )
      icurcol = mod( icurcol+1, npcol )
*
*     Loop over the remaining block of columns
*
      DO 30 j = jn+1, ja+n-1, desca( nb_ )
         jb = min( ja+n-j, desca( nb_ ) )
*
         IF( myrow.EQ.icurrow .AND. mycol.EQ.icurcol ) THEN
            DO 20 ll = ioffa, ioffa + (jb-1)*(lda+1), lda+1
               trace = trace + a( ll )
   20       CONTINUE
         END IF
         IF( myrow.EQ.icurrow )
     $      ioffa = ioffa + jb
         IF( mycol.EQ.icurcol )
     $      ioffa = ioffa + jb*lda
         icurrow = mod( icurrow+1, nprow )
         icurcol = mod( icurcol+1, npcol )
   30 CONTINUE
*
      CALL dgsum2d( desca( ctxt_ ), 'All', ' ', 1, 1, trace, 1, -1,
     $              mycol )
*
      pdlatra = trace
*
      RETURN
*
*     End of PDLATRA
*
      END