pcgebd2()

subroutine pcgebd2	(	integer	m,
		integer	n,
		complex, dimension( * )	a,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		real, dimension( * )	d,
		real, dimension( * )	e,
		complex, dimension( * )	tauq,
		complex, dimension( * )	taup,
		complex, dimension( * )	work,
		integer	lwork,
		integer	info
	)

Definition at line 1 of file pcgebd2.f.

*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            IA, INFO, JA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      REAL               D( * ), E( * )
      COMPLEX            A( * ), TAUP( * ), TAUQ( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PCGEBD2 reduces a complex general M-by-N distributed matrix
*  sub( A ) = A(IA:IA+M-1,JA:JA+N-1) to upper or lower bidiagonal
*  form B by an unitary transformation: Q' * sub( A ) * P = B.
*
*  If M >= N, B is upper bidiagonal; if M < N, B is lower bidiagonal.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  M       (global input) INTEGER
*          The number of rows to be operated on, i.e. the number of rows
*          of the distributed submatrix sub( A ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on, i.e. the number of
*          columns of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) COMPLEX pointer into the
*          local memory to an array of dimension (LLD_A,LOCc(JA+N-1)).
*          On entry, this array contains the local pieces of the
*          general distributed matrix sub( A ). On exit, if M >= N,
*          the diagonal and the first superdiagonal of sub( A ) are
*          overwritten with the upper bidiagonal matrix B; the elements
*          below the diagonal, with the array TAUQ, represent the
*          unitary matrix Q as a product of elementary reflectors, and
*          the elements above the first superdiagonal, with the array
*          TAUP, represent the orthogonal matrix P as a product of
*          elementary reflectors. If M < N, the diagonal and the first
*          subdiagonal are overwritten with the lower bidiagonal
*          matrix B; the elements below the first subdiagonal, with the
*          array TAUQ, represent the unitary matrix Q as a product of
*          elementary reflectors, and the elements above the diagonal,
*          with the array TAUP, represent the orthogonal matrix P as a
*          product of elementary reflectors. See Further Details.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  D       (local output) REAL array, dimension
*          LOCc(JA+MIN(M,N)-1) if M >= N; LOCr(IA+MIN(M,N)-1) otherwise.
*          The distributed diagonal elements of the bidiagonal matrix
*          B: D(i) = A(i,i). D is tied to the distributed matrix A.
*
*  E       (local output) REAL array, dimension
*          LOCr(IA+MIN(M,N)-1) if M >= N; LOCc(JA+MIN(M,N)-2) otherwise.
*          The distributed off-diagonal elements of the bidiagonal
*          distributed matrix B:
*          if m >= n, E(i) = A(i,i+1) for i = 1,2,...,n-1;
*          if m < n, E(i) = A(i+1,i) for i = 1,2,...,m-1.
*          E is tied to the distributed matrix A.
*
*  TAUQ    (local output) COMPLEX array dimension
*          LOCc(JA+MIN(M,N)-1). The scalar factors of the elementary
*          reflectors which represent the unitary matrix Q. TAUQ is
*          tied to the distributed matrix A. See Further Details.
*
*  TAUP    (local output) COMPLEX array, dimension
*          LOCr(IA+MIN(M,N)-1). The scalar factors of the elementary
*          reflectors which represent the unitary matrix P. TAUP is
*          tied to the distributed matrix A. See Further Details.
*
*  WORK    (local workspace/local output) COMPLEX array,
*                                                  dimension (LWORK)
*          On exit, WORK(1) returns the minimal and optimal LWORK.
*
*  LWORK   (local or global input) INTEGER
*          The dimension of the array WORK.
*          LWORK is local input and must be at least
*          LWORK >= MAX( MpA0, NqA0 )
*
*          where NB = MB_A = NB_A, IROFFA = MOD( IA-1, NB )
*          IAROW = INDXG2P( IA, NB, MYROW, RSRC_A, NPROW ),
*          IACOL = INDXG2P( JA, NB, MYCOL, CSRC_A, NPCOL ),
*          MpA0 = NUMROC( M+IROFFA, NB, MYROW, IAROW, NPROW ),
*          NqA0 = NUMROC( N+IROFFA, NB, MYCOL, IACOL, NPCOL ).
*
*          INDXG2P and NUMROC are ScaLAPACK tool functions;
*          MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*          the subroutine BLACS_GRIDINFO.
*
*          If LWORK = -1, then LWORK is global input and a workspace
*          query is assumed; the routine only calculates the minimum
*          and optimal size for all work arrays. Each of these
*          values is returned in the first entry of the corresponding
*          work array, and no error message is issued by PXERBLA.
*
*  INFO    (local output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  Further Details
*  ===============
*
*  The matrices Q and P are represented as products of elementary
*  reflectors:
*
*  If m >= n,
*
*     Q = H(1) H(2) . . . H(n)  and  P = G(1) G(2) . . . G(n-1)
*
*  Each H(i) and G(i) has the form:
*
*     H(i) = I - tauq * v * v'  and G(i) = I - taup * u * u'
*
*  where tauq and taup are complex scalars, and v and u are complex
*  vectors;
*  v(1:i-1) = 0, v(i) = 1, and v(i+1:m) is stored on exit in
*  A(ia+i:ia+m-1,ja+i-1);
*  u(1:i) = 0, u(i+1) = 1, and u(i+2:n) is stored on exit in
*  A(ia+i-1,ja+i+1:ja+n-1);
*  tauq is stored in TAUQ(ja+i-1) and taup in TAUP(ia+i-1).
*
*  If m < n,
*
*     Q = H(1) H(2) . . . H(m-1)  and  P = G(1) G(2) . . . G(m)
*
*  Each H(i) and G(i) has the form:
*
*     H(i) = I - tauq * v * v'  and G(i) = I - taup * u * u'
*
*  where tauq and taup are complex scalars, and v and u are complex
*  vectors;
*  v(1:i) = 0, v(i+1) = 1, and v(i+2:m) is stored on exit in
*  A(ia+i+1:ia+m-1,ja+i-1);
*  u(1:i-1) = 0, u(i) = 1, and u(i+1:n) is stored on exit in
*  A(ia+i-1,ja+i:ja+n-1);
*  tauq is stored in TAUQ(ja+i-1) and taup in TAUP(ia+i-1).
*
*  The contents of sub( A ) on exit are illustrated by the following
*  examples:
*
*  m = 6 and n = 5 (m > n):          m = 5 and n = 6 (m < n):
*
*    (  d   e   u1  u1  u1 )           (  d   u1  u1  u1  u1  u1 )
*    (  v1  d   e   u2  u2 )           (  e   d   u2  u2  u2  u2 )
*    (  v1  v2  d   e   u3 )           (  v1  e   d   u3  u3  u3 )
*    (  v1  v2  v3  d   e  )           (  v1  v2  e   d   u4  u4 )
*    (  v1  v2  v3  v4  d  )           (  v1  v2  v3  e   d   u5 )
*    (  v1  v2  v3  v4  v5 )
*
*  where d and e denote diagonal and off-diagonal elements of B, vi
*  denotes an element of the vector defining H(i), and ui an element of
*  the vector defining G(i).
*
*  Alignment requirements
*  ======================
*
*  The distributed submatrix sub( A ) must verify some alignment proper-
*  ties, namely the following expressions should be true:
*                  ( MB_A.EQ.NB_A .AND. IROFFA.EQ.ICOFFA )
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      COMPLEX            ONE, ZERO
      parameter( one = ( 1.0e+0, 0.0e+0 ),
     $                   zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            I, IACOL, IAROW, ICOFFA, ICTXT, II, IROFFA, J,
     $                   JJ, K, LWMIN, MPA0, MYCOL, MYROW, NPCOL, NPROW,
     $                   NQA0
      COMPLEX            ALPHA
*     ..
*     .. Local Arrays ..
      INTEGER            DESCD( DLEN_ ), DESCE( DLEN_ )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_abort, blacs_gridinfo, cgebr2d,
     $                   cgebs2d, chk1mat, clarfg, descset, infog2l,
     $                   pcelset, pclacgv, pclarf, pclarfc,
     $                   pclarfg, pselset, pxerbla, sgebr2d,
     $                   sgebs2d
*     ..
*     .. External Functions ..
      INTEGER            INDXG2P, NUMROC
      EXTERNAL           indxg2p, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, min, mod, real
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(600+ctxt_)
      ELSE
         CALL chk1mat( m, 1, n, 2, ia, ja, desca, 6, info )
         IF( info.EQ.0 ) THEN
            iroffa = mod( ia-1, desca( mb_ ) )
            icoffa = mod( ja-1, desca( nb_ ) )
            iarow = indxg2p( ia, desca( mb_ ), myrow, desca( rsrc_ ),
     $                       nprow )
            iacol = indxg2p( ja, desca( nb_ ), mycol, desca( csrc_ ),
     $                       npcol )
            mpa0 = numroc( m+iroffa, desca( mb_ ), myrow, iarow, nprow )
            nqa0 = numroc( n+icoffa, desca( nb_ ), mycol, iacol, npcol )
            lwmin = max( mpa0, nqa0 )
*
            work( 1 ) = cmplx( real( lwmin ) )
            lquery = ( lwork.EQ.-1 )
            IF( iroffa.NE.icoffa ) THEN
               info = -5
            ELSE IF( desca( mb_ ).NE.desca( nb_ ) ) THEN
               info = -(600+nb_)
            ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
               info = -12
            END IF
         END IF
      END IF
*
      IF( info.LT.0 ) THEN
         CALL pxerbla( ictxt, 'PCGEBD2', -info )
         CALL blacs_abort( ictxt, 1 )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, ii, jj,
     $              iarow, iacol )
*
      IF( m.EQ.1 .AND. n.EQ.1 ) THEN
         IF( mycol.EQ.iacol ) THEN
            IF( myrow.EQ.iarow ) THEN
               i = ii+(jj-1)*desca( lld_ )
               CALL clarfg( 1, a( i ), a( i ), 1, tauq( jj ) )
               d( jj ) = real( a( i ) )
               CALL sgebs2d( ictxt, 'Columnwise', ' ', 1, 1, d( jj ),
     $                       1 )
               CALL cgebs2d( ictxt, 'Columnwise', ' ', 1, 1, tauq( jj ),
     $                       1 )
            ELSE
               CALL sgebr2d( ictxt, 'Columnwise', ' ', 1, 1, d( jj ),
     $                       1, iarow, iacol )
               CALL cgebr2d( ictxt, 'Columnwise', ' ', 1, 1, tauq( jj ),
     $                       1, iarow, iacol )
            END IF
         END IF
         IF( myrow.EQ.iarow )
     $      taup( ii ) = zero
         RETURN
      END IF
*
      alpha = zero
*
      IF( m.GE.n ) THEN
*
*        Reduce to upper bidiagonal form
*
         CALL descset( descd, 1, ja+min(m,n)-1, 1, desca( nb_ ), myrow,
     $                 desca( csrc_ ), desca( ctxt_ ), 1 )
         CALL descset( desce, ia+min(m,n)-1, 1, desca( mb_ ), 1,
     $                 desca( rsrc_ ), mycol, desca( ctxt_ ),
     $                 desca( lld_ ) )
         DO 10 k = 1, n
            i = ia + k - 1
            j = ja + k - 1
*
*           Generate elementary reflector H(j) to annihilate
*           A(ia+i:ia+m-1,j)
*
            CALL pclarfg( m-k+1, alpha, i, j, a, min( i+1, m+ia-1 ),
     $                    j, desca, 1, tauq )
            CALL pselset( d, 1, j, descd, real( alpha ) )
            CALL pcelset( a, i, j, desca, one )
*
*           Apply H(i) to A(i:ia+m-1,i+1:ja+n-1) from the left
*
            CALL pclarfc( 'Left', m-k+1, n-k, a, i, j, desca, 1, tauq,
     $                    a, i, j+1, desca, work )
            CALL pcelset( a, i, j, desca, cmplx( real( alpha ) ) )
*
            IF( k.LT.n ) THEN
*
*              Generate elementary reflector G(i) to annihilate
*              A(i,ja+j+1:ja+n-1)
*
               CALL pclacgv( n-k, a, i, j+1, desca, desca( m_ ) )
               CALL pclarfg( n-k, alpha, i, j+1, a, i,
     $                       min( j+2, ja+n-1 ), desca, desca( m_ ),
     $                       taup )
               CALL pselset( e, i, 1, desce, real( alpha ) )
               CALL pcelset( a, i, j+1, desca, one )
*
*              Apply G(i) to A(i+1:ia+m-1,i+1:ja+n-1) from the right
*
               CALL pclarf( 'Right', m-k, n-k, a, i, j+1, desca,
     $                      desca( m_ ), taup, a, i+1, j+1, desca,
     $                      work )
               CALL pcelset( a, i, j+1, desca, cmplx( real( alpha ) ) )
               CALL pclacgv( n-k, a, i, j+1, desca, desca( m_ ) )
            ELSE
               CALL pcelset( taup, i, 1, desce, zero )
            END IF
   10    CONTINUE
*
      ELSE
*
*        Reduce to lower bidiagonal form
*
         CALL descset( descd, ia+min(m,n)-1, 1, desca( mb_ ), 1,
     $                 desca( rsrc_ ), mycol, desca( ctxt_ ),
     $                 desca( lld_ ) )
         CALL descset( desce, 1, ja+min(m,n)-1, 1, desca( nb_ ), myrow,
     $                 desca( csrc_ ), desca( ctxt_ ), 1 )
         DO 20 k = 1, m
            i = ia + k - 1
            j = ja + k - 1
*
*           Generate elementary reflector G(i) to annihilate
*           A(i,ja+j:ja+n-1)
*
            CALL pclacgv( n-k+1, a, i, j, desca, desca( m_ ) )
            CALL pclarfg( n-k+1, alpha, i, j, a, i,
     $                    min( j+1, ja+n-1 ), desca, desca( m_ ), taup )
            CALL pselset( d, i, 1, descd, real( alpha ) )
            CALL pcelset( a, i, j, desca, one )
*
*           Apply G(i) to A(i:ia+m-1,j:ja+n-1) from the right
*
            CALL pclarf( 'Right', m-k, n-k+1, a, i, j, desca,
     $                   desca( m_ ), taup, a, min( i+1, ia+m-1 ), j,
     $                   desca, work )
            CALL pcelset( a, i, j, desca, cmplx( real( alpha ) ) )
            CALL pclacgv( n-k+1, a, i, j, desca, desca( m_ ) )
*
            IF( k.LT.m ) THEN
*
*              Generate elementary reflector H(i) to annihilate
*              A(i+2:ia+m-1,j)
*
               CALL pclarfg( m-k, alpha, i+1, j, a,
     $                       min( i+2, ia+m-1 ), j, desca, 1, tauq )
               CALL pselset( e, 1, j, desce, real( alpha ) )
               CALL pcelset( a, i+1, j, desca, one )
*
*              Apply H(i) to A(i+1:ia+m-1,j+1:ja+n-1) from the left
*
               CALL pclarfc( 'Left', m-k, n-k, a, i+1, j, desca, 1,
     $                       tauq, a, i+1, j+1, desca, work )
               CALL pcelset( a, i+1, j, desca, cmplx( real( alpha ) ) )
            ELSE
               CALL pcelset( tauq, 1, j, desce, zero )
            END IF
   20    CONTINUE
      END IF
*
      work( 1 ) = cmplx( real( lwmin ) )
*
      RETURN
*
*     End of PCGEBD2
*

Here is the call graph for this function:

Here is the caller graph for this function: